I_MaintenanceTaskListValueHelp

@AbapCatalog.sqlViewName: 'IMAINTTSKLSTVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Task List'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'TaskListGroupCounter'
@Search.searchable: true
@VDM.viewType: #COMPOSITE
@Consumption.ranked: true

define view I_MaintenanceTaskListValueHelp
  as select from I_MaintenanceTaskList
{

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #MEDIUM
  key TaskListType,

      @EndUserText.label: 'Task List Group'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #MEDIUM
  key TaskListGroup,

      @EndUserText.label: 'Task List Group Counter'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #MEDIUM
  key TaskListGroupCounter,
  
      @UI.hidden: true
  key TaskListVersionCounter,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      TaskListDesc,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #MEDIUM
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_MaintenanceStrategyStdVH', element: 'MaintenanceStrategy' } }]
      MaintenanceStrategy,

      Plant,

      //      @EndUserText.label: 'Task List'

      //      @ObjectModel.text.element: [ 'TaskListDesc' ]

      //      case ltrim( TaskListGroup, '0')

      //           when '' then case ltrim( TaskListGroupCounter, '0')

      //                           when '' then concat( TaskListType, '/0/0' )

      //                           else concat( concat( TaskListType, '/0/' ), ltrim( TaskListGroupCounter, '0') )

      //                        end

      //           else case ltrim( TaskListGroupCounter, '0')

      //                   when '' then concat( concat( concat( TaskListType, '/' ), ltrim( TaskListGroup, '0') ), '/0' )

      //                   else concat( concat( concat( concat( TaskListType, '/' ), ltrim(TaskListGroup, '0') ), '/' ), ltrim( TaskListGroupCounter, '0') )

      //                end

      //      end as TaskList,


      -- Task List Group
      @EndUserText.label: 'Task List'
      @ObjectModel.text.element: [ 'TaskListDesc' ]
      case TaskListType
          when ''
          then ''
          else concat(concat(concat(concat(TaskListType,'/'),ltrim(TaskListGroup,'0')),'/'), ltrim( TaskListGroupCounter,'0')) end as TaskList,


      @EndUserText.label: 'Task List Status'
      TaskListStatus,

      @EndUserText.label: 'Task List Usage'
      TaskListUsage,
      
      @EndUserText.label: 'Equipment'
      Equipment,
      
      @EndUserText.label: 'Functional Location'
      FunctionalLocationLabelName,

      /* Technical fields for DCL */

      @Consumption.hidden: true
      ResponsiblePlannerGroup,

      //@Consumption.hidden: true

      TechnicalObject,

      //@Consumption.hidden: true

      TechObjIsEquipOrFuncnlLoc,
      
//      cast ( case TechObjIsEquipOrFuncnlLoc 

//        when 'EAMS_FL' then FunctionalLocationLabelName

//        when 'EAMS_EQUI' then Equipment

//        else ''

//      end as eam_maintitemreferenceobject preserving type ) as MaintenanceItemReferenceObject,




      _TaskListStatus,

      /* Associations */
      @Consumption.hidden: true
      _TaskListType,

      @Consumption.hidden: true
      _TaskListGroup,

      @Consumption.hidden: true
      _TaskListGroupCounter,


      /* Associations for DCL */
      @Consumption.hidden: true
      _TechnicalObject,

      @Consumption.hidden: true
      _MaintenanceStrategy

}
where
      IsDeleted           is initial
  and IsMarkedForDeletion is initial
  and ValidityStartDate   <= $session.user_date
  and TaskListStatus      = '2'
  or  TaskListStatus      = '4'