I_MfgOrdOperationPRTWithStatus

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser']
@Analytics.dataCategory: #FACT
@Analytics.technicalName: 'IMFGORDOPPRTWSTS'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Operation PRT with Status'

define view entity I_MfgOrdOperationPRTWithStatus
  as select from I_MfgOrderOperationPRT        as prt
      inner join P_OrderOpPRTStatusBasicAggrgn as stat on stat.ObjectInternalID = prt.ObjectInternalID

{
      // Key

      @ObjectModel.foreignKey.association: '_MfgOrderInternalID'
  key prt.MfgOrderInternalID,
      @ObjectModel.text.element: ['MfgOrderOpProdnRsceToolText']
  key prt.MfgOrderOpProdnRsceToolIntID,

      // Admin data

      prt.IsDeleted,
      @Semantics.systemDate.createdAt: true
      prt.CreationDate,
      @Semantics.user.createdBy: true
      prt.CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      prt.LastChangeDate,
      @Semantics.user.lastChangedBy: true
      prt.LastChangedByUser,

      // Text

      @Semantics.text: true
      prt.MfgOrderOpProdnRsceToolText,
      @ObjectModel.foreignKey.association: '_Language'
      prt.Language,

      // PRT System Status

      stat.OrderOperationPRTIsCreated,     // I0001

      stat.OrderOperationPRTIsReleased,    // I0002

      stat.OrderOperationPRTIsPrinted,     // I0007

      stat.OrderOperationPRTIsDeleted,     // I0013

      stat.OrdOperationPRTIsNotAvailable,  // I0095


      // PRT data

      @ObjectModel.foreignKey.association: '_ProductionResourceType'
      prt.ProductionResourceType,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolByInternalKey'
      prt.ProductionResourceInternalID,
      prt.ProductionResourceTool,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolCategory'      
      prt.ProdnRsceToolCategory_2 as ProdnRsceToolCategory, //   w/o conv. exit

      @ObjectModel.foreignKey.association: '_ProdnRsceToolControlProfile'
      prt.ProdnRsceToolControlProfile,
      @ObjectModel.text.element: ['MfgOrderOpProdnRsceToolText']
      prt.ProdnRsceToolItemNumber,

      // Order and Operation data

      @ObjectModel.foreignKey.association: '_MfgOrderOperation'
      prt.OrderOperationInternalID,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      @ObjectModel.foreignKey.association: '_MfgOrder'
      prt.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      prt.ManufacturingOrderSequence,
      @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemKey' 
      prt.ManufacturingOrderOperation_2 as ManufacturingOrderOperation, //   w/o conv. exit

      prt.MfgOrderOperationIsPhase,
      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      prt.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      prt.ManufacturingOrderType,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      prt.ProductionPlant,
      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      prt.OperationControlProfile,

      // BOO Data

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      prt.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      prt.BillOfOperationsGroup,

      // Dates and Times

      prt.EarliestSchedldUsageStartDate,
      prt.EarliestSchedldUsageStartTime,
      prt.EarliestSchedldUsageEndDate,
      prt.EarliestSchedldUsageEndTime,
      prt.LatestSchedldUsageStartDate,
      prt.LatestSchedldUsageStartTime,
      prt.LatestSchedldUsageEndDate,
      prt.LatestSchedldUsageEndTime,
      prt.ActualUsageStartDate,
      prt.ActualUsageStartTime,
      prt.ActualUsageEndDate,
      prt.ActualUsageEndTime,

      // Duration

      prt.ProdnRsceToolUsageDurnUnit,
      prt.ProdnRsceToolUsageDuration,

      // Quantities and UoM

      prt.ProdnRsceToolStdWorkQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ProdnRsceToolStdWorkQtyUnit'
      @Aggregation.default: #SUM
      prt.ProdnRsceToolStandardWorkQty,

      prt.PlannedProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'PlannedProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      prt.PlannedTotalProdnRsceToolQty,

      prt.ConfirmedProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfirmedProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      prt.ConfirmedProdnRsceToolQty,

      prt.RemainingProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'RemainingProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      prt.RemainingProdnRsceToolQty,

      // Usage Quantities and UoMs

      prt.ProdnRsceToolUsageQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'ProdnRsceToolUsageQuantityUnit'
      @Aggregation.default: #SUM
      prt.ProdnRsceToolUsageQuantity,

      prt.PlndProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'PlndProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      prt.PlannedProdnRsceToolUsageQty,

      prt.ConfdProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfdProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      prt.ConfirmedProdnRsceToolUsageQty,

      prt.RmngProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'RmngProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      prt.RemainingProdnRsceToolUsageQty,

      // Formulas

      prt.ProdnRsceToolTotQtyCalcFormula,
      prt.ProdnRsceToolUsageQtyCalcFmla,

      // Associations

      @Consumption.hidden: true
      prt._MfgOrderInternalID,
      prt._MfgOrder,
      prt._MfgOrderSequence2 as _MfgOrderSequence,
      prt._MfgOrderOperation,
      prt._MfgOrderOperationBySemKey,   
      prt._MfgOrderCategory,
      prt._MfgOrderType,
      prt._ProductionPlant,
      prt._OperationControlProfile,
      prt._ProdnRsceToolControlProfile,
      prt._ProductionResourceType,
      prt._ProdnRsceToolByInternalKey,
      prt._ProdnRsceToolMasterData,
      prt._ProdnRsceToolCategory_2 as _ProdnRsceToolCategory,
      prt._CreatedByUser,
      prt._LastChangedByUser,
      prt._Language,
      prt._BillOfOperationsType,
      prt._BillOfOperationsGroup,
      prt._ProdnRsceToolUsageDurnUnit,
      prt._ProdnRsceToolStdWorkQtyUnit,
      prt._PlannedProdnRsceToolQtyUnit,
      prt._ConfirmedProdnRsceToolQtyUnit,
      prt._RemainingProdnRsceToolQtyUnit,
      prt._ProdnRsceToolUsageQtyUnit,
      prt._PlndProdnRsceToolUsageQtyUnit,
      prt._ConfdProdnRsceToolUsgeQtyUnit,
      prt._RmngProdnRsceToolUsageQtyUnit,
      stat._PRTIsCreatedCode,
      stat._PRTIsReleasedCode,
      stat._PRTIsPrintedCode,
      stat._PRTIsDeletedCode,
      stat._PRTIsNotAvailableCode
};