I_MDChangeProcessVariant

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Variant Definition'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #BASIC
define view entity I_MDChangeProcessVariant
  as select from I_MasterDataChangeProcess
{
  key MasterDataChangeProcessUUID,
      MasterDataChangeProcess,
      MDChgProcessSrceObjectTypeCode,
      cast(
      case when MDChgProcessGoal = 'G' or MDChgProcessGoal = 'U' or MDChgProcessGoal = 'X'
           then case when MDChgProcessSrceObjectTypeCode = '147' or MDChgProcessSrceObjectTypeCode = '986'
                     then 'BP_GOV'
                     when MDChgProcessSrceObjectTypeCode = '1405'
                     then 'BPREL_GOV'
                     else ''
                end
           when MDChgProcessGoal = 'C'
           then case when MDChgProcessSrceObjectTypeCode = '147' or MDChgProcessSrceObjectTypeCode = '986'
                     then 'BP_CONS'
                     when MDChgProcessSrceObjectTypeCode = '1405'
                     then 'BPREL_CONS'
                     else ''
                end
           when MDChgProcessGoal = 'F' or MDChgProcessGoal = 'P' or MDChgProcessGoal = 'Y'
           then case when MDChgProcessSrceObjectTypeCode = '147'
                     then 'BP_INBOUND'
                     else ''
                end
           when MDChgProcessGoal = 'Q'
           then case when MDChgProcessSrceObjectTypeCode = '147'
                     then 'BP_EVA'
                     else ''
                end 
           when MDChgProcessGoal = 'T'
           then case when MDChgProcessSrceObjectTypeCode = '147'
                     then 'BP_SIM'
                     else ''
                end 
           else ''
      end as mdc_process_variant ) as MasterDataChangeProcessVariant,
      MDChgProcessGoal
}