I_ProdCmplncPhrsTxtWthFallback

@AbapCatalog: {
  sqlViewName: 'IPHRSTXTFB',
  compiler.compareFilter: true,
  preserveKey: true }

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Text for every Phrase in every Language'

@ObjectModel: {
  usageType: {
    serviceQuality: #A,
    sizeCategory:  #L,
    dataClass: #MASTER },
  dataCategory: #TEXT,
  representativeKey: 'ProdCmplncPhrsUUID' }

@VDM.viewType: #COMPOSITE

define view I_ProdCmplncPhrsTxtWthFallback
  as select from P_ProdCmplncPhrsTxtWthFallback
{
      /**** Keys ****/

  key ProdCmplncPhrsUUID                   as ProdCmplncPhrsUUID,

      //      //Needed for VDM conformity - a text node needs the language as a key field - Is it an issue if we leave it out?

      //      @Semantics.language: true

      //  key cast($session.system_language as langu preserving type )                       as Language,



      /**** Content ****/

      @Semantics.text: true
      cast(
        case
          when ProdCmplncPhrsCode is initial
            then ProdCmplncPhrsText
          when ProdCmplncPhrsCode is not initial
            then concat('(', concat(ProdCmplncPhrsCode, concat_with_space(')', cast(ProdCmplncPhrsText as ehfnd_description_xxl), 1)))
        end
      // There might be a bit of text which is cut of with this cast. We can't work around this, as the case can't result in anything longer.

      // Currently we can not change this as...

      // 1.) Result of Concat Operation has a maximum length of 1333

      // 2.) Cast from Char to String or SString is not supported

      // 3.) Maximum lentgth of CDS-Char-Fields is 1333

      as ehfnd_phrs_text preserving type ) as ProdCmplncPhrsText,

      ProdCmplncPhrs                       as ProdCmplncPhrs,
      ProdCmplncPhrsCode                   as ProdCmplncPhrsCode,
      ProdCmplncPhrsILLText                as ProdCmplncPhrsILLText,
      ProdCmplncPhrsEnglishText            as ProdCmplncPhrsEnglishText
}