I_ProdnVersTP

@AbapCatalog.sqlViewName: 'IPRODNVERSTP'
@EndUserText.label: 'Manage Production Version'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #TRANSACTIONAL
@Search.searchable:true
@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #XL}

@ObjectModel: { semanticKey: ['MaterialForEdit', 'PlantForEdit', 'ProductionVersionForEdit' ],
                transactionalProcessingEnabled: true,
                compositionRoot: true,
                createEnabled,
                deleteEnabled,
                updateEnabled,
                draftEnabled: true,      -- Draft enablement
                writeDraftPersistence: 'MPEPRODNVERSD', -- Draft persistence
                entityChangeStateId: 'LastChangeDate'
                }

define view I_ProdnVersTP
  as select from           I_ProductionVersion

  association [0..*] to I_ProdnVersRtgBOMVersTP as _ProdnVersRtgBOMVers on  $projection.Material          = _ProdnVersRtgBOMVers.Material
                                                                        and $projection.Plant             = _ProdnVersRtgBOMVers.Plant
                                                                        and $projection.ProductionVersion = _ProdnVersRtgBOMVers.ProductionVersion
  association        to I_UnitizedMaterial      as _UnitizedMaterial    on  $projection.Material = _UnitizedMaterial.Material
  association [0..1] to I_ProductPlantBasic     as _ProductPlantBasic   on  $projection.Plant    = _ProductPlantBasic.Plant
                                                                        and $projection.Material = _ProductPlantBasic.Product
{
  key   I_ProductionVersion.Material,
  key   I_ProductionVersion.Plant,
        @ObjectModel.readOnly: true
  key   I_ProductionVersion.ProductionVersion,
        I_ProductionVersion.BillOfOperationsGroup,
        I_ProductionVersion.BillOfOperationsVariant,
        I_ProductionVersion.BillOfMaterialVariantUsage,
        I_ProductionVersion.BillOfMaterialVariant,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        I_ProductionVersion.Material          as MaterialForEdit,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        I_ProductionVersion.Plant             as PlantForEdit,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        I_ProductionVersion.ProductionVersion as ProductionVersionForEdit,
        _ProductPlantBasic.MRPResponsible     as MRPController,
        I_ProductionVersion.ValidityEndDate,
        I_ProductionVersion.ValidityStartDate,
        I_ProductionVersion.BillOfOperationsType,
        I_ProductionVersion.ProductionLine,
        I_ProductionVersion.ProductionVersionGroup,
        @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
        I_ProductionVersion.ProductionVersionText,
        I_ProductionVersion.QuantityDistributionKey,
        @VDM.lifecycle.status: #DEPRECATED
        @VDM.lifecycle.successor: 'I_ProductionVersion.QuantityDistributionKey'
        I_ProductionVersion.DistributionKey,
        I_ProductionVersion.ProdnVersIsAllowedForRptvMfg,
        I_ProductionVersion.MaterialMinLotSizeQuantity,
        I_ProductionVersion.MaterialMaxLotSizeQuantity,
        I_ProductionVersion.ReceivingStorageLocation,
        I_ProductionVersion.MaterialCostApportionmentStruc,
        I_ProductionVersion.MainProduct,
        I_ProductionVersion.IssuingStorageLocation,
        I_ProductionVersion.ProductionSupplyArea,
        I_ProductionVersion.ProductionVersionStatus,
        I_ProductionVersion.ProductionVersionLastCheckDate,
        I_ProductionVersion.ProductionVersionIsLocked,
        I_ProductionVersion.RateBasedPlanningStatus,
        I_ProductionVersion.PreliminaryPlanningStatus,
        I_ProductionVersion.BOMCheckStatus,
        I_ProductionVersion.OriginalBatchReferenceMaterial,
        I_ProductionVersion.ChangeHistoryCount,
        I_ProductionVersion.ChangeNumber,
        I_ProductionVersion.CreationDate,
        I_ProductionVersion.CreatedByUser,
        I_ProductionVersion.LastChangeDate,
        I_ProductionVersion.LastChangedByUser,
        cast( ' ' as boole_d)                 as CheckStatus,
        I_ProductionVersion.HasVersionCtrldBOMAndRouting,
        I_ProductionVersion.PlanningAndExecutionBOMIsDiff,
        I_ProductionVersion.ExecBillOfMaterialVariant,
        I_ProductionVersion.ExecBillOfMaterialVariantUsage,
        I_ProductionVersion.ExecBillOfOperationsType,
        I_ProductionVersion.ExecBillOfOperationsGroup,
        I_ProductionVersion.ExecBillOfOperationsVariant,
        I_ProductionVersion.Warehouse         as EWMWarehouse,
        I_ProductionVersion.DestinationStorageBin,
        @ObjectModel.readOnly: true
        I_ProductionVersion.MaterialBaseUnit,
        I_ProductionVersion.ConfigblProdProductionVersion,
        _ProductPlantBasic.ConfigurableProduct,

        @ObjectModel.readOnly: true
        case
          when _UnitizedMaterial.EffectivityType is not null
            then  cast('X' as mpe_cima_untz_matl_ind_type preserving type )
          else cast('' as mpe_cima_untz_matl_ind_type preserving type )
        end                                   as IsMaterialUnitized,

        _BillOfOperationsType,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        _ProdnVersRtgBOMVers

}