I_MfgActnSettingReasonTypeText

@AbapCatalog.sqlViewName: 'IMPERSNCTTXT'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'MfgActionSettingReasonCodeType'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #S, dataClass: #META}
@VDM.viewType: #BASIC
@EndUserText.label: 'Reason Code Requirement Text'
@Search.searchable: true
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_MfgActnSettingReasonTypeText
  as select from dd07t as txt
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      @ObjectModel.text.element: 'MfgActnSttgReasonCodeTypeName'
  key cast( cast(substring(txt.domvalue_l, 1, 1) as abap.numc(1)) as mpe_action_setting_reason_type)  as MfgActionSettingReasonCodeType,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast(txt.ddlanguage as spras preserving type)                                                   as Language,
      @Semantics.text: true
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      txt.ddtext                                                                                      as MfgActnSttgReasonCodeTypeName,

      // Associations

      _Language
}
where
      domname  = 'MPE_REASON_TYPE'
  and as4local = 'A';