I_MfgOrderSystemStatusText

@AccessControl.authorizationCheck: #MANDATORY
@Analytics.technicalName: 'IMFGORDSYSTSTXT'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order System Status - Text'
// Concatenates the language-dependent order header system status names to one CHAR40 element (similar to CAUFVD-STTXT)

// according to TJ04-LINEP and -STATP of SAP's standard delivery (as in client 100). Only statuses listed in that table

// with positions (LINEP) 1 up to 10 are considered for this CDS view.  

// Statuses which are not listed in standard TJ04 content are NOT considered here!


  define view entity I_MfgOrderSystemStatusText
    with parameters 
    @Environment.systemField : #SYSTEM_LANGUAGE
    P_Language : sylangu
    as select from  P_MfgOrderSystemStatusText(P_Language : $parameters.P_Language)
      
    association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      // Key

      @ObjectModel.text.element: ['MfgOrderSystemStatusText']
  key ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast($parameters.P_Language as spras preserving type) as Language,

      @ObjectModel.text.element: ['MfgOrderSystemStatusText']
      ObjectInternalID,
      -- for DCLS
      @Consumption.hidden : true
      ManufacturingOrderCategory,
      @Consumption.hidden : true
      ManufacturingOrderType,
      @Consumption.hidden : true
      ProductionPlant,
      
      // System status

      @Semantics.text: true
      cast( concat_with_space( Text1, concat_with_space( Text2, concat_with_space( Text3, concat_with_space( Text4, concat_with_space( Text5, concat_with_space( Text6, 
            concat_with_space( Text7, concat_with_space( Text8, concat_with_space( Text9, Text10, 1), 1), 1) ,1) ,1), 1), 1) , 1) ,1 ) 
        as co_sttxt) as MfgOrderSystemStatusText,

      // Associations

      _Language
};