I_MDLoadAssaySubjectValueHelp

@AbapCatalog.sqlViewName: 'IMDCLASSAYSUB'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Master Data Subject of a Load Assay'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  representativeKey: 'MasterDataLoadAssaySubject',
  dataCategory: #VALUE_HELP,
  usageType:{
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #META
  }
}
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_MDLoadAssaySubjectValueHelp
  as select from           dd07l as value
    left outer to one join dd07t as text on  value.domname    = text.domname
                                         and value.domvalue_l = text.domvalue_l
                                         and text.as4local    = 'A'
                                         and text.ddlanguage  = $session.system_language
{
      @EndUserText.label: 'Subject of a MDC Load Assay'
      @ObjectModel.text.element: ['MasterDataLoadAssaySubjectText']
  key cast( left(value.domvalue_l, 10) as mdc_load_assay_subject preserving type ) as MasterDataLoadAssaySubject,
      @Semantics.text
      @EndUserText.label: 'Subject Description of a MDC Load Assay'
      text.ddtext                                                                  as MasterDataLoadAssaySubjectText
}
where
      value.domname  = 'MDC_LOAD_ASSAY_SUBJECT'
  and value.as4local = 'A'
  and value.domvalue_l != 'R';