I_PurContractPartnerFunctionVH

@AbapCatalog.sqlViewName: 'IPCPARTNFUNCTVH'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Pur. Contr. Partner Function Value Help'
//@ObjectModel.representativeKey: 'PartnerFunction'


@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MIXED

@Search.searchable: true

define view I_PurContractPartnerFunctionVH
  as select from t161  as schema
    inner join   I_PartFuncByPartDetnProced as function       on schema.pargr = function.PartnerDeterminationProcedure
//    left outer join tpaum as partnerfunction on partnerfunction.parvw = function.parvw

//                          and partnerfunction.spras = $session.system_language

    inner join   tpar  as functiondetail on function.PartnerFunction = functiondetail.parvw

  association [0..1] to I_PartnerFunctionText    as _PartnerFunctionText    on  _PartnerFunctionText.PartnerFunction = $projection.PartnerFunction //function.parvw to be tried by new field exposure

                                                                            and _PartnerFunctionText.Language        = $session.system_language
  association [0..1] to I_PartnerTypeText        as _PartnerTypeText        on  _PartnerTypeText.PurchasingDocumentPartnerType = $projection.PurchasingDocumentPartnerType
                                                                            and _PartnerTypeText.Language                      = $session.system_language

  association [0..1] to I_PurchasingDocumentType as _PurchasingDocumentType on  _PurchasingDocumentType.PurchasingDocumentType     = $projection.PurchasingDocumentType
                                                                            and _PurchasingDocumentType.PurchasingDocumentCategory = 'K'

{
      //    key schema.bstyp as PurchasingDocumentCategory,

      @ObjectModel.foreignKey.association: '_PurchasingDocumentType'
      @Search: { defaultSearchElement: true, ranking: #HIGH }
  key schema.bsart         as PurchasingDocumentType,

      @UI.hidden: true
  key schema.pargr         as PartnerSchema,

      @ObjectModel.text.element: ['PartnerFunctionName']
      @Search: { defaultSearchElement: true, ranking: #HIGH }
      @UI.hidden: true
  key function.PartnerFunction  as PartnerFunction,
  //key  coalesce(partnerfunction.parvw , function.parvw) as PartnerFunction, 

  
    // partnerfunction.pabez as PartnerFunction1,

      @EndUserText.label: 'Partner Function'
      function._PartnerFunction._PartnerFunctionLangDepdnt[Language=$session.system_language].PartnerFunctionLanguageDepdnt,
      
      @Semantics.text: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      _PartnerFunctionText.PartnerFunctionName,

      @UI.hidden: true
      functiondetail.stein as PartnerFunctionIsUnique,
      
      @ObjectModel.text.element: ['PurgDocumentPartnerTypeName']
      @Search: { defaultSearchElement: true, ranking: #HIGH }
      functiondetail.nrart as PurchasingDocumentPartnerType,

      @Semantics.text: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      _PartnerTypeText.PurgDocumentPartnerTypeName,

      _PurchasingDocumentType

}
where
  schema.bstyp = 'K'