I_MDChgProcessSourceWorklist

@AbapCatalog.sqlViewName: 'IMDCHGPROCSRCEWL'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Master Data Chg Proc Src Worklist'
@VDM.viewType: #BASIC
@Analytics.dataCategory:#DIMENSION
@ObjectModel.representativeKey: 'MDChgProcessSrceWlUUID'

@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #M, serviceQuality: #B }

@ObjectModel.alternativeKey: [{
        id : 'MDCHGPROCESSSOURCEWORKLIST',
        uniqueness : #UNIQUE_IF_NOT_INITIAL,
        element : ['MASTERDATACHANGEPROCESS', 'MDCHGPROCESSSOURCEWORKLIST']
    }]


define view I_MDChgProcessSourceWorklist
  as select from mdc_d_prcwlist
  association [1..1] to I_MDChangeProcessSource   as _MDChangeProcessSource   on _MDChangeProcessSource.MDChgProcessSourceUUID = $projection.MDChgProcessSourceUUID
  association [1..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on _MasterDataChangeProcess.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [1..*] to I_Mdchgprocessworklistfeed as _MDChgProcessWorklistFeed on _MDChgProcessWorklistFeed.MasterDataChgProcessWorklist = $projection.MDChgProcessSourceWorklist

{
      // keys

  key db_key        as MDChgProcessSrceWlUUID,
      // data

      root_key      as MasterDataChangeProcessUUID,
      parent_key    as MDChgProcessSourceUUID,
      process_id    as MasterDataChangeProcess, 
      worklist_guid as MDChgProcessSourceWorklist,
      purpose       as MDChgProcessWlPurpose, //this is A (Aggregation) or D (Deletion)

      source_otc    as MDChgProcessWlObjectTypeCode,
      filter_chain  as MDChgProcessWlFilterChain,
      // association


      _MDChangeProcessSource,
      _MasterDataChangeProcess,
      _MDChgProcessWorklistFeed
}