I_MaterialValuationHist

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Material Valuation History'
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IMMVALNHIST'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'Material'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true

define view I_MaterialValuationHist as select from Mbv_Mbewh  as MatValHist 

  inner join   I_ValuationArea as ValuationArea on MatValHist.bwkey = ValuationArea.ValuationArea
      inner join I_CompanyCode as CompanyCode on CompanyCode.CompanyCode = ValuationArea.CompanyCode      
        
//  Below given inner join to fetch Purch Organiztion has been commmeted since there would be multiple Org's against a plant.

//  hence join would fetch multiple records out of this join. This would duplicate MovingAveragePrice data for key combination of ValuationArea and Material.

//    inner join I_PlantPurchasingOrganization as PlantPurchOrg on  ProductPlant.Plant = PlantPurchOrg.Plant

        
{

 
  key MatValHist.matnr as Material,
  key MatValHist.bwkey as ValuationArea,
  key bwtar as ValuationType,
  key MatValHist.lfgja as FiscalYearCurrentPeriod,  
  key MatValHist.lfmon as FiscalMonthCurrentPeriod,
  lbkum as TotalValStockQuantity,
  salk3 as StockValueInCCCrcy,
  vprsv as MaterialPriceControl,
  verpr as MovingAveragePrice,
  stprs as StandardPrice,
  peinh as MaterialPriceUnitQty,
  bklas as ValuationClass,
  salkv as ValBsdOnMvgAvgPrcInCCCrcy,
  vksal as TotStkValAtSlsPrcInCoCodeCrcy,  
  CompanyCode.Currency       as Currency,
  CompanyCode.CompanyCode       as CompanyCode, 
  cast ( concat( MatValHist.lfgja , concat( MatValHist.lfmon , '01' ) )  as erdat )as CreationDate
  
}