I_ProdCmplncEventProcStatusTxt

DDL: I_PRODCMPLNCEVENTPROCSTATUSTXT Type: view BASIC

View Product Cmplnc Events Proc Sts Txt

I_ProdCmplncEventProcStatusTxt is a Basic CDS View that provides data about "View Product Cmplnc Events Proc Sts Txt" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 4 fields with key fields ProdCmplncEventProcgStatus, Language. It has 2 associations to related views.

1 data source(s) 4 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_Language _Language $projection.Language = _Language.Language
[1..1] ehfndv_dummy _Constants _Constants.dummy = _Constants.dummy

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName IPCEPROCSTSTXT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label View Product Cmplnc Events Proc Sts Txt view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey ProdCmplncEventProcgStatus view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #META view
Search.searchable true view
VDM.viewType #BASIC view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY ProdCmplncEventProcgStatus
KEY Language dd07t ddlanguage
ProdCmplncEventProcgStsText dd07t ddtext
_Language _Language 
@AbapCatalog: {
  sqlViewName: 'IPCEPROCSTSTXT',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'View Product Cmplnc Events Proc Sts Txt'

@ObjectModel: {
  dataCategory: #TEXT,
  representativeKey: 'ProdCmplncEventProcgStatus',
  usageType:{ serviceQuality: #C,
                sizeCategory: #S,
                   dataClass: #META
            }
}
@Search.searchable: true
@VDM.viewType: #BASIC

define view I_ProdCmplncEventProcStatusTxt
  as select from dd07t
  association [1..1] to I_Language   as _Language  on $projection.Language = _Language.Language
  // Associate the database view as the constant-views are COMPOSITE and CONSUMPTION and this is a basic view

  association [1..1] to ehfndv_dummy as _Constants on _Constants.dummy = _Constants.dummy

{
      /****  Keys  ****/
  key cast(dd07t.domvalue_l as ehfnd_pce_evt_proc_stat ) as ProdCmplncEventProcgStatus,

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key dd07t.ddlanguage                                   as Language,


      /****  Content  ****/
      @Semantics.text:true
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8      
      dd07t.ddtext                                       as ProdCmplncEventProcgStsText,

      case dd07t.domvalue_l
        when _Constants[inner].constantevtstsnew        then _Constants[inner].constant0 // "New" -> neutral

        when _Constants[inner].constantevtstserror      then _Constants[inner].constant2 // "Error" -> yellow

        when _Constants[inner].constantevtstsfatal      then _Constants[inner].constant1 // "Fatal Error" -> red

        when _Constants[inner].constantevtstsinprogress then _Constants[inner].constant2 // "In Progress" -> yellow

        when _Constants[inner].constantevtstscompleted  then _Constants[inner].constant3 // "Completed" -> green

      end                                                as ProdCmplncEventProcgStsCritlty,

      /****  Associations  ****/
      _Language
}
where
      dd07t.domname  = 'EHFND_PCE_EVT_PROC_STAT'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

Learn More