I_MfgOrderItemWithStatus

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_MRPController', '_ProductionSupervisor']
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@Analytics.technicalName: 'IMFGORDITEMWSTS'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'ManufacturingOrderItem'
@ObjectModel.semanticKey: ['ManufacturingOrder', 'ManufacturingOrderItem']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Item with Status'

define view entity I_MfgOrderItemWithStatus
  as select from I_ManufacturingOrderItem     as item
    inner join   P_OrderItemStatusBasicAggrgn as stat on stat.ObjectInternalID = item.ObjectInternalID  // Status


    association [0..1] to I_ProductionVersionBasic as _ProductionVersion   on  $projection.Product           = _ProductionVersion.Product
                                                                           and $projection.ProductionPlant   = _ProductionVersion.Plant
                                                                           and $projection.ProductionVersion = _ProductionVersion.ProductionVersion
    association [0..1] to I_WBSElementBasicData    as _WBSElementBasicData on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
{
      // Key

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      @ObjectModel.foreignKey.association: '_MfgOrder'
  key item.ManufacturingOrder,
  key item.ManufacturingOrderItem,

      // Category and Type

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      item.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      item.ManufacturingOrderType,

      // Attributes

      item.IsMarkedForDeletion,
      item.OrderItemIsNotRelevantForMRP,

      // System Status

      stat.OrderItemIsCreated,
      stat.OrderItemIsReleased,
      stat.OrderItemIsClosed,
      stat.OrderItemIsPartiallyDelivered,
      stat.SettlementRuleIsCreated,

      // Assignments

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductVH', element: 'Product' } } ]
      @ObjectModel.foreignKey.association: '_Product'
      item.Product,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      item.ProductionPlant,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_MRPPlant'
      item.PlanningPlant,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderMRPControllerStdVH', element: 'MRPController' } } ]
      @ObjectModel.foreignKey.association: '_MRPController'
      item.MRPController,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderProdnSupervisorStdVH', element: 'ProductionSupervisor' } } ]
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      item.ProductionSupervisor,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionVersionStdVH', element: 'ProductionVersion' } } ]
      @ObjectModel.foreignKey.association: '_ProductionVersion'
      item.ProductionVersion,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MRPAreaVH', element: 'MRPArea' } } ]
      @ObjectModel.foreignKey.association: '_MRPArea'
      cast(item.MRPArea as berid preserving type)                    as MRPArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderStdVH', element: 'SalesOrder' } } ]
      @ObjectModel.foreignKey.association: '_SalesOrder'
      item.SalesOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderItemStdVH', element: 'SalesOrderItem' } } ]
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      item.SalesOrderItem,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementInternalID' } } ]
      @ObjectModel.foreignKey.association: '_WBSElementBasicData'
      cast(item.WBSElementInternalID as ps_s4_pspnr preserving type) as WBSElementInternalID,
--    @ObjectModel.foreignKey.association: '_QuotaArrangement'
      item.QuotaArrangement,
--    @ObjectModel.foreignKey.association: '_QuotaArrangementItem'
      item.QuotaArrangementItem,
      @ObjectModel.foreignKey.association: '_SettlementReservation'
      item.SettlementReservation,
      @ObjectModel.foreignKey.association: '_SettlementReservationItem'
      item.SettlementReservationItem,
      @ObjectModel.foreignKey.association: '_CoProductReservation'
      item.CoProductReservation,
      @ObjectModel.foreignKey.association: '_CoProductReservationItem'
      item.CoProductReservationItem,
      @ObjectModel.foreignKey.association: '_MatlProcurementCategory'
      item.MaterialProcurementCategory,
      @ObjectModel.foreignKey.association: '_MatlProcurementType'
      item.MaterialProcurementType,
--    @ObjectModel.foreignKey.association: '_SerialNumberProfile'
      item.SerialNumberAssgmtProfile,
      item.NumberOfSerialNumbers,
      item.MfgOrderItemReplnmtElmntType,
      item.ProductConfiguration,
      item.ObjectInternalID,
      item.QuantityDistributionKey,
      item.EffectivityParameterVariant,

      // Goods Receipt data

      item.GoodsReceiptIsExpected,
      item.GoodsReceiptIsNonValuated,
      @ObjectModel.foreignKey.association: '_DeliveryCompletedIndicator'
      item.IsCompletelyDelivered,
      item.MaterialGoodsReceiptDuration,
      item.UnderdelivTolrtdLmtRatioInPct,
      item.OverdelivTolrtdLmtRatioInPct,
      item.UnlimitedOverdeliveryIsAllowed,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      item.StorageLocation,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BatchStdVH', element: 'Batch' } } ]
      item.Batch,
      @ObjectModel.foreignKey.association: '_InventoryValuationType'
      item.InventoryValuationType,
      item.InventoryValuationCategory,
      @ObjectModel.foreignKey.association: '_InventoryUsabilityCode'
      item.InventoryUsabilityCode,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
      item.InventorySpecialStockType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockValnType'
      item.InventorySpecialStockValnType,
      @ObjectModel.foreignKey.association: '_ConsumptionPosting'      
      item.ConsumptionPosting,
      @Semantics.text: true
      item.GoodsRecipientName,
      @Semantics.text: true
      item.UnloadingPointName,
      item.StockSegment,

      // Order Header Dates and Times

      item.MfgOrderPlannedStartDate,
      item.MfgOrderPlannedStartTime,
      item.MfgOrderScheduledStartDate,
      item.MfgOrderScheduledStartTime,
      item.MfgOrderActualStartDate,
      item.MfgOrderActualStartTime,
      item.MfgOrderPlannedEndDate,
      item.MfgOrderPlannedEndTime,
      item.MfgOrderScheduledEndDate,
      item.MfgOrderScheduledEndTime,
      item.MfgOrderConfirmedEndDate,
      item.MfgOrderConfirmedEndTime,
      item.MfgOrderActualEndDate,
      item.MfgOrderScheduledReleaseDate,
      item.MfgOrderActualReleaseDate,      

      // Order Item Dates

      item.MfgOrderItemPlannedEndDate,
      item.MfgOrderItemScheduledEndDate,
      item.MfgOrderItemPlndDeliveryDate,
      item.MfgOrderItemActualDeliveryDate,
      item.MfgOrderItemTotalCmtmtDate,

      // Item Quantities and UoM

      item.ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderItemPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderItemPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item. MfgOrderItemPlannedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderItemGoodsReceiptQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderItemActualDeviationQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderItemOpenYieldQty,

      // Header Quantities and UoM

      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderConfirmedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      item.MfgOrderPlannedScrapQty,

      // Assignments FI/CO

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      cast(item.CompanyCode as bukrs preserving type) as CompanyCode,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
      @ObjectModel.foreignKey.association: '_BusinessArea'
      item.BusinessArea,
      @ObjectModel.foreignKey.association: '_AccountAssignmentCategory'
      item.AccountAssignmentCategory,

      // Amount and Currency

      item.CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @Aggregation.default: #SUM
      item.GoodsReceiptAmountInCoCodeCrcy,

      // no longer needed but kept for compatibility

      @Consumption.hidden: true
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'OrderItemIsCreated'
      '' as OrderIsCreated,
      @Consumption.hidden: true
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'OrderItemIsReleased'
      '' as OrderIsReleased,

      // Associations

      item._MfgOrder,
      item._MfgOrderCategory,
      item._MfgOrderType,
      item._MfgOrderItemSrlNmbr,
      item._ProductionPlant,
      item._ProductionSupervisor,
      item._MRPController,
      item._MRPPlant,
      item._MRPArea,
      item._Product,
      item._ProductPlant2         as _ProductPlant,
      item._ProductPlanningPlant2 as _ProductPlanningPlant,
      item._ProductionUnit,
      _ProductionVersion,
      item._MatlProcurementCategory,
      item._MatlProcurementType,
      item._DeliveryCompletedIndicator,
      item._StorageLocation,
      item._InventorySpecialStockType,
      item._InventorySpecialStockValnType,
      item._InventoryValuationType,
      item._ConsumptionPosting,
      item._InventoryUsabilityCode,
      item._SalesOrder,
      item._SalesOrderItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_WBSElementBasicData'
      item._WBSElement,
      _WBSElementBasicData,
      item._QuotaArrangement,
      item._QuotaArrangementItem,
      item._SettlementReservation,
      item._SettlementReservationItem,
      item._CoProductReservation,
      item._CoProductReservationItem,
      item._SerialNumberProfile,
      item._CompanyCode,
      item._BusinessArea,
      item._AccountAssignmentCategory
};