I_MaintenanceTaskListStdVH

DDL: I_MAINTENANCETASKLISTSTDVH SQL: IMAINTTSKLST__VH Type: view COMPOSITE

Maintenance Task List

I_MaintenanceTaskListStdVH is a Composite CDS View that provides data about "Maintenance Task List" in SAP S/4HANA. It reads from 1 data source (I_MaintenanceTaskList) and exposes 15 fields with key fields TaskListType, TaskListGroup, TaskListGroupCounter, TaskListVersionCounter.

1 data source(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintenanceTaskList I_MaintenanceTaskList from

Annotations (14)

NameValueLevelField
AbapCatalog.compiler.compareFilter true view
AbapCatalog.sqlViewName IMAINTTSKLST__VH view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Maintenance Task List view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey TaskListGroupCounter view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
Search.searchable true view
Consumption.ranked true view
VDM.viewType #COMPOSITE view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY TaskListType TaskListType
KEY TaskListGroup TaskListGroup Task List Group
KEY TaskListGroupCounter TaskListGroupCounter Task List Group Counter
KEY TaskListVersionCounter TaskListVersionCounter
TaskListDesc TaskListDesc
Plant Plant
TaskListStatus TaskListStatus
ResponsiblePlannerGroup ResponsiblePlannerGroup
TechnicalObject TechnicalObject
TechObjIsEquipOrFuncnlLoc TechObjIsEquipOrFuncnlLoc
TaskListUsage TaskListUsage
_TaskListType _TaskListType
_TaskListGroup _TaskListGroup
_TaskListGroupCounter _TaskListGroupCounter
_TechnicalObject _TechnicalObject 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IMAINTTSKLST__VH'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Task List'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'TaskListGroupCounter'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@Search.searchable: true
@Consumption.ranked: true
@VDM.viewType: #COMPOSITE

define view I_MaintenanceTaskListStdVH
  as select from I_MaintenanceTaskList
{
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key TaskListType,

      @EndUserText.label: 'Task List Group'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key TaskListGroup,

      @EndUserText.label: 'Task List Group Counter'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key TaskListGroupCounter,
      
      @UI.hidden: true
  key TaskListVersionCounter,
      
      @EndUserText.label: 'Task List'
      @ObjectModel.text.element: [ 'TaskListDesc' ]
      case ltrim( TaskListGroup, '0')
           when '' then case ltrim( TaskListGroupCounter, '0')
                           when '' then concat( TaskListType, '/0/0' )
                           else concat( concat( TaskListType, '/0/' ), ltrim( TaskListGroupCounter, '0') )
                        end
           else case ltrim( TaskListGroupCounter, '0')
                   when '' then concat( concat( concat( TaskListType, '/' ), ltrim( TaskListGroup, '0') ), '/0' )
                   else concat( concat( concat( concat( TaskListType, '/' ), ltrim(TaskListGroup, '0') ), '/' ), ltrim( TaskListGroupCounter, '0') )
                end
      end as  TaskList,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      TaskListDesc,


      /* Technical fields for DCL */
      @Consumption.hidden: true
      Plant,
      
      @Consumption.hidden: true
      TaskListStatus,
      
      @Consumption.hidden: true
      ResponsiblePlannerGroup,
      
      @Consumption.hidden: true
      TechnicalObject,
      
      @Consumption.hidden: true
      TechObjIsEquipOrFuncnlLoc,

// Added for I_ROUT2      

      @Consumption.hidden: true
      TaskListUsage,

      /* Associations */
      @Consumption.hidden: true
      _TaskListType,
      
      @Consumption.hidden: true
      _TaskListGroup,
      
      @Consumption.hidden: true
      _TaskListGroupCounter,
      
      
      /* Associations for DCL */
      @Consumption.hidden: true
      _TechnicalObject
}

Learn More