I_MaintOrderOpAndSubOp_2

@AbapCatalog.sqlViewName: 'IMTORDOPSOPR2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order Operation and Suboperation'

@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL

define view I_MaintOrderOpAndSubOp_2
  as select from           afvc
    left outer to one join afvc as afvc_superior on  afvc.aufpl = afvc_superior.aufpl
                                                 and afvc.sumnr = afvc_superior.aplzl
    inner join             afko as afko          on  afvc.aufpl = afko.aufpl
                                                 and plnaw      = 'I'

  association [1..1] to I_MaintOrderOperPlanningValues as _OperationPlanningValues      on  $projection.MaintOrderRoutingNumber     = _OperationPlanningValues.MaintOrderRoutingNumber
                                                                                        and $projection.MaintenanceOrderRoutingNode = _OperationPlanningValues.MaintOrderOperationCounter
  association [0..1] to I_WorkCenter                   as _WorkCenter                   on  _WorkCenter.WorkCenterInternalID = $projection.OperationWorkCenterInternalID
                                                                                        and _WorkCenter.WorkCenterTypeCode   = $projection.OperationWorkCenterTypeCode
  association [0..1] to I_Plant                        as _Plant                        on  _Plant.Plant = $projection.Plant
  association [0..1] to I_OperationControlProfile      as _OperationControlKey          on  _OperationControlKey.OperationControlProfile = $projection.OperationControlKey
  association [0..1] to I_MaintenanceOrder             as _MaintenanceOrder             on  _MaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder
  association [0..*] to I_StatusObjectActiveStatus     as _StatusObjectActiveStatus     on  _StatusObjectActiveStatus.StatusObject = $projection.MaintOrdOperationStatusObject
  association [0..1] to I_Language                     as _Language                     on  $projection.Language = _Language.Language
  association [0..*] to I_OrderProdnResourceTool       as _MaintOrderProdnRsceTool      on  _MaintOrderProdnRsceTool.OrderInternalBillOfOperations = $projection.MaintOrderRoutingNumber
                                                                                        and _MaintOrderProdnRsceTool.OrderIntBillOfOperationsItem  = $projection.MaintenanceOrderRoutingNode
  association [0..*] to I_MaintenanceOrderComponent_2  as _MaintOrderComponent          on  _MaintOrderComponent.MaintOrderRoutingNumber    = $projection.MaintOrderRoutingNumber
                                                                                        and _MaintOrderComponent.MaintOrderOperationCounter = $projection.MaintenanceOrderRoutingNode
  association [0..1] to I_WorkforcePerson              as _PersonResponsible            on  $projection.OperationPersonResponsible = _PersonResponsible.PersonExternalID
  association [0..1] to I_Supplier                     as _Supplier                     on  $projection.OperationSupplier = _Supplier.Supplier
  association [0..1] to I_Currency                     as _OpExternalProcessingCurrency on  $projection.OpExternalProcessingCurrency = _OpExternalProcessingCurrency.Currency
  association [0..1] to I_Material                     as _Assembly                     on  $projection.Assembly = _Assembly.Material
  association [0..1] to I_StatusObjectStatus           as _DeletionFlag                 on  $projection.MaintOrdOperationStatusObject = _DeletionFlag.StatusObject
                                                                                        and _DeletionFlag.StatusCode                  = 'I0013'
  association [1..1] to I_MaintOperationExecStageCode  as _MaintOperationExecStageCode  on  $projection.MaintOperationExecStageCode = _MaintOperationExecStageCode.MaintOperationExecStageCode

{
  key  afvc.aufpl                                                                    as MaintOrderRoutingNumber,
  key  afvc.aplzl                                                                    as MaintenanceOrderRoutingNode,
       afko.aufnr                                                                    as MaintenanceOrder,
       @Consumption.hidden: true
       afko.plnaw                                                                    as BillOfOperationsApplication,
       coalesce( afvc_superior.vornr, afvc.vornr )                                   as MaintenanceOrderOperation,
       case when afvc.sumnr = '00000000' then '' else afvc.vornr end                 as MaintenanceOrderSubOperation,
       afvc.sumnr                                                                    as SuperiorOperationInternalID,
       afvc.objnr                                                                    as MaintOrdOperationStatusObject,
       afvc.steus                                                                    as OperationControlKey,
       afvc.ltxa1                                                                    as OperationDescription,
       @ObjectModel.foreignKey.association: '_PersonResponsible'
       afvc.pernr                                                                    as OperationPersonResponsible,
       @ObjectModel.foreignKey.association: '_Plant'
       afvc.werks                                                                    as Plant,
       afvc.arbid                                                                    as OperationWorkCenterInternalID,
       'A'                                                                           as OperationWorkCenterTypeCode,
       afvc.anzzl                                                                    as NumberOfCapacities,
       afvc.rueck                                                                    as MaintOrderConfirmation,

       afvc.equnr                                                                    as Equipment,
       afvc.tplnr                                                                    as FunctionalLocation, // <-- This is in internal labelling!


       afvc.sortl                                                                    as OperationPurgInfoRecdSearchTxt,
       afvc.afnam                                                                    as OperationRequisitionerName,
       afvc.wempf                                                                    as OperationGoodsRecipientName,

       @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
       @DefaultAggregation: #NONE
       afvc.preis                                                                    as OpExternalProcessingPrice,
       afvc.peinh                                                                    as OpExternalProcessingPriceUnit,
       @ObjectModel.foreignKey.association: '_OpExternalProcessingCurrency'
       @Semantics.currencyCode: true
       afvc.waers                                                                    as OpExternalProcessingCurrency,
       afvc.bednr                                                                    as OperationTrackingNumber,
       afvc.infnr                                                                    as OperationPurchasingInfoRecord,
       afvc.ablad                                                                    as OperationUnloadingPointName,
       cast (afvc.ebeln as konnr)                                                    as OpPurchaseOutlineAgreement,
       cast (afvc.ebelp as ktpnr)                                                    as OpPurchaseOutlineAgreementItem,
       @ObjectModel.foreignKey.association: '_Supplier'
       afvc.lifnr                                                                    as OperationSupplier,
       @ObjectModel.foreignKey.association: '_Assembly'
       afvc.istru                                                                    as Assembly,
       afvc.anlzu                                                                    as OperationSystemCondition,
       afvc.larnt                                                                    as CostCtrActivityType,
       afvc.anfkokrs                                                                 as ReqgCostCenterControllingArea,
       afvc.indet                                                                    as OperationCalculationControl,
       afvc.prznt                                                                    as OperationWorkPercent,
       afvc.bedid                                                                    as CapacityRequirement,
       afvc.banfn                                                                    as PurchaseRequisition,
       afvc.bnfpo                                                                    as PurchaseRequisitionItem,
       afvc.matkl                                                                    as MaterialGroup,
       afvc.sakto                                                                    as CostElement,
       afvc.ekorg                                                                    as PurchasingOrganization,
       afvc.ekgrp                                                                    as PurchasingGroup,

       afvc.maintordopprocessphasecode                                               as MaintOrdOpProcessPhaseCode,
       afvc.maintordopprocesssubphasecode                                            as MaintOrdOpProcessSubPhaseCode,
       @ObjectModel.foreignKey.association: '_MaintOperationExecStageCode'
       cast( afvc.maintopexecutionphasecode as eam_premainpost_cds preserving type ) as MaintOperationExecStageCode,

       @ObjectModel.foreignKey.association: '_Language'
       cast(afvc.txtsp as spras preserving type)                                     as Language,
       cast(case when afvc.txtsp = '' then '' else 'X' end as xfeld)                 as OperationHasLongText,

       afvc.ktsch                                                                    as OperationStandardTextCode,
       afvc.loanz                                                                    as NumberOfTimeTickets,
       afvc.gsber                                                                    as BusinessArea,
       afvc.prctr                                                                    as ProfitCenter,
       afvc.kalsm                                                                    as CostingSheet,
       afvc.txjcd                                                                    as TaxJurisdiction,
       afvc.func_area                                                                as FunctionalArea,

       cast( afvc.scope as ps_s4_scope_cv preserving type )                          as MaintControllingObjectClass,
       afvc.vertl                                                                    as WrkCtrIntCapRqmtsDistr,
       afvc.zschl                                                                    as MaintOrdOperationOverheadCode,
       cast( afvc.projn as ps_s4_pspnr preserving type )                             as MaintOrdOpAssgdWBSElmntInt,
       afvc.loekz                                                                    as IsMarkedForDeletion,
       afvc.allmaintordcompcmtdqtsarekept                                            as AllMaintOrdCompCmtdQtsAreKept,
       afvc.rmzhl                                                                    as MaintOrderConfCntrValue,
       afvc.leknw                                                                    as MaintOrdOpHasNoRemainingWork,
       afvc.maintordophasleanservices                                                as MaintOrdOpHasLeanServices,
       afvc.plnty                                                                    as TaskListType,
       cast(afvc.sched_end as cc4_delvry_date_adj_oper preserving type)              as MaintOrdOpDelivDateAdjustment,

       afvc.plnnr                                                                    as TaskListGroup,
       afvc.plnal                                                                    as TaskListGroupCounter,

       _OperationPlanningValues,
       _MaintenanceOrder,
       _OperationControlKey,
       _Plant,
       _WorkCenter,
       _StatusObjectActiveStatus,
       _Language,
       _PersonResponsible,
       _Supplier,
       _MaintOrderComponent,
       _MaintOrderProdnRsceTool,
       _OpExternalProcessingCurrency,
       _Assembly,
       _DeletionFlag,
       _MaintOperationExecStageCode
}