I_MatlStkRptCollectionWeekDayT

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Collection Day - Text'
@ObjectModel.usageType.serviceQuality:#C
@ObjectModel.usageType.sizeCategory:#S
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.dataCategory:#TEXT
@Search.searchable
@VDM:{
  viewType: #BASIC,
  private:false
}
define view entity I_MatlStkRptCollectionWeekDayT
  as select from dd07t
  association [0..1] to I_MatlStkRptCollectionWeekDay as _CollectionDay on $projection.MatlStkRptCollectionWeekDay = _CollectionDay.MatlStkRptCollectionWeekDay
  association [0..1] to I_Language      as _Language      on $projection.Language = _Language.Language
{
       @ObjectModel.text.element: ['MatlStkRptCollWeekDayText']
  key  cast(substring(dd07t.domvalue_l, 1, 2) as collectiondayofweek preserving type) as MatlStkRptCollectionWeekDay,
       @ObjectModel.foreignKey.association: '_Language'
       @Semantics.language:true
  key  cast( ddlanguage as spras )                                                   as Language,     
      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
       cast ( substring ( ddtext, 1, 60 ) as val_text )                              as MatlStkRptCollWeekDayText,      
       _CollectionDay,
       _Language           
    
  }
  where
  (
    dd07t.domname  = 'STOCKREPORTINGDAYOFWEEK'
  )
  and(
    dd07t.as4local = 'A'
  );