I_PPM_Note

@EndUserText.label: 'Note'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IPPMNOTE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.representativeKey: 'ReferencedObjectUUID'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_PPM_Note
  as select from P_PPM_Note
    left outer join /s4ppm/cds_dummy on /s4ppm/cds_dummy.dummy_char = P_PPM_Note.TextObjectKeyString //Workaround to get string field where we can put the notetext in, because cast to string is not supported in CDS at the moment.

    left outer join I_EPPMGlobalSetting as _GlobalSetting on _GlobalSetting.EPPMUsageArea = '0007' and _GlobalSetting.EPPMGlobalSettingsCode = '0053'
    // associations to authorization views

    association [0..*] to I_PPM_AuthznByUsrH        as _AuthUser
            on      _AuthUser.ReferencedObjectUUID   = $projection.ReferencedNodeUUID
             and    _AuthUser.UserID                 = $session.user
             and (  _AuthUser.Activity = 'Admin'     or _AuthUser.Activity = 'Write'      or _AuthUser.Activity = 'Read' )
    association [0..*] to I_PPM_AuthznBySubstitH    as _AuthSubst
            on      _AuthSubst.ReferencedObjectUUID  = $projection.ReferencedNodeUUID
             and    _AuthSubst.UserID                = $session.user
             and (  _AuthSubst.Activity = 'Admin'    or _AuthSubst.Activity = 'Write'     or _AuthSubst.Activity = 'Read' )
    association [0..*] to I_PPM_AuthznByUserRoleH   as _AuthRole
            on      _AuthRole.ReferencedObjectUUID   = $projection.ReferencedNodeUUID
             and    _AuthRole.UserID                 = $session.user
             and (  _AuthRole.Activity = 'Admin'     or _AuthRole.Activity = 'Write'      or _AuthRole.Activity = 'Read' )
    association [0..*] to I_PPM_AuthznByUsrGrpH     as _AuthGroup
            on      _AuthGroup.ReferencedObjectUUID  = $projection.ReferencedNodeUUID
             and    _AuthGroup.UserID                = $session.user
             and (  _AuthGroup.Activity = 'Admin'    or _AuthGroup.Activity = 'Write'     or _AuthGroup.Activity = 'Read' )
{
  key P_PPM_Note.TextObjectKeyString            as ReferencedObjectUUID,
      /* Empty fields need to be filled in DPC_EXT */
  key cast(111111 as dpr_tv_api_integer)                                         as NoteID,
      cast('' as /s4ppm/tv_created_by)                                           as CreatedByUser,
      cast('' as dpr_tv_api_full_name)                                           as CreatedByUserFullName,
      cast(cast('19900101000000' as abap.dec( 15, 0 )) as /s4ppm/tv_created_on ) as CreationDateTime,
      /s4ppm/cds_dummy.dummy_string                                              as NoteText,

      hextobin(P_PPM_Note.TextObjectKeyString)   as ReferencedNodeUUID,
      _GlobalSetting.EPPMSettingsDefaultValue,

      _AuthUser,
      _AuthSubst,
      _AuthRole,
      _AuthGroup
}