I_ProdSpecDescription

@AbapCatalog.sqlViewName: 'IPRODSPECDESC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Product Specification Description'

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

define view I_ProdSpecDescription
  as select from(
                 I_SpecIdentifier           as SpecIdentifier
      inner join I_SpecIdnListingDefinition as ListingCust on  ListingCust.SpecificationIdnListing     = 'D_DEFAULT'
                                                           and ListingCust.SpecificationIdnListingPrio = '0001'
                                                           and ListingCust.SpecificationIdnListingPos  = '0002'
                                                           and ListingCust.SpecificationCategory       = ''
                                                           and ListingCust.SpecIdfgDescCategory        = SpecIdentifier.SpecIdfgDescCategory
                                                           and ListingCust.SpecIdfgDescType            = SpecIdentifier.SpecIdfgDescType
      inner join I_ProdSpecNonHistoric      as ProdSpec    on ProdSpec.ProductSpecificationInternalID = SpecIdentifier.SpecificationInternalID
  )

  association [1..*] to I_ProductSpecification    as _ProductSpecification    on _ProductSpecification.ProductSpecificationInternalID = $projection.ProductSpecificationInternalID
  association [1..1] to I_ProdSpecNonHistoric     as _ProdSpecNonHistoric     on _ProdSpecNonHistoric.ProductSpecificationInternalID = $projection.ProductSpecificationInternalID
  association [1..1] to I_ProdSpecDescNonHistoric as _ProdSpecDescNonHistoric on _ProdSpecDescNonHistoric.ProdSpecDescriptionInternalID = $projection.ProdSpecDescriptionInternalID
{

  key cast( SpecIdfgDescInternalID as /plmb/spc_ident_int_id preserving type )            as ProdSpecDescriptionInternalID,
  key cast( SpecIdfgDescChangeState as /plmb/spc_ident_chg_state preserving type )        as ProdSpecDescriptionChangeState,

      cast( SpecificationInternalID as /plmb/spc_prod_int_id preserving type )            as ProductSpecificationInternalID,

      cast( SpecIdfgDescLanguage as /plmb/spc_ident_langu preserving type )               as ProdSpecDescriptionLanguage,
      cast( SpecIdfgDescText as /plmb/spc_ident_text preserving type )                    as ProdSpecDescription,

      cast( SpecIdfgDescValidityStartDate as /plmb/spc_ident_valid_from preserving type ) as ProdSpecDescValidityStartDate,
      cast( SpecIdfgDescValidityEndDate as /plmb/spc_ident_valid_to preserving type )     as ProdSpecDescValidityEndDate,
      cast( SpecIdfgDescChangeNumber as /plmb/spc_changenumber_api_ext preserving type )  as ProdSpecDescChangeNumber,

      SpecIdfgDescIsDeleted                                                               as ProdSpecDescIsDeleted,

      _ProductSpecification,
      _ProdSpecNonHistoric,
      _ProdSpecDescNonHistoric

}