I_NotificationType

@AbapCatalog.sqlViewName: 'INOTIFTYPE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE 

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@EndUserText.label: 'Notification Type'
@ObjectModel:{
    usageType:{
        dataClass: #CUSTOMIZING,
        serviceQuality: #A,
        sizeCategory: #S
    },
    representativeKey: 'NotificationType'
}
@Metadata.ignorePropagatedAnnotations: true

define view I_NotificationType as select from tq80 

    association[0..*] to I_NotificationTypeName as _NotificationTypeName on $projection.NotificationType = _NotificationTypeName.NotificationType
{
    
    @ObjectModel.text.association: '_NotificationTypeName'
    key qmart   as NotificationType,
    qmnuk       as NumberRange,
    herkz       as NotificationOrigin,
    
    cast( parvw_kund as vdm_q_parvw_kund preserving type ) as NotifPartnerFuncCustomer,  
    cast( parvw_ap   as vdm_q_parvw_ap   preserving type ) as NotifPartnerFuncContactPerson,  
    cast( parvw_int  as vdm_q_parvw_int  preserving type ) as NotifPrtnFuncImplementingDept,  
    cast( parvw_lief as vdm_q_parvw_lief preserving type ) as NotifPartnerFuncSupplier,  
    cast( parvw_her  as vdm_q_parvw_her  preserving type ) as NotifPartnerFuncManufacturer,  
    cast( parvw_vera as vdm_q_parvw_vera preserving type ) as NotifPartnerRoleResponsible,  
    cast( parvw_auto as vdm_q_parvw_auto preserving type ) as NotifPartnerFuncAuthor,  
    cast( parvw_qmsm as vdm_q_parvw_qmsm preserving type ) as NotifPartnerFuncTask,
//    cast( parvw_page as vdm_q_parvw_page preserving type ) as NotifPartnerFuncPaging,

    cast( parvw_geh  as vdm_q_parvw_geh  preserving type ) as NotifPartnerFuncApprover,
    
    _NotificationTypeName
    
}