I_ProdPlntInptAssistant

@AbapCatalog.sqlViewName: 'IPRDPLNTIA'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Input Assistance for Product Plant'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory : #L
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics:{
    dataExtraction: {
        enabled: true
    }
}
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #EXTRACTION_DATA_SOURCE
]
define view I_ProdPlntInptAssistant
  as select from v_marc_md
    inner join   mara on mara.matnr = v_marc_md.matnr
  association [1..1] to I_UnitOfMeasure      as _BaseUnitOfMeasure     on $projection.BaseUnit = _BaseUnitOfMeasure.UnitOfMeasure
  association [0..*] to I_UnitOfMeasureText  as _BaseUnitOfMeasureText on $projection.BaseUnit = _BaseUnitOfMeasureText.UnitOfMeasure
  association [1..1] to I_Producttype        as _ProductType           on $projection.ProductType = _ProductType.ProductType
  association [0..*] to I_ProductTypeText    as _ProductTypeName       on $projection.ProductType = _ProductTypeName.ProductType
  association [0..1] to I_ProductGroup_2     as _ProductGroup          on $projection.ProductGroup = _ProductGroup.ProductGroup
  association [0..*] to I_ProductGroupText_2 as _ProductGroupText      on $projection.ProductGroup = _ProductGroupText.ProductGroup
{
  key  mara.matnr      as Product,
  key  v_marc_md.werks as Plant,

       @ObjectModel.foreignKey.association: '_ProductType'
       mtart           as ProductType,
       _ProductType,
       _ProductTypeName,

       @ObjectModel.foreignKey.association: '_ProductGroup'
       matkl           as ProductGroup,
       _ProductGroup,
       _ProductGroupText,

       @ObjectModel.foreignKey.association: '_BaseUnitOfMeasure'
       @Semantics.unitOfMeasure: true
       meins           as BaseUnit,
       _BaseUnitOfMeasure,
       _BaseUnitOfMeasureText,

       begru           as AuthorizationGroup,

       dismm           as MRPType,
       dispo           as MRPController,
       disgr           as MRPGroup,
       disls           as LotSizingProcedure,

       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       bstmi           as MinimumLotSizeQuantity,
       fxhor           as PlanningTimeFence,
       shzet           as SafetyDuration,
       webaz           as GoodsReceiptDuration

}