I_MfgOrderForOutput

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #FACT
@Analytics.technicalName: 'IMFGORDER4OUTPUT'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order For Output'
-- CDS view for output purposes - with less associations to keep email rendering time as small as possible --

define view entity I_MfgOrderForOutput
    as select from I_ManufacturingOrder as ord
             
{
      // Key

      @ObjectModel.text.element: ['ManufacturingOrderText']
  key cast(ord.ManufacturingOrder as co_aufnr preserving type) as ManufacturingOrder,

      // Text

      @Semantics.text: true
      ord.ManufacturingOrderText,
      ord.ManufacturingOrderHasLongText,
      ord.LongTextLanguageCode,

      // Attributes

      ord.ManufacturingOrderImportance,
      @Semantics.booleanIndicator
      ord.MfgOrderHasMultipleItems,
      @Semantics.booleanIndicator
      ord.MfgOrderIsPartOfCollvOrder,
      ord.MfgOrderHierarchyLevel,

      // Admin

      ord.CreationDate,
      ord.CreationTime,
      ord.CreatedByUser,
      ord.LastChangeDate,
      ord.LastChangeTime,
      ord.LastChangedByUser,

      // Header Material data

      @ObjectModel.text.element: ['ProductName']
      ord.Product,
      @Semantics.text: true
      _Product._Text[1: Language=$session.system_language].ProductName,
      StorageLocation,
      ord.Batch,
      @Semantics.text: true
      ord.GoodsRecipientName,
      @Semantics.text: true
      ord.UnloadingPointName,
      ord.InventoryUsabilityCode,
      ord.MaterialGoodsReceiptDuration,
      ord.QuantityDistributionKey,

      // Assignments

      ord.ManufacturingOrderCategory,
      @ObjectModel.text.element: ['ManufacturingOrderTypeName']
      cast(ord.ManufacturingOrderType as aufart preserving type) as ManufacturingOrderType,
      @Semantics.text: true
      _MfgOrderType._Text[1: Language=$session.system_language].ManufacturingOrderTypeName,
      ord.SuperiorOrder,
      ord.ReferenceOrder,
      ord.LeadingOrder,

      @ObjectModel.text.element: ['ProductionPlantName']
      ord.ProductionPlant,
      @Semantics.text: true
      ord._ProductionPlant.PlantName as ProductionPlantName,
      @ObjectModel.text.element: ['PlanningPlantName']
      ord.PlanningPlant,
      @Semantics.text: true
      ord._PlanningPlant.PlantName   as PlanningPlantName,

      @ObjectModel.text.element: ['MRPAreaText']
      cast(ord.MRPArea as berid preserving type) as MRPArea,
      @Semantics.text: true
      ord._MRPArea.MRPAreaText as MRPAreaText,

      @ObjectModel.text.element: ['MRPControllerName']
      ord.MRPController,
      @Semantics.text: true
      ord._MRPController.MRPControllerName as MRPControllerName,
      @ObjectModel.text.element: ['ProductionSupervisorName']
      ord.ProductionSupervisor,
      @Semantics.text: true
      ord._ProductionSupervisor.ProductionSupervisorName as ProductionSupervisorName,
      @ObjectModel.text.element: ['MRPControllerName']
      ord.ResponsiblePlannerGroup,
      @Semantics.text: true
      ord._ResponsiblePlannerGroup.ResponsiblePlannerGroupName as ResponsiblePlannerGroupName,

      ord.ProductionSchedulingProfile,
      ord.ProductionVersion,
      ord.PlannedOrder,
      ord.SalesOrder,
      ord.SalesOrderItem,

      @ObjectModel.text.element: ['WBSDescription']
      ord._WBSElementBasicData2.WBSElementExternalID as WBSElement,
      @Semantics.text: true
      ord._WBSElementBasicData2.WBSDescription       as WBSDescription,

      ord.Reservation,
      ord.CapacityRequirement,
      ord.InspectionLot,
      ord.ChangeNumber,
      ord.BasicSchedulingType,
      ord.ForecastSchedulingType,
      ord.ObjectInternalID,
      ord.ProductConfiguration,
      ord.EffectivityParameterVariant,
      ord.ConditionApplication,
      ord.CapacityActiveVersion,
      ord.OrderSequenceNumber,
      ord.MfgOrderSplitStatus,

      // Assignments BOO

      ord.BillOfOperationsMaterial,
      ord.BillOfOperationsType,
      ord.BillOfOperationsGroup,
      ord.BillOfOperationsVariant,
      ord.BOOInternalVersionCounter,
      ord.BillOfOperationsUsage,
      ord.BillOfOperationsVersion,
      ord.BOOExplosionDate,
      ord.BOOValidityStartDate,

      // Assignments BOM

      ord.BillOfMaterialCategory,
      ord.BillOfMaterialInternalID,
      ord.BillOfMaterialVariant,
      ord.BillOfMaterialVariantUsage,
      ord.BillOfMaterialVersion,
      ord.BOMExplosionDate,
      ord.BOMValidityStartDate,

      // Assignments FI/CO

      ord.BusinessArea,
      cast(ord.CompanyCode as bukrs preserving type) as CompanyCode,
      ord.ControllingArea,
      ord.ProfitCenter,
      ord.CostCenter,
      cast(ord.ResponsibleCostCenter as pph_kostl preserving type) as ResponsibleCostCenter,
      ord.CostElement,
      ord.CostingSheet,
      ord.GLAccount,
      ord.ProductCostCollector,
      ord.ActualCostsCostingVariant,
      ord.PlannedCostsCostingVariant,
      ord.ControllingObjectClass,
      ord.FunctionalArea,

      // Floats

      ord.SchedulingFloatProfile,
      ord.FloatBeforeProductionInWrkDays,
      ord.FloatAfterProductionInWorkDays,
      ord.ReleasePeriodInWorkDays,

      // Dates

      ord.MfgOrderPlannedStartDate,
      ord.MfgOrderPlannedStartTime,
      ord.MfgOrderPlannedEndDate,
      ord.MfgOrderPlannedEndTime,
      ord.MfgOrderPlannedReleaseDate,
      ord.MfgOrderScheduledStartDate,
      ord.MfgOrderScheduledStartTime,
      ord.MfgOrderScheduledEndDate,
      ord.MfgOrderScheduledEndTime,
      ord.MfgOrderScheduledReleaseDate,
      ord.MfgOrderActualStartDate,
      ord.MfgOrderActualStartTime,
      ord.MfgOrderActualEndDate,
      ord.MfgOrderActualReleaseDate,
      ord.MfgOrderConfirmedEndDate,
      ord.MfgOrderConfirmedEndTime,
      ord.MfgOrderTotalCommitmentDate,
      ord.MfgOrderActualCompletionDate,
      ord.MfgOrderItemActualDeliveryDate,

      // Quantities and UoM

      ord.ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      ord.MfgOrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      ord.MfgOrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      ord.MfgOrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      ord.MfgOrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      ord.MfgOrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      ord.ExpectedDeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @Aggregation.default: #SUM
      ord.ActualDeliveredQuantity,
      
      // Associations

      _ProductionUnit
};