I_ProjectNetworkBasicData

@AbapCatalog.sqlViewName: 'IPROJNTWKBASDAT'
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.representativeKey: 'ProjectNetwork'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_MRPController']
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Project Network Basic Data'
@Metadata.ignorePropagatedAnnotations:true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Analytics: {
      dataCategory: #DIMENSION,
      internalName: #LOCAL,
      dataExtraction.enabled: true
}
@Metadata.allowExtensions: true

define view I_ProjectNetworkBasicData
  as select from afko
    inner join   aufk on afko.aufnr = aufk.aufnr
  association [0..1] to I_OrderType                    as _OrderType                    on  $projection.ProjectNetworkType = _OrderType.OrderType
  association [0..1] to I_ProjectBasicData             as _Project                      on  $projection.ProjectInternalID = _Project.ProjectInternalID
  association [1..1] to I_OrderCategory                as _OrderCategory                on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [1..1] to I_NetworkActivityByInternalKey as _NetworkActivityByInternalKey on  $projection.SuperiorProjectNetworkIntID    = _NetworkActivityByInternalKey.ProjectNetworkInternalID
                                                                                        and $projection.SuperiorNtwkActivityInternalID = _NetworkActivityByInternalKey.NetworkActivityInternalID
  association [1..1] to I_Plant                        as _Plant                        on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Prioritycode                 as _PriorityCode                 on  $projection.PriorityCode = _PriorityCode.PriorityCode
  association [0..1] to I_ControllingArea              as _ControllingArea              on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BusinessArea                 as _BusinessArea                 on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..*] to I_ProfitCenter                 as _ProfitCenter                 on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                        and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..1] to I_MRPController                as _MRPController                on  $projection.Plant         = _MRPController.Plant
                                                                                        and $projection.MRPController = _MRPController.MRPController
  // Multi language Short text

  association [0..1] to I_ProjectObjectShortText       as _NetworkShortText             on  _NetworkShortText.Language                     = $session.system_language
                                                                                        and _NetworkShortText.ProjectApplicationIdentifier = 'PS'
                                                                                        and _NetworkShortText.ProjectObjectType            = 'NP'
                                                                                        and $projection.ProjectNetworkObject               = _NetworkShortText.ProjectObjectNode


  association [0..1] to I_ProjectData_2                as _ProjectData                  on  $projection.ProjectInternalID = _ProjectData.ProjectInternalID
  association [0..1] to I_WBSElementData_2             as _WBSElementData               on  $projection.WBSElementInternalID = _WBSElementData.WBSElementInternalID
  association [1..1] to E_LogisticsOrder               as _Extension                    on  $projection.ProjectNetwork = _Extension.OrderID

{
  key afko.aufnr                                       as ProjectNetwork,
      afko.aufpl                                       as ProjectNetworkInternalID,
      afko.plart                                       as ProdAvailyCheckPlanningType,
      cast( afko.pronr as ps_pspnr )                   as ProjectInternalID,
      @ObjectModel.foreignKey.association: '_OrderCategory'
      aufk.autyp                                       as OrderCategory,
      aufk.kokrs                                       as ControllingArea,
      aufk.auart                                       as ProjectNetworkType,
      @Semantics.text: true
      cast(aufk.ktext as pph_auftext preserving type)  as ProjectNetworkDescription,
      afko.aufnt                                       as SuperiorProjectNetwork,
      afko.aufpt                                       as SuperiorProjectNetworkIntID,
      afko.aplzt                                       as SuperiorNtwkActivityInternalID,
      aufk.kdauf                                       as SalesOrder,
      aufk.kdpos                                       as SalesOrderItem,
      aufk.bukrs                                       as CompanyCode,
      aufk.gsber                                       as BusinessArea,
      cast(aufk.pspel as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      aufk.objnr                                       as ProjectNetworkObject,
      aufk.prctr                                       as ProfitCenter,
      afko.gstrp                                       as PlannedStartDate,
      afko.gltrp                                       as PlannedEndDate,
      afko.gstrs                                       as ScheduledBasicStartDate,
      afko.gltrs                                       as ScheduledBasicEndDate,
      afko.gstri                                       as ActualStartDate,
      afko.getri                                       as ActualEndDate,
      afko.aprio                                       as PriorityCode,
      aufk.loekz                                       as IsMarkedForDeletion,
      afko.gstpp                                       as ForecastedStartDate,
      afko.gltpp                                       as ForecastedEndDate,
      afko.gstps                                       as ScheduledForecastedStartDate,
      afko.gltps                                       as ScheduledForecastedEndDate,
      aufk.erdat                                       as CreationDate,
      aufk.ernam                                       as CreatedByUser,
      aufk.aedat                                       as LastChangeDate,
      aufk.kostl                                       as CostCenter,
      cast(afko.ftrms as fis_co_ftrms)                 as ScheduledReleaseDate,
      aufk.kostv                                       as ResponsibleCostCenter,
      aufk.werks                                       as Plant,
      afko.dispo                                       as MRPController,
      afko.profid                                      as NetworkProfile,
      afko.ftrps                                       as ScheduledFcstdReleaseDate,
      afko.ftrmi                                       as ActualReleasedDate,
      afko.terkz                                       as BasicSchedulingType,
      afko.redkz                                       as BasicSchedulingReductionLevel, //Reduction Indicator for Scheduling (Basic)

      afko.trkzp                                       as ForecastSchedulingType,
      afko.rdkzp                                       as FcstSchedulingReductionLevel, //Reduction Indicator for Scheduling (Forecast)

      @Semantics.booleanIndicator: true
      afko.nauterm                                     as OrdIsNotSchedldAutomatically,
      afko.kbed                                        as CapacityRqmtHasNotToBeCreated, //Indicator: Calculate capacity requirements

      afko.breaks                                      as SchedulingIsAllowingForBreaks, // Indicator:  Scheduling allowing for breaks

      aufk.func_area                                   as FunctionalArea,
      cast(aufk.scope as pph_scope preserving type)    as ControllingObjectClass,
      aufk.txjcd                                       as TaxJurisdiction,
      aufk.waers                                       as Currency,
      afko.plgrp                                       as ResponsiblePlannerGroup,
      afko.aennr                                       as ChangeNumber,
      aufk.vname                                       as JointVenture,
      aufk.recid                                       as JointVentureRecoveryCode,
      aufk.etype                                       as JointVentureEquityType,
      aufk.otype                                       as JointVentureObjectType,
      aufk.jv_jibcl                                    as JointVentureClass,
      aufk.jv_jibsa                                    as JointVentureSubClass,
      aufk.jv_oco                                      as JointVentureOriginalCostObject,
      afko.gmein                                       as BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      afko.gamng                                       as PlannedTotalQty, // Execution Factor

      aufk.kalsm                                       as CostingSheet,
      afko.klvarp                                      as PlannedCostsCostingVariant,
      afko.klvari                                      as ActualCostsCostingVariant,
      aufk.zschl                                       as OverheadCode,
      afko.nopcost                                     as PlannedCostsAreNotCalculated,
      @Semantics.booleanIndicator: true
      afko.naucost                                     as OrderIsNotCostedAutomatically,
      afko.costupd                                     as OrderCostsAreUpdated,
      afko.no_disp                                     as ProjNtwkIsRlvtForMatlPlng,

      // Administr.

      aufk.aenam                                       as LastChangedByUser,
      aufk.aezeit                                      as LastChangeTime,

      // Other Fields

      @Semantics.booleanIndicator: true
      case when afko.netzkont = '1' then
        'X'
      else
        ' '
      end                                              as NetworkIsAccountAssigned,
      aufk.order_proc_mode                             as ProcurementMode,
      aufk.aufk_status                                 as StatusCombinationCode,

      _ProjectData,
      _WBSElementData,
      _OrderType,
      _OrderCategory,
      _Project,
      _NetworkActivityByInternalKey,
      _Plant,
      _PriorityCode,
      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _ProfitCenter,
      _MRPController,
      //Multi Language Short text

      _NetworkShortText
}
where
  aufk.autyp = '20'