I_MfgActionReasonCodeGroupTP

DDL: I_MFGACTIONREASONCODEGROUPTP SQL: IMPEMFGARCGTP Type: view TRANSACTIONAL

MPE MFG Action Reason Code Group

I_MfgActionReasonCodeGroupTP is a Transactional CDS View that provides data about "MPE MFG Action Reason Code Group" in SAP S/4HANA. It reads from 1 data source (I_MfgActionReasonCodeGroup) and exposes 20 fields with key fields MfgActionReasonCodeGroupCtlg, MfgActionReasonCodeGroup. It has 1 association to related views.

1 data source(s) 20 fields

Data Sources (1)

SourceAliasJoin Type
I_MfgActionReasonCodeGroup grp from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_MfgActionReasonCodeToGroupTP _Code $projection.MfgActionReasonCodeGroupCtlg = _Code.MfgActionReasonCodeGroupCtlg and $projection.MfgActionReasonCodeGroup = _Code.MfgActionReasonCodeGroup

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName IMPEMFGARCGTP view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #TRANSACTIONAL view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.compositionRoot true view
ObjectModel.transactionalProcessingEnabled true view
ObjectModel.createEnabled true view
ObjectModel.updateEnabled true view
ObjectModel.deleteEnabled true view
ObjectModel.draftEnabled true view
ObjectModel.writeDraftPersistence IMFGARCGTPDRAFT view
EndUserText.label MPE MFG Action Reason Code Group view

Fields (20)

KeyFieldSource TableSource FieldDescription
KEY MfgActionReasonCodeGroupCtlg I_MfgActionReasonCodeGroup MfgActionReasonCodeGroupCtlg
KEY MfgActionReasonCodeGroup I_MfgActionReasonCodeGroup MfgActionReasonCodeGroup
MfgActnRsnCodeGroupCtlgForEdit I_MfgActionReasonCodeGroup MfgActionReasonCodeGroupCtlg
MfgActnReasonCodeGroupForEdit I_MfgActionReasonCodeGroup MfgActionReasonCodeGroup
MfgActionReasonCodeGroupName
InspSpecAdditionalCatalogText
CreatedByUserDescription _CreatedByUser UserDescription
LastChangedByUserDescription _LastChangedByUser UserDescription
CodeGroupIsInactive I_MfgActionReasonCodeGroup CodeGroupIsInactive
CodeGroupStatus I_MfgActionReasonCodeGroup CodeGroupStatus
MfgActionReasonCodeGroupIsUsed I_MfgActionReasonCodeGroup MfgActionReasonCodeGroupIsUsed
CreatedByUser I_MfgActionReasonCodeGroup CreatedByUser
CreationDateTime
LastChangedByUser I_MfgActionReasonCodeGroup LastChangedByUser
LastChangeDateTime
_Text _Text
_Code _Code
_Catalog _Catalog
_CreatedByUser _CreatedByUser
_LastChangedByUser _LastChangedByUser 
@AbapCatalog.sqlViewName: 'IMPEMFGARCGTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:
{
  serviceQuality: #C,
  sizeCategory:   #S,
  dataClass:      #CUSTOMIZING
}
@ObjectModel:
{
  compositionRoot: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  draftEnabled: true,                         -- Draft enablement
  writeDraftPersistence: 'IMFGARCGTPDRAFT',   -- Draft persistence
  semanticKey: ['MfgActnRsnCodeGroupCtlgForEdit', 'MfgActnReasonCodeGroupForEdit']
}
@EndUserText.label: 'MPE MFG Action Reason Code Group'
define view I_MfgActionReasonCodeGroupTP
  as select from I_MfgActionReasonCodeGroup as grp

  // association to child view

  association [0..*] to I_MfgActionReasonCodeToGroupTP as _Code  on  $projection.MfgActionReasonCodeGroupCtlg = _Code.MfgActionReasonCodeGroupCtlg
                                                                 and $projection.MfgActionReasonCodeGroup     = _Code.MfgActionReasonCodeGroup

{

      // key fields

      @ObjectModel.readOnly: true
  key grp.MfgActionReasonCodeGroupCtlg                                                                                   as  MfgActionReasonCodeGroupCtlg,
      @ObjectModel.readOnly: true
  key grp.MfgActionReasonCodeGroup                                                                                       as  MfgActionReasonCodeGroup,

      // reason code group

      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.element: 'InspSpecAdditionalCatalogText'
      grp.MfgActionReasonCodeGroupCtlg                                                                                   as  MfgActnRsnCodeGroupCtlgForEdit,
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.element:  [ 'MfgActionReasonCodeGroupName' ]
      grp.MfgActionReasonCodeGroup                                                                                       as  MfgActnReasonCodeGroupForEdit,

      @Semantics.text: true
      cast(_Text[1: Language=$session.system_language].MfgActionReasonCodeGroupName as mpe_rsn_code_group_description)   as  MfgActionReasonCodeGroupName,

      @Semantics.text: true
      _Catalog._InspectionCatalogText[1: Language=$session.system_language].InspSpecAdditionalCatalogText                as  InspSpecAdditionalCatalogText,

      @Semantics.text: true
      _CreatedByUser.UserDescription                                                                                     as  CreatedByUserDescription,
      @Semantics.text: true
      _LastChangedByUser.UserDescription                                                                                 as  LastChangedByUserDescription,

      grp.CodeGroupIsInactive                                                                                            as  CodeGroupIsInactive,
      grp.CodeGroupStatus                                                                                                as  CodeGroupStatus,
      grp.MfgActionReasonCodeGroupIsUsed                                                                                 as  MfgActionReasonCodeGroupIsUsed,

      // admin

      @ObjectModel.readOnly: true
      @ObjectModel.text.element:  [ 'CreatedByUserDescription' ]
      @Semantics.user.createdBy: true
      grp.CreatedByUser                                                                                                  as  CreatedByUser,
      @ObjectModel.readOnly: true
      cast(grp.CreationDateTime as mpe_create_date preserving type)                                                      as  CreationDateTime,
      @ObjectModel.readOnly: true
      @ObjectModel.text.element:  [ 'LastChangedByUserDescription' ]
      grp.LastChangedByUser                                                                                              as  LastChangedByUser,
      @ObjectModel.readOnly: true
      cast(grp.LastChangeDateTime as mpe_lchange_date preserving type)                                                   as  LastChangeDateTime,

      // text associations

      _Text,

      // to child

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _Code,

      // others

      _Catalog,
      _CreatedByUser,
      _LastChangedByUser
}

Learn More