I_MRPQuantityDistributionKey

@AbapCatalog.sqlViewName: 'IMRPQTYDISTRKEY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'QuantityDistributionKey'
@ObjectModel.semanticKey: ['Plant', 'QuantityDistributionKey']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Quantity Distribution Key in MRP'

define view I_MRPQuantityDistributionKey
  as select from t437v

  association [1..1] to I_Plant                   as _Plant on  $projection.Plant = _Plant.Plant
  association [0..*] to I_MRPQuantityDistrKeyText as _Text  on  $projection.Plant                   = _Text.Plant
                                                            and $projection.QuantityDistributionKey = _Text.QuantityDistributionKey
{
      // Key

      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @ObjectModel.foreignKey.association: '_Plant'
  key werks as Plant,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.text.association: '_Text'
  key vertl as QuantityDistributionKey,

--    @ObjectModel.foreignKey.association: '_DistributionType'
      fnart as DistributionType,
--    @ObjectModel.foreignKey.association: '_DistributionFunction'
      funct as DistributionFunction,

      // Associations

      _Plant,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text
};