I_PT_SelfBillgCustAddrVers

@AbapCatalog.sqlViewName: 'IPTSBADRVERS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('BLOCKED_DATA_INCLUDED')
@EndUserText.label: 'PT Self-Billing CustAddr Version'
define view I_PT_SelfBillgCustAddrVers
  as select from    I_PT_SelfBillgDgtlSgntr        as Signature

    inner join      I_SupplierInvoiceItemPurOrdRef as Item    on  Signature.SupplierInvoice = Item.SupplierInvoice
                                                              and Signature.FiscalYear      = Item.FiscalYear
    inner join      I_Plant                        as Plant   on Item.Plant = Plant.Plant

    left outer join I_PT_CustomerAddressVersion    as Version on Plant.PlantCustomer                           =  Version.Customer
                                                              and(
                                                                Signature.PortugueseDigitalSignatureDate       >  Version.PortugueseDigitalSignatureDate
                                                                or(
                                                                  Signature.PortugueseDigitalSignatureDate     =  Version.PortugueseDigitalSignatureDate
                                                                  and Signature.PortugueseDigitalSignatureTime >= Version.PortugueseDigitalSignatureTime
                                                                )
                                                              )
{
  key Item.FiscalYear                                                       as   FiscalYear,
  key Item.SupplierInvoice                                                  as   SupplierInvoice,
  key Plant.PlantCustomer                                                   as   PlantCustomer,

      Signature.CompanyCode                                                 as   CompanyCode,

      Signature.Supplier                                                    as   Supplier,

      cast(max(Version.PortugueseCustomerVersion) as sipt_data_version)     as   PortugueseCustomerVersion,

      /* Associations */
      //FOR DPP AUTHORIZATION CHECK

      Plant._Customer,
      Signature._Supplier

}
group by
  Item.FiscalYear,
  Item.SupplierInvoice,
  Plant.PlantCustomer,
  CompanyCode,
  Supplier;