I_PaymentBatchHasAlertText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@EndUserText.label: 'Payment Batch Has Alert - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'PaymentBatchHasAlert'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
define view entity I_PaymentBatchHasAlertText 
  as select from dd07t
  association to parent I_PaymentBatchHasAlert as _PaymentBatchHasAlert
    on $projection.PaymentBatchHasAlert = _PaymentBatchHasAlert.PaymentBatchHasAlert
  association [0..1] to I_Language as _Language      
    on $projection.Language = _Language.Language  
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @ObjectModel.foreignKey.association: '_PaymentBatchHasAlert'
      @ObjectModel.text.element: ['PaymentBatchHasAlertName']
      @Semantics.booleanIndicator
  key cast( dd07t.domvalue_l as farp_bnk_com_payt_alert ) as PaymentBatchHasAlert,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as payt_batch_has_alert_name preserving type ) as PaymentBatchHasAlertName,
      _PaymentBatchHasAlert,
      _Language
} 
where dd07t.domname  = 'PAYMENTBATCHHASALERT'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'