I_PPM_ProjectTaskTP

@AbapCatalog.sqlViewName: 'IPPMPROJTASKTP'
@AbapCatalog.compiler.compareFilter: true
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Milestone Information - transac. proc.'
@ObjectModel:
  {  
    writeDraftPersistence: 'PPM_PRO_TASK_D',
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    semanticKey:  [ 'TaskName' ],
    usageType:
    {
      serviceQuality: #C, 
      sizeCategory: #L,
      dataClass: #TRANSACTIONAL
    }
  } 

define view I_PPM_ProjectTaskTP
  as select from I_PPM_ProjectTask
  association [1..1] to I_PPM_ProjectTP              as _Root                      on $projection.ProjectUUID = _Root.ProjectUUID
  association [1..1] to I_PPM_ProjectTaskJVATP       as _JointVentureAccounting    on $projection.TaskUUID = _JointVentureAccounting.TaskUUID
 
  association [1..1] to I_PPM_ProjTaskPublicSectorTP as _PublicSector              on $projection.TaskUUID = _PublicSector.TaskUUID
  
  association [0..1] to I_EntProjElmntBlockFuncTP    as _BlockFunc                 on $projection.TaskUUID = _BlockFunc.TaskUUID
  
  association [1..1] to I_EntProjElmntLongTextTP     as _LongText                  on $projection.TaskUUID = _LongText.TaskUUID 
  
  ---Extension Association
  association [1..1] to E_PPM_Task                   as _ProjectBriefTaskExtension on $projection.TaskUUID = _ProjectBriefTaskExtension.TaskUUID
 
{ 
      @ObjectModel.readOnly: true
  key TaskUUID,

      //@ObjectModel.readOnly: true

      ExternalId, // obselete, do not use !!


      @ObjectModel.readOnly: true
      Task,
      @ObjectModel.readOnly: true
      ProjectInternalID,

      @ObjectModel.readOnly: true
      WBSElementInternalID,

      @ObjectModel.readOnly: true
      ProjectUUID,
      
      TaskTemplateUUID, 

      MilestoneName, // obselete, do not use !!


      TaskName,
      PlannedStartDate,
      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      PlannedEndDate,

      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      ForecastedEndDate,
      
      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      ActualStartDate,
      
      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      ActualEndDate,

      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      IsMainMilestone,

      TaskType,
   
      ProcessingStatus,

      MilestoneApprovalStatus,
      //2102 Enterprise project multiple so items

      EntProjIsMultiSlsOrdItmsEnbld,   
      @ObjectModel.readOnly: false // just to make sure BOPF generates this correctly, based on a discussioni with IVO, BOPF only honors what is in here

      IsProjectMilestone,

      @ObjectModel.readOnly: true
      WBSElement,
      @ObjectModel.readOnly: true
      WBSDescription,
      @ObjectModel.readOnly: true
      CompanyCode,
      @ObjectModel.readOnly: true
      ControllingArea,
      @ObjectModel.readOnly: true
      FunctionalArea,
      @ObjectModel.readOnly: true
      ProfitCenter,
      @ObjectModel.readOnly: true
      ResponsibleCostCenter,
      @ObjectModel.readOnly: true
      Plant,
      @ObjectModel.readOnly: true
      Location,
      @ObjectModel.readOnly: true
      FactoryCalendar,
      @ObjectModel.readOnly: true
      CostingSheet,
      @ObjectModel.readOnly: true
      CostCenter,
      @ObjectModel.readOnly: true
      InvestmentProfile,
      @ObjectModel.readOnly: true
      WBSIsStatisticalWBSElement,

      ParentObjectUUID,
      SortingNumber,
      ActiveTaskUUID,
      
      
      // 2105 include - flags for copying demands and settlement rules 

      cast ( '' as boole_d preserving type ) as EntProjElmntDmndCpyIsReqd,
      cast ( '' as boole_d preserving type ) as EntProjElmntSettlmtCpyIsReqd,
      
      // Tax Jurisdiction & Functional Location

      @ObjectModel.readOnly: true
      TaxJurisdiction,
      @ObjectModel.readOnly: true
      FunctionalLocation,
      //S/4H 2002 Billing element indicator

      @Feature: 'BF:IDEA_EPPM_MULTI_BILLING_ENABLEMENT'
      WBSElementIsBillingElement,
//      CE2208 Hierarchical settlement changes

      EntProjectSettlementElement,
      EntProjIsSettlmtRuleInherited,
//      result analysis key changes

      @Feature: 'PM_CIE_EPPM_MEDIA_PROJ_RAKEY'
      ResultAnalysisInternalID,
      @Feature: 'BF:JOINT_VENTURE_ACCOUNTING, IDEA_EPPM_JVA_ENABLEMENT'
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _JointVentureAccounting,
      
      @Feature: 'BF:PSM_BUDGET_ACCOUNTING_CONTROL, EPPM_PUBLIC_SECTOR'
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PublicSector,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _BlockFunc,
      
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ] 
      _LongText, 
      
      CreatedByUser,

      CreationDateTime,

      LastChangedByUser,

      LastChangeDateTime,
      _MilestoneApprovalStatus,
      _MilestoneApprovalStatusText,
      // No need, can use I_EnterpriseProjElmntHier

      //      _TaskHierarchy,

      _ProjectRoot,

      // Assoziations for Auth-check

      _AuthUser,
      _AuthSubst,
      _AuthRole,
      _AuthGroup,

      _I_Project,
      _ProjObjRoot,

      _CompanyCode,
      _ControllingArea,
      _FunctionalArea,
      _ProfitCenter,
      _Plant,
      _ResponsibleCostCenter,
      _FactoryCalendar,
      _CostCenter,
      _ProcessingStatus,


      _CreatedByUser,
      _LastChangedByUser,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _Root

}