I_PaRealignment

@AbapCatalog.sqlViewName: 'IPAREALGNMT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED 
@EndUserText.label: 'CO-PA Realignment'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
define view I_PaRealignment as select from I_PaRealignmentLog 
inner join I_PaRealignmentHistory on I_PaRealignmentLog.RealignmentRun = I_PaRealignmentHistory.RealignmentRun
inner join I_GLAccountLineItem on 
  I_GLAccountLineItem.Ledger             = I_PaRealignmentHistory.Ledger
                            and I_GLAccountLineItem.CompanyCode        = I_PaRealignmentHistory.CompanyCode
                            and I_GLAccountLineItem.FiscalYear         = I_PaRealignmentHistory.FiscalYear
                            and I_GLAccountLineItem.AccountingDocument = I_PaRealignmentHistory.AccountingDocument
                            and I_GLAccountLineItem.LedgerGLLineItem   = I_PaRealignmentHistory.LedgerGLLineItem  
                                                    
association [0..1] to I_WBSElement         as _WBSElement                              on $projection.WBSElement        = _WBSElement.WBSElement

{
key I_GLAccountLineItem.SourceLedger,
key I_GLAccountLineItem.Ledger as Ledger,
    key I_GLAccountLineItem.CompanyCode as CompanyCode,
    key I_GLAccountLineItem.FiscalYear as FiscalYear, 
    key I_GLAccountLineItem.AccountingDocument as AccountingDocument, 
    key I_GLAccountLineItem.LedgerGLLineItem as LedgerGLLineItem,
    key I_PaRealignmentLog.RealignmentRun as RealignmentRun,
    I_GLAccountLineItem.ProfitCenter as ProfitCenter,
    I_PaRealignmentLog.RealignmentRunEndDate as RealignmentRunEndDate,
    I_PaRealignmentLog.RealignmentRunEndTime as RealignmentRunEndTime,
    I_GLAccountLineItem.FiscalPeriod as FiscalPeriod,
    I_GLAccountLineItem.PostingDate as PostingDate,
//    I_GLAccountLineItem.FinancialTransactionType as FinancialTransactionType,

    I_GLAccountLineItem.BusinessTransactionType as BusinessTransactionType,
    @DefaultAggregation: #SUM
    @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
    I_GLAccountLineItem.AmountInBalanceTransacCrcy as AmountInBalanceTransacCrcy,
    @Semantics.currencyCode:true
    I_GLAccountLineItem.BalanceTransactionCurrency as BalanceTransactionCurrency,
    @DefaultAggregation: #SUM
    @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
    I_GLAccountLineItem.AmountInCompanyCodeCurrency as AmountInCompanyCodeCurrency,
    @Semantics.currencyCode:true
    I_GLAccountLineItem.CompanyCodeCurrency as CompanyCodeCurrency,
    @DefaultAggregation: #SUM
    @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
    I_GLAccountLineItem.AmountInGlobalCurrency as AmountInGlobalCurrency,
    @Semantics.currencyCode:true
    I_GLAccountLineItem.GlobalCurrency as GlobalCurrency,
    I_GLAccountLineItem.GLAccount as GLAccount,
    I_GLAccountLineItem.FunctionalArea as FunctionalArea,
    I_GLAccountLineItem.Segment as Segment,
    I_GLAccountLineItem.AccountingDocumentType as AccountingDocumentType,
    I_GLAccountLineItem.Supplier as  Supplier,
     I_GLAccountLineItem.ControllingArea as ControllingArea,
    
   I_PaRealignmentHistory.RealgnmtPrevSoldMaterial as RealgnmtPrevSoldMaterial,
   I_GLAccountLineItem.SoldProduct as SoldMaterial,
   
   I_PaRealignmentHistory.RealgnmtPrevBillgDocType as RealgnmtPrevBillgDocType,
   I_GLAccountLineItem.BillingDocumentType as BillingDocumentType,
   
   I_PaRealignmentHistory.RealgnmtPrevCustomerGroup as RealgnmtPrevCustomerGroup,
   I_GLAccountLineItem.CustomerGroup as CustomerGroup,
   
   I_PaRealignmentHistory.RealgnmtPrevCustSuplrCntry as RealgnmtPrevCustSuplrCntry,
   I_GLAccountLineItem.CustomerSupplierCountry as CustomerSupplierCountry,
   
   I_PaRealignmentHistory.RealgnmtPrevMaterialGroup as RealgnmtPrevMaterialGroup,
   I_GLAccountLineItem.SoldProductGroup as MaterialGroup,
 
   I_PaRealignmentHistory.RealgnmtPrevSalesOrganization as RealgnmtPrevSalesOrganization,
   I_GLAccountLineItem.SalesOrganization as SalesOrganization,
   
   I_PaRealignmentHistory.RealgnmtPrevDistrChannel as RealgnmtPrevDistrChannel,
   I_GLAccountLineItem.DistributionChannel as DistributionChannel,
   
   I_PaRealignmentHistory.RealgnmtPrevPlant as RealgnmtPrevPlant,
   I_GLAccountLineItem.Plant as Plant,
   
   I_PaRealignmentHistory.RealgnmtPrevSalesOrder as RealgnmtPrevSalesOrder,
   I_GLAccountLineItem.SalesOrder as SalesOrder,
   
   I_PaRealignmentHistory.RealgnmtPrevSalesOrderItem as RealgnmtPrevSalesOrderItem,
   I_GLAccountLineItem.SalesOrderItem as SalesOrderItem,
   
   I_PaRealignmentHistory.RealgnmtPrevCustomer as RealgnmtPrevCustomer,
   I_GLAccountLineItem.Customer as Customer,
   
   I_PaRealignmentHistory.RealgnmtPrevOrderID as RealgnmtPrevOrderID,
   I_GLAccountLineItem.OrderID as OrderID,
   
   I_PaRealignmentHistory.RealgnmtPrevSalesDistrict as RealgnmtPrevSalesDistrict,
   I_GLAccountLineItem.SalesDistrict as SalesDistrict,
   
   I_PaRealignmentHistory.RealgnmtPrevShipToParty as RealgnmtPrevShipToParty,
   I_GLAccountLineItem.ShipToParty as ShipToParty,
   
   I_PaRealignmentHistory.RealgnmtPrevBillToParty as RealgnmtPrevBillToParty,
   I_GLAccountLineItem.BillToParty as BillToParty,
   
   I_PaRealignmentHistory.RealgnmtPrevOrgDivision as RealgnmtPrevOrgDivision,
   I_GLAccountLineItem.OrganizationDivision as OrganizationDivision,
   
   @ObjectModel.foreignKey.association: '_WBSElementInternalID'
   I_GLAccountLineItem.WBSElementInternalID as WBSElementInternalID,
   
   I_PaRealignmentHistory.RealgnmtPrevWBSElement as RealgnmtPrevWBSElement,
   @ObjectModel.foreignKey.association: '_WBSElement'
   _WBSElementInternalID.WBSElement as WBSElement,
//   I_GLAccountLineItem.WBSElement as WBSElement,

   
   I_PaRealignmentHistory.RealgnmtPrevCostObject as RealgnmtPrevCostObject,
   I_GLAccountLineItem.CostObject as CostObject,
   
   I_PaRealignmentHistory.RealgnmtPrevCostCenter as RealgnmtPrevCostCenter,
   I_GLAccountLineItem.CostCenter as CostCenter,
   
   _WBSElementInternalID,
   _WBSElement,
 
   1 as NmbrOfRealignedJrnlEntryItems
   
   
   

   
   
}