I_ProductionModelOperation

@EndUserText.label: 'Production Model Operation'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}

define view entity I_ProductionModelOperation
  as select from           P_ProdnModBOOOperation        as BOOOpBasic
    inner join             I_ProdnModBOOVersBOMAssgmt    as BOOVersion           on  BOOVersion.BillOfOperationsType    = BOOOpBasic.BillOfOperationsType
                                                                                 and BOOVersion.BillOfOperationsGroup   = BOOOpBasic.BillOfOperationsGroup
                                                                                 and BOOVersion.BillOfOperationsVariant = BOOOpBasic.BillOfOperationsVariant
                                                                                 and BOOVersion.BillOfOperationsVersion = BOOOpBasic.BillOfOperationsVersion
    inner join             I_ProductionModelBasic        as ProductionModel      on  ProductionModel.BillOfOperationsType    = BOOVersion.BillOfOperationsType
                                                                                 and ProductionModel.BillOfOperationsGroup   = BOOVersion.BillOfOperationsGroup
                                                                                 and ProductionModel.BillOfOperationsVariant = BOOVersion.BillOfOperationsVariant
    left outer to one join P_ProdnModOperationWorkCenter as ProdnModOpWorkCenter on  ProdnModOpWorkCenter.WorkCenterTypeCode   = BOOOpBasic.WorkCenterTypeCode
                                                                                 and ProdnModOpWorkCenter.WorkCenterInternalID = BOOOpBasic.WorkCenterInternalID
    left outer to one join I_BOOOperationChgStOANBasic   as BOOOpChgStOANBasic   on  BOOOpChgStOANBasic.BillOfOperationsType        = BOOOpBasic.BillOfOperationsType
                                                                                 and BOOOpChgStOANBasic.BillOfOperationsGroup       = BOOOpBasic.BillOfOperationsGroup
                                                                                 and BOOOpChgStOANBasic.BOOOperationInternalID      = BOOOpBasic.BOOOperationInternalID
                                                                                 and BOOOpChgStOANBasic.BOOOpInternalVersionCounter = BOOOpBasic.BOOOpInternalVersionCounter
                                                                                 and BOOOpChgStOANBasic.BillOfOperationsVersion     = BOOOpBasic.BillOfOperationsVersion
    left outer to one join I_BillOfOperations            as BOORoutingTemplate   on  BOORoutingTemplate.BillOfOperationsType    = BOOOpChgStOANBasic.ShopFloorRtgTmplTaskListType
                                                                                 and BOORoutingTemplate.BillOfOperationsGroup   = BOOOpChgStOANBasic.ShopFloorRtgTemplateGroup
                                                                                 and BOORoutingTemplate.BillOfOperationsVariant = BOOOpChgStOANBasic.ShopFloorRtgTemplateGrpVariant
  association [0..1] to I_WorkCenterTextBySemanticKey  as _WorkCenterText                on  $projection.BOOOperationPlant = _WorkCenterText.Plant
                                                                                         and $projection.WorkCenter        = _WorkCenterText.WorkCenter
                                                                                         and _WorkCenterText.Language      = $session.system_language
  association [0..1] to I_OperationControlProfileText  as _ControlProfileText            on  $projection.OperationControlProfile = _ControlProfileText.OperationControlProfile
                                                                                         and _ControlProfileText.Language        = $session.system_language
  association [0..1] to I_Plant                        as _Plant                         on  $projection.BOOOperationPlant = _Plant.Plant
  association [0..1] to I_LeadTimeReducnStrategyText   as _LeadTimeReductionStrategyText on  $projection.LeadTimeReductionStrategy   = _LeadTimeReductionStrategyText.LeadTimeReductionStrategy
                                                                                         and $projection.Plant                       = _LeadTimeReductionStrategyText.Plant
                                                                                         and _LeadTimeReductionStrategyText.Language = $session.system_language
  association [0..1] to I_EmployeeWageGroupText        as _EmployeeWageGroupText         on  $projection.EmployeeWageGroup   = _EmployeeWageGroupText.EmployeeWageGroup
                                                                                         and $projection.Plant               = _EmployeeWageGroupText.Plant
                                                                                         and _EmployeeWageGroupText.Language = $session.system_language
  association [0..1] to I_OperationSetupTypeText       as _OperationSetupTypeText        on  $projection.OperationSetupType   = _OperationSetupTypeText.OperationSetupType
                                                                                         and $projection.Plant                = _OperationSetupTypeText.Plant
                                                                                         and _OperationSetupTypeText.Language = $session.system_language
  association [0..1] to I_OperationSetupGroupCatText   as _OperationSetupGroupCatText    on  $projection.OperationSetupGroupCategory = _OperationSetupGroupCatText.OperationSetupGroupCategory
                                                                                         and $projection.Plant                       = _OperationSetupGroupCatText.Plant
                                                                                         and _OperationSetupGroupCatText.Language    = $session.system_language
  association [0..1] to I_OperationSetupGroupText      as _OperationSetupGroupText       on  $projection.OperationSetupGroup         = _OperationSetupGroupText.OperationSetupGroup
                                                                                         and $projection.OperationSetupGroupCategory = _OperationSetupGroupText.OperationSetupGroupCategory
                                                                                         and $projection.Plant                       = _OperationSetupGroupText.Plant
                                                                                         and _OperationSetupGroupText.Language       = $session.system_language
  association [0..1] to I_MaintOrdOpCompCostRelevancyT as _CostRelevancyText             on  $projection.OperationCostingRelevancyType = _CostRelevancyText.CostingRelevantDescription
                                                                                         and _CostRelevancyText.Language               = $session.system_language
  association [0..1] to I_User                         as _CreatedByUser                 on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _ChangedByUser                 on  $projection.LastChangedByUser = _ChangedByUser.UserID
  association [0..*] to I_ProductionModel              as _ProductionModel               on  $projection.ProductionModelUUID     = _ProductionModel.ProductionModelUUID
                                                                                         and $projection.BillOfOperationsVersion = _ProductionModel.BillOfOperationsVersion
  association [0..*] to I_ProdnModOperationActivity    as _OperationActivity             on  $projection.ProductionModelUUID     = _OperationActivity.ProductionModelUUID
                                                                                         and $projection.BillOfMaterial          = _OperationActivity.BillOfMaterial
                                                                                         and $projection.BillOfMaterialVariant   = _OperationActivity.BillOfMaterialVariant
                                                                                         and $projection.BillOfMaterialCategory  = _OperationActivity.BillOfMaterialCategory
                                                                                         and $projection.Plant                   = _OperationActivity.Plant
                                                                                         and $projection.BillOfOperationsType    = _OperationActivity.BillOfOperationsType
                                                                                         and $projection.BillOfOperationsGroup   = _OperationActivity.BillOfOperationsGroup
                                                                                         and $projection.BillOfOperationsVariant = _OperationActivity.BillOfOperationsVariant
                                                                                         and $projection.BillOfOperationsVersion = _OperationActivity.BillOfOperationsVersion
                                                                                         and $projection.BOOOperationInternalID  = _OperationActivity.BOOOperationInternalID
  association [0..*] to I_ProdnModOperationComponent   as _OperationComponent            on  $projection.ProductionModelUUID         = _OperationComponent.ProductionModelUUID
                                                                                         and $projection.BillOfOperationsVersion     = _OperationComponent.BillOfOperationsVersion
                                                                                         and $projection.BillOfMaterial              = _OperationComponent.BillOfMaterial
                                                                                         and $projection.BillOfMaterialVariant       = _OperationComponent.BillOfMaterialVariant
                                                                                         and $projection.BillOfMaterialCategory      = _OperationComponent.BillOfMaterialCategory
                                                                                         and $projection.Plant                       = _OperationComponent.Plant
                                                                                         and $projection.BillOfOperationsType        = _OperationComponent.BillOfOperationsType
                                                                                         and $projection.BillOfOperationsGroup       = _OperationComponent.BillOfOperationsGroup
                                                                                         and $projection.BillOfOperationsVariant     = _OperationComponent.BillOfOperationsVariant
                                                                                         and $projection.BOOOperationInternalID      = _OperationComponent.BOOOperationInternalID
  association [1..1] to I_OperationControlProfile      as _OperationControlProfile       on  $projection.OperationControlProfile = _OperationControlProfile.OperationControlProfile
  association [0..1] to I_BOOOperationOvrlpngText      as _ProdnModelBOOOpOvrlpngText    on  $projection.BOOOperationOverlapping  = _ProdnModelBOOOpOvrlpngText.BOOOperationOverlapping
                                                                                         and _ProdnModelBOOOpOvrlpngText.Language = $session.system_language
  association [0..1] to I_PurchasingOrganization       as _PurchasingOrganization        on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_MaterialGroupText            as _MaterialGroupText             on  $projection.MaterialGroup   = _MaterialGroupText.MaterialGroup
                                                                                         and _MaterialGroupText.Language = $session.system_language
  association [0..1] to I_PurchasingGroup              as _PurchasingGroup               on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_Supplier                     as _Supplier                      on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_CurrencyText                 as _OpExtProcessingCurrencyText   on  $projection.OpExternalProcessingCurrency = _OpExtProcessingCurrencyText.Currency
                                                                                         and _OpExtProcessingCurrencyText.Language    = $session.system_language

  association [0..1] to I_InspectionLotTypeText        as _InspectionLotTypeText         on  $projection.InspectionLotType = _InspectionLotTypeText.InspectionLotType
  association [0..1] to I_PurchasingGroup              as _PurchasingGroupText           on  $projection.PurchasingGroup = _PurchasingGroupText.PurchasingGroup
{

  key       ProductionModel.ProductionModelUUID,
  key       BOOVersion.BillOfOperationsVersion,
  key       BOOOpBasic.BOOOperationInternalID,
            BOOOpBasic.BOOOpInternalVersionCounter,
            cast( ProductionModel.BillOfMaterial as cs_stlnr )  as BillOfMaterial,
            ProductionModel.BillOfMaterialVariant,
            ProductionModel.BillOfMaterialCategory,
            ProductionModel.BillOfMaterialVariantUsage,
            ProductionModel.Plant,
            ProductionModel.BillOfOperationsGroup,
            ProductionModel.BillOfOperationsType,
            ProductionModel.BillOfOperationsVariant,
            BOOOpBasic.OperationExternalID,
            cast(BOOOpBasic.Operation_2 as mpe_vdm_rtg_operation preserving type ) as Operation,
            cast(BOOOpBasic.OperationText as mpe_ltxa1 preserving type ) as OperationText,
            BOOOpBasic.LongTextLanguageCode,
            BOOOpBasic.WorkCenterTypeCode,
            BOOOpBasic.WorkCenterInternalID,
            ProdnModOpWorkCenter.WorkCenter,
            cast (BOOOpBasic.Plant as werks_d preserving type ) as BOOOperationPlant,
            @ObjectModel.foreignKey.association: '_OperationControlProfile'
            BOOOpBasic.OperationControlProfile,
            @Semantics.quantity.unitOfMeasure: 'OperationUnit'
            BOOOpBasic.OperationReferenceQuantity,
            BOOOpBasic.OperationUnit,
            @Semantics.quantity.unitOfMeasure: 'BillOfOperationsBreakDurnUnit'
            BOOOpBasic.BillOfOperationsBreakDuration,
            BOOOpBasic.BillOfOperationsBreakDurnUnit,
            BOOOpBasic.BusinessProcess,
            BOOOpBasic.LeadTimeReductionStrategy,
            BOOOpBasic.TeardownAndWaitIsParallel,
            @Semantics.quantity.unitOfMeasure: 'MinimumWaitDurationUnit'
            BOOOpBasic.MinimumWaitDuration,
            BOOOpBasic.MinimumWaitDurationUnit,
            @Semantics.quantity.unitOfMeasure: 'MaximumWaitDurationUnit'
            BOOOpBasic.MaximumWaitDuration,
            BOOOpBasic.MaximumWaitDurationUnit,
            @Semantics.quantity.unitOfMeasure: 'MinimumQueueDurationUnit'
            BOOOpBasic.MinimumQueueDuration,
            BOOOpBasic.MinimumQueueDurationUnit,
            @Semantics.quantity.unitOfMeasure: 'StandardQueueDurationUnit'
            BOOOpBasic.StandardQueueDuration,
            BOOOpBasic.StandardQueueDurationUnit,
            @Semantics.quantity.unitOfMeasure: 'MinimumMoveDurationUnit'
            BOOOpBasic.MinimumMoveDuration,
            BOOOpBasic.MinimumMoveDurationUnit,
            @Semantics.quantity.unitOfMeasure: 'StandardMoveDurationUnit'
            BOOOpBasic.StandardMoveDuration,
            BOOOpBasic.StandardMoveDurationUnit,
            ProdnModOpWorkCenter.WorkCenterStdQueueDurnUnit,
            @Semantics.quantity.unitOfMeasure: 'WorkCenterStdQueueDurnUnit'
            ProdnModOpWorkCenter.WorkCenterStandardQueueDurn,
            ProdnModOpWorkCenter.WorkCenterMinimumQueueDurnUnit,
            @Semantics.quantity.unitOfMeasure: 'WorkCenterMinimumQueueDurnUnit'
            ProdnModOpWorkCenter.WorkCenterMinimumQueueDuration,
            BOOOpBasic.OperationSplitIsRequired,
            BOOOpBasic.MaximumNumberOfSplits,
            @Semantics.quantity.unitOfMeasure: 'MinProcessingDurnPerSplitUnit'
            BOOOpBasic.MinProcessingDurationPerSplit,
            BOOOpBasic.MinProcessingDurnPerSplitUnit,
            cast ( case when BOOOpBasic.OperationOverlappingIsRequired = 'X'
                    then '1'
                    when BOOOpBasic.OperationOverlappingIsPossible = 'X'
                    then '2'
                    when BOOOpBasic.OperationsIsAlwaysOverlapping = 'X'
                    then '3'
                    else '' end as mpe_rtg_op_overlapping )     as BOOOperationOverlapping,
            BOOOpBasic.OperationOverlappingIsRequired,
            BOOOpBasic.OperationOverlappingIsPossible,
            BOOOpBasic.OperationsIsAlwaysOverlapping,
            @Semantics.quantity.unitOfMeasure: 'OverlapMinimumDurationUnit'
            BOOOpBasic.OverlapMinimumDuration,
            BOOOpBasic.OverlapMinimumDurationUnit,
            @Semantics.quantity.unitOfMeasure: 'OverlapMinimumTransferQtyUnit'
            BOOOpBasic.OverlapMinimumTransferQty,
            BOOOpBasic.OverlapMinimumTransferQtyUnit,
            BOOOpBasic.OperationScrapPercent,
            ProdnModOpWorkCenter.NmbrOfTimeTicketsIsReferenced,
            ProdnModOpWorkCenter.NumberOfConfSlipsIsReferenced,
            ProdnModOpWorkCenter.EmployeeWageGroupIsReferenced,
            ProdnModOpWorkCenter.EmployeeWageTypeIsReferenced,
            ProdnModOpWorkCenter.WorkCenterSetpTypeIsReferenced,
            cast ( case ProdnModOpWorkCenter.NmbrOfTimeTicketsIsReferenced
            when 'X' then ProdnModOpWorkCenter.NumberOfTimeTickets
            else BOOOpBasic.NumberOfTimeTickets
            end as lohnanz preserving type )                    as NumberOfTimeTickets,
            cast( case ProdnModOpWorkCenter.NumberOfConfSlipsIsReferenced
            when 'X' then ProdnModOpWorkCenter.NumberOfConfirmationSlips
            else BOOOpBasic.NumberOfConfirmationSlips
            end as cr_rs_anz preserving type )                  as NumberOfConfirmationSlips,
            cast ( case ProdnModOpWorkCenter.EmployeeWageGroupIsReferenced
            when 'X' then ProdnModOpWorkCenter.EmployeeWageGroup
            else BOOOpBasic.EmployeeWageGroup
            end as lohngrp preserving type )                    as EmployeeWageGroup,
            cast ( case ProdnModOpWorkCenter.EmployeeWageTypeIsReferenced
            when 'X' then ProdnModOpWorkCenter.EmployeeWageType
            else BOOOpBasic.EmployeeWageType
            end as lohnart preserving type )                    as EmployeeWageType,
            BOOOpBasic.NumberOfEmployees,
            cast( case ProdnModOpWorkCenter.WorkCenterSetpTypeIsReferenced
            when 'X' then ProdnModOpWorkCenter.WorkCenterSetupType
            else BOOOpBasic.OperationSetupType
            end as ruearschlu preserving type )                 as OperationSetupType,
            BOOOpBasic.OperationSetupGroupCategory,
            BOOOpBasic.OperationSetupGroup,
            BOOOpBasic.OperationCostingRelevancyType,
            ProdnModOpWorkCenter.StandardWorkFormulaParamName1,
            ProdnModOpWorkCenter.StandardWorkFormulaParamName2,
            ProdnModOpWorkCenter.StandardWorkFormulaParamName3,
            ProdnModOpWorkCenter.StandardWorkFormulaParamName4,
            ProdnModOpWorkCenter.StandardWorkFormulaParamName5,
            ProdnModOpWorkCenter.StandardWorkFormulaParamName6,
            @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
            BOOOpBasic.StandardWorkQuantity1,
            @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit2'
            BOOOpBasic.StandardWorkQuantity2,
            @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit3'
            BOOOpBasic.StandardWorkQuantity3,
            @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit4'
            BOOOpBasic.StandardWorkQuantity4,
            @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit5'
            BOOOpBasic.StandardWorkQuantity5,
            @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit6'
            BOOOpBasic.StandardWorkQuantity6,
            BOOOpBasic.StandardWorkQuantityUnit1,
            BOOOpBasic.StandardWorkQuantityUnit2,
            BOOOpBasic.StandardWorkQuantityUnit3,
            BOOOpBasic.StandardWorkQuantityUnit4,
            BOOOpBasic.StandardWorkQuantityUnit5,
            BOOOpBasic.StandardWorkQuantityUnit6,
            ProdnModOpWorkCenter.CostCtrActyType1IsReferenced,
            ProdnModOpWorkCenter.CostCtrActyType2IsReferenced,
            ProdnModOpWorkCenter.CostCtrActyType3IsReferenced,
            ProdnModOpWorkCenter.CostCtrActyType4IsReferenced,
            ProdnModOpWorkCenter.CostCtrActyType5IsReferenced,
            ProdnModOpWorkCenter.CostCtrActyType6IsReferenced,
            cast( case ProdnModOpWorkCenter.CostCtrActyType1IsReferenced
            when 'X' then ProdnModOpWorkCenter.CostCtrActivityType1
            else BOOOpBasic.CostCtrActivityType1
            end as lstar preserving type )                      as CostCtrActivityType1,
            cast( case ProdnModOpWorkCenter.CostCtrActyType2IsReferenced
            when 'X' then ProdnModOpWorkCenter.CostCtrActivityType2
            else BOOOpBasic.CostCtrActivityType2
            end as lstar preserving type )                      as CostCtrActivityType2,
            cast( case ProdnModOpWorkCenter.CostCtrActyType3IsReferenced
            when 'X' then ProdnModOpWorkCenter.CostCtrActivityType3
            else BOOOpBasic.CostCtrActivityType3
            end as lstar preserving type )                      as CostCtrActivityType3,
            cast( case ProdnModOpWorkCenter.CostCtrActyType4IsReferenced
            when 'X' then ProdnModOpWorkCenter.CostCtrActivityType4
            else BOOOpBasic.CostCtrActivityType4
            end as lstar preserving type )                      as CostCtrActivityType4,
            cast( case ProdnModOpWorkCenter.CostCtrActyType5IsReferenced
            when 'X' then ProdnModOpWorkCenter.CostCtrActivityType5
            else BOOOpBasic.CostCtrActivityType5
            end as lstar preserving type )                      as CostCtrActivityType5,
            cast( case ProdnModOpWorkCenter.CostCtrActyType6IsReferenced
            when 'X' then ProdnModOpWorkCenter.CostCtrActivityType6
            else BOOOpBasic.CostCtrActivityType6
            end as lstar preserving type )                      as CostCtrActivityType6,
            BOOOpBasic.PurchasingInfoRecord,
            BOOOpBasic.PurchaseContract,
            BOOOpBasic.PurchasingInfoRecdAddlGrpgName,
            BOOOpBasic.MaterialGroup,
            BOOOpBasic.PurchasingGroup,
            BOOOpBasic.Supplier,
            BOOOpBasic.PlannedDeliveryDuration,
            BOOOpBasic.NumberOfOperationPriceUnits,
            @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
            BOOOpBasic.OpExternalProcessingPrice,
            BOOOpBasic.InspectionLotType,
            BOOOpBasic.PurchasingOrganization,
            BOOOpBasic.PurchaseContractItem,
            BOOOpBasic.CostElement,
            BOOOpBasic.OpExternalProcessingCurrency,
            BOOOpChgStOANBasic.GoodsRecipientName,
            BOOOpChgStOANBasic.UnloadingPointName,
            BOORoutingTemplate.ShopFloorRoutingTemplateType,
            BOOOpChgStOANBasic.ShopFloorRtgTemplateGroup,
            BOOOpChgStOANBasic.ShopFloorRtgTemplateGrpVariant,
            BOOOpChgStOANBasic.ShopFloorRtgTemplateVersion,
            @Semantics.user.createdBy: true
            BOOOpBasic.CreatedByUser,
            @Semantics.systemDate.createdAt: true
            BOOOpBasic.CreationDate,
            @Semantics.user.lastChangedBy: true
            BOOOpBasic.LastChangedByUser,
            @Semantics.systemDate.lastChangedAt: true
            BOOOpBasic.LastChangeDate,

            _WorkCenterText,
            _ControlProfileText,
            _Plant,
            _LeadTimeReductionStrategyText,
            _EmployeeWageGroupText,
            _OperationSetupTypeText,
            _OperationSetupGroupCatText,
            _OperationSetupGroupText,
            _CostRelevancyText,
            _CreatedByUser,
            _ChangedByUser,
            _ProductionModel,
            _OperationActivity,
            _OperationComponent,
            _OperationControlProfile,
            _ProdnModelBOOOpOvrlpngText,
            _PurchasingOrganization,
            _MaterialGroupText,
            _PurchasingGroup,
            _Supplier,
            _OpExtProcessingCurrencyText,
            _InspectionLotTypeText,
            _PurchasingGroupText

}
where
  ProductionModel.ProdnModComplexAssemblyType <> 'MA';