I_MaintTaskListGroupCounter

DDL: I_MAINTTASKLISTGROUPCOUNTER SQL: IMNTTASKGRPCTR Type: view BASIC

Maintenance Task List Group Counter

I_MaintTaskListGroupCounter is a Basic CDS View that provides data about "Maintenance Task List Group Counter" in SAP S/4HANA. It reads from 1 data source (plkz) and exposes 21 fields with key fields BillOfOperationsType, BillOfOperationsGroup, BillOfOperationsVariant. It has 7 associations to related views.

1 data source(s) 21 fields

Data Sources (1)

SourceAliasJoin Type
plkz plkz from

Associations (7)

CardinalityTargetAliasCondition
[1..1] I_MaintenanceTaskListType _BillOfOperationsType $projection.BillOfOperationsType = _BillOfOperationsType.TaskListType
[0..1] I_BillOfOperationsVersionType _BillOfOperationsVersionType $projection.BillOfOperationsVersionType = _BillOfOperationsVersionType.BillOfOperationsVersionType
[1..1] I_BillOfOperationsGroup _BillOfOperationsGroup $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
[1..1] I_MaintenanceTaskListGroup _BillOfOperationsGroup_2 $projection.BillOfOperationsType = _BillOfOperationsGroup_2.BillOfOperationsType and $projection.BillOfOperationsGroup = _BillOfOperationsGroup_2.BillOfOperationsGroup -- to child: Change State of Root
[1..*] I_BillOfOperationsChangeState _BillOfOperationsChangeState $projection.BillOfOperationsType = _BillOfOperationsChangeState.BillOfOperationsType and $projection.BillOfOperationsGroup = _BillOfOperationsChangeState.BillOfOperationsGroup and $projection.BillOfOperationsVariant = _BillOfOperationsChangeState.BillOfOperationsVariant -- to child: Sequences
[1..*] I_BillOfOperationsSequence _BillOfOperationsSequence $projection.BillOfOperationsType = _BillOfOperationsSequence.BillOfOperationsType and $projection.BillOfOperationsGroup = _BillOfOperationsSequence.BillOfOperationsGroup and $projection.BillOfOperationsVariant = _BillOfOperationsSequence.BillOfOperationsVariant -- to child: Material to BOO assignment
[1..*] I_BOOMaterialAssignment _BOOMaterialAssignment $projection.BillOfOperationsType = _BOOMaterialAssignment.BillOfOperationsType and $projection.BillOfOperationsGroup = _BOOMaterialAssignment.BillOfOperationsGroup and $projection.BillOfOperationsVariant = _BOOMaterialAssignment.BillOfOperationsVariant

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName IMNTTASKGRPCTR view
ObjectModel.compositionRoot true view
AccessControl.authorizationCheck #CHECK view
VDM.viewType #BASIC view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.representativeKey BillOfOperationsVariant view
AbapCatalog.compiler.compareFilter true view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MASTER view
AbapCatalog.preserveKey true view
EndUserText.label Maintenance Task List Group Counter view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.modelingPattern #CDS_MODELING_DATA_SOURCE view

Fields (21)

KeyFieldSource TableSource FieldDescription
KEY BillOfOperationsType plkz plnty
KEY BillOfOperationsGroup plkz plnnr
KEY BillOfOperationsVariant plkz plnal
BillOfOperationsVersionType plkz subtype
BillOfOperationsSubtype plkz subtype
LastUsageDate plkz abdat
NumberOfUsages plkz abanz
HasChangeNumber plkz flg_ecm
HasParameterEffectivity plkz flg_ecm_par
aedatasLastChangeDate
LastChangeTime plkz aeuzeit
LastChangedByUser
RoutingIsReworkRouting plkz rework
ProdnProcgIsFlexible plkz relaxed
_BOOMaterialAssignment _BOOMaterialAssignment
_BillOfOperationsChangeState _BillOfOperationsChangeState
_BillOfOperationsGroup _BillOfOperationsGroup
_BillOfOperationsGroup_2 _BillOfOperationsGroup_2
_BillOfOperationsSequence _BillOfOperationsSequence
_BillOfOperationsType _BillOfOperationsType
_BillOfOperationsVersionType _BillOfOperationsVersionType 
@AbapCatalog.sqlViewName: 'IMNTTASKGRPCTR'
@ObjectModel.compositionRoot: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BillOfOperationsVariant'
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@AbapCatalog.preserveKey:true 
@EndUserText.label: 'Maintenance Task List Group Counter'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern:             #CDS_MODELING_DATA_SOURCE
@ObjectModel.supportedCapabilities:     [ #CDS_MODELING_DATA_SOURCE ]


define view I_MaintTaskListGroupCounter
  as select from plkz

  association [1..1] to I_MaintenanceTaskListType     as _BillOfOperationsType        on  $projection.BillOfOperationsType        = _BillOfOperationsType.TaskListType
  association [0..1] to I_BillOfOperationsVersionType as _BillOfOperationsVersionType on  $projection.BillOfOperationsVersionType = _BillOfOperationsVersionType.BillOfOperationsVersionType  
  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [1..1] to I_MaintenanceTaskListGroup    as _BillOfOperationsGroup_2     on  $projection.BillOfOperationsType  = _BillOfOperationsGroup_2.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup_2.BillOfOperationsGroup
  -- to child: Change State of Root
  association [1..*] to I_BillOfOperationsChangeState as _BillOfOperationsChangeState on  $projection.BillOfOperationsType    = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsChangeState.BillOfOperationsVariant
  -- to child: Sequences
  association [1..*] to I_BillOfOperationsSequence    as _BillOfOperationsSequence    on  $projection.BillOfOperationsType    = _BillOfOperationsSequence.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsSequence.BillOfOperationsVariant

  -- to child: Material to BOO assignment
  association [1..*] to I_BOOMaterialAssignment       as _BOOMaterialAssignment       on  $projection.BillOfOperationsType    = _BOOMaterialAssignment.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BOOMaterialAssignment.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BOOMaterialAssignment.BillOfOperationsVariant
{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plkz.plnty                                                   as   BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup_2'
  key plkz.plnnr                                                   as   BillOfOperationsGroup,
  key plkz.plnal                                                   as   BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsVersionType'
      plkz.subtype                                                 as   BillOfOperationsVersionType,
      
      plkz.subtype                                                 as   BillOfOperationsSubtype, //kept for compatibility reasons


      plkz.abdat                                                   as   LastUsageDate,
      plkz.abanz                                                   as   NumberOfUsages,

      plkz.flg_ecm                                                 as   HasChangeNumber,
      plkz.flg_ecm_par                                             as   HasParameterEffectivity,

      -- Administrative Data
      @Semantics.systemDate.lastChangedAt: true
      plkz.aedat                                                   as   LastChangeDate,
      plkz.aeuzeit                                                 as   LastChangeTime,
      @Semantics.user.lastChangedBy: true
      cast(plkz.aenam as vdm_lastchangedbyuserid preserving type)  as   LastChangedByUser,
      
      plkz.rework                                                  as   RoutingIsReworkRouting,
      plkz.relaxed                                                 as   ProdnProcgIsFlexible,

      // **************************** Associations *****************************


      _BOOMaterialAssignment,
      _BillOfOperationsChangeState,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_BillOfOperationsGroup_2'
      _BillOfOperationsGroup,
      _BillOfOperationsGroup_2, 
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BillOfOperationsVersionType
}
   where plnty    = 'A'
   or    plnty    = 'E'
   or    plnty    = 'T'
;

Learn More