I_ProdnModRefChangeRecord

DDL: I_PRODNMODREFCHANGERECORD Type: view_entity COMPOSITE

Reference Change Records

I_ProdnModRefChangeRecord is a Composite CDS View that provides data about "Reference Change Records" in SAP S/4HANA. It reads from 4 data sources (I_ChangeRecordBsc, I_ChgRecdRefRoutingBsc, I_ChangeRecordType, I_ProductionModel) and exposes 14 fields with key fields ProductionModelUUID, BillOfOperationsVersion, ChangeRecordUUID.

4 data source(s) 14 fields

Data Sources (4)

SourceAliasJoin Type
I_ChangeRecordBsc ChangeRecord inner
I_ChgRecdRefRoutingBsc ChangeRecordRefRouting from
I_ChangeRecordType ChangeRecordType inner
I_ProductionModel ProductionModel inner

Annotations (7)

NameValueLevelField
EndUserText.label Reference Change Records view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #COMPOSITE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY ProductionModelUUID I_ProductionModel ProductionModelUUID
KEY BillOfOperationsVersion I_ProductionModel BillOfOperationsVersion
KEY ChangeRecordUUID I_ChgRecdRefRoutingBsc ChangeRecordUUID
ChangeRecord I_ChangeRecordBsc ChangeRecord
ChangeRecordType I_ChangeRecordBsc ChangeRecordType
ChangeRecordTypeDesc I_ChangeRecordType ChangeRecordTypeDesc
ChgRecordDescriptionText
ChangeRecordStatus I_ChangeRecordBsc ChangeRecordStatus
BillOfOperationsType I_ProductionModel BillOfOperationsType
BillOfOperationsGroup I_ProductionModel BillOfOperationsGroup
BillOfOperationsVariant I_ProductionModel BillOfOperationsVariant
BillOfMaterialCategory I_ProductionModel BillOfMaterialCategory
BillOfMaterialVariantUsage I_ProductionModel BillOfMaterialVariantUsage
Plant I_ProductionModel Plant 
@EndUserText.label: 'Reference Change Records'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity I_ProdnModRefChangeRecord
  as select from           I_ChgRecdRefRoutingBsc     as ChangeRecordRefRouting
    left outer to one join I_ProductionRoutingVersion as Routing          on  ChangeRecordRefRouting.ChgRecRefInternalKey1 = Routing.BillOfOperationsGroup
                                                                          and ChangeRecordRefRouting.ChgRecRefInternalKey2 = Routing.BillOfOperationsType
                                                                          and ChangeRecordRefRouting.ChgRecRefInternalKey3 = Routing.BillOfOperationsVariant
                                                                          and ChangeRecordRefRouting.ChgRecRefInternalKey4 = Routing.BillOfOperationsVersion
    inner join             I_ProductionModel          as ProductionModel  on  ProductionModel.BillOfOperationsGroup   = Routing.BillOfOperationsGroup
                                                                          and ProductionModel.BillOfOperationsType    = Routing.BillOfOperationsType
                                                                          and ProductionModel.BillOfOperationsVariant = Routing.BillOfOperationsVariant
                                                                          and ProductionModel.BillOfOperationsVersion = Routing.BillOfOperationsVersion
    inner join             I_ChangeRecordBsc          as ChangeRecord     on ChangeRecord.ChangeRecordUUID = ChangeRecordRefRouting.ChangeRecordUUID
    inner join             I_ChangeRecordType         as ChangeRecordType on ChangeRecord.ChangeRecordType = ChangeRecordType.ChangeRecordType
{
  key ProductionModel.ProductionModelUUID,
  key ProductionModel.BillOfOperationsVersion,
  key ChangeRecordRefRouting.ChangeRecordUUID,
      ChangeRecord.ChangeRecord,
      ChangeRecord.ChangeRecordType,
      @Semantics.text: true
      ChangeRecordType.ChangeRecordTypeDesc,
      @Semantics.text: true
      ChangeRecord._Text[ 1: Language = $session.system_language].ChgRecordDescriptionText,
      ChangeRecord.ChangeRecordStatus,
      ProductionModel.BillOfOperationsType,
      ProductionModel.BillOfOperationsGroup,
      ProductionModel.BillOfOperationsVariant,
      ProductionModel.BillOfMaterialCategory,
      ProductionModel.BillOfMaterialVariantUsage,
      ProductionModel.Plant


}

Learn More