I_MatlCompProvisionTypeText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'MaterialProvisionType'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Material Component Provision Type - Text'

define view entity I_MatlCompProvisionTypeText 
  as select from t417t as text

  association [1..1] to I_MatlCompProvisionType as _ProvisionType on $projection.MaterialProvisionType = _ProvisionType.MaterialProvisionType  
  association [0..1] to I_Language              as _Language      on $projection.Language = _Language.Language
{
      @Semantics.language
      @ObjectModel.foreignKey.association: '_Language'
  key text.spras                                    as Language,
      @ObjectModel.foreignKey.association: '_ProvisionType'  
      @ObjectModel.text.element: ['MaterialProvisionTypeName']
  key cast(text.beikz as vdm_beikz preserving type) as MaterialProvisionType,

      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(text.btext as vdm_btkkt preserving type) as MaterialProvisionTypeName,

      // Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _ProvisionType,
      _Language
};