I_MaterialDocumentHeader

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IMATDOCHEADER'
@EndUserText.label: 'Material Document Header'

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    usageType: {
        sizeCategory: #XXL,
        serviceQuality: #B,
        dataClass:#TRANSACTIONAL
    },
    compositionRoot: true,
    representativeKey: 'MaterialDocument',
    semanticKey: ['MaterialDocumentYear', 'MaterialDocument'],
    modelingPattern: #ANALYTICAL_DIMENSION,
    supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
} 

@Search.searchable: true
@VDM: {
        viewType: #COMPOSITE,
        lifecycle.contract.type: #PUBLIC_LOCAL_API,
        lifecycle.status: #DEPRECATED,
        lifecycle.successor: 'I_MaterialDocumentHeader_2'
      }
@Analytics.dataCategory: #DIMENSION

@Metadata: {
             ignorePropagatedAnnotations: true,
             allowExtensions: true
           }

define view I_MaterialDocumentHeader
  as select from I_MaterialDocumentRecord
  association [1..1] to I_MaterialDocumentYear as _MaterialDocumentYear on  $projection.MaterialDocumentYear = _MaterialDocumentYear.MaterialDocumentYear
  association [1..*] to I_MaterialDocumentItem as _MaterialDocumentItem on  $projection.MaterialDocumentYear = _MaterialDocumentItem.MaterialDocumentYear
                                                                        and $projection.MaterialDocument     = _MaterialDocumentItem.MaterialDocument
  association [1..*] to I_MaterialDocumentItem_2 as _MaterialDocumentItem_2 on  $projection.MaterialDocumentYear = _MaterialDocumentItem_2.MaterialDocumentYear
                                                                        and $projection.MaterialDocument     = _MaterialDocumentItem_2.MaterialDocument
  association [0..1] to I_DeliveryDocument     as _DeliveryDocument     on  $projection.DeliveryDocument = _DeliveryDocument.DeliveryDocument
  -- the association to the DeliveryDocument would also be available as _DeliveryInMatlDocumentHeader in I_MaterialDocumentRecord,
  -- but since the field is rebranded as DeliveryDocument in the header view, the repeated association seems to make sense
{
      @ObjectModel.foreignKey.association: '_MaterialDocumentYear'
  key MaterialDocumentYear,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      @Search.ranking: #HIGH
  key MaterialDocument,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      @Search.ranking: #MEDIUM
      @Semantics.businessDate.at: true
      DocumentDate,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      @Search.ranking: #MEDIUM
      @Semantics.businessDate.at: true
      PostingDate,
      AccountingDocumentType,
      InventoryTransactionType,

      CreatedByUser,
      CreationDate,
      CreationTime,
      MaterialDocumentHeaderText,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      @Search.ranking: #MEDIUM
      @ObjectModel.foreignKey.association: '_DeliveryDocument'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_DeliveryDocumentStdVH',
                     element: 'DeliveryDocument' }
        }]
      DeliveryInMatlDocumentHeader as DeliveryDocument,
      ReferenceDocument,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #MEDIUM
      BillOfLading,
      
      _MaterialDocumentYear,
      @ObjectModel.association.type:#TO_COMPOSITION_CHILD
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_MaterialDocumentItem_2'
      _MaterialDocumentItem,
      _MaterialDocumentItem_2,

      _User,
      _AccountingDocumentType,
      _InventoryTransactionType,

      _DeliveryDocument
}
where
      MaterialDocumentRecordType = 'MDOC'
  and IsMaterialDocumentHeader   = 1