I_LoanContrPayoffWthDflt

@AbapCatalog:
{
    sqlViewName: 'ILCPAYOFFWTDEF',
    compiler.compareFilter: true,
    preserveKey: true
}
@AccessControl:
{
    authorizationCheck: #CHECK,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@ObjectModel.usageType:
{
    serviceQuality: 'C',
    sizeCategory: 'XL',
    dataClass:'MASTER'
}
@VDM:
{
    viewType: #COMPOSITE,
    private: false
}
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'Payoff data for Loan Contract with defaulting'

define view I_LoanContrPayoffWthDflt
  as select distinct from I_LoanContrData     as _LoanContrBP
    left outer join       P_LoanContrPayoff as _LoanContrPayoff on  _LoanContrPayoff.CompanyCode           = _LoanContrBP.CompanyCode
                                                                and _LoanContrPayoff.LoanArchivingCategory = _LoanContrBP.LoanArchivingCategory
                                                                and _LoanContrPayoff.LoanContractID        = _LoanContrBP.LoanContractID
    left outer join       I_CompanyCode     as _CompanyCode     on _CompanyCode.CompanyCode                = _LoanContrBP.CompanyCode
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key _LoanContrBP.CompanyCode,
  key _LoanContrBP.LoanContractID,

      case
      when _LoanContrPayoff.NumberOfPayoff is null then 1
      else
      _LoanContrPayoff.NumberOfPayoff + 1
      end as NumberOfPayoff,

      case
      when _LoanContrPayoff.PayoffWeightedAverageRatio is null then fltp_to_dec(0.00001 as abap.dec(19,6))
      else
      _LoanContrPayoff.PayoffWeightedAverageRatio + fltp_to_dec(0.00001 as abap.dec(19,6))
      end as PayoffWeightedAverageRatio,

      case
      when _LoanContrPayoff.PayoffWeightedRatio is null then fltp_to_dec(0.00001 as abap.dec(19,6))
      else
      _LoanContrPayoff.PayoffWeightedRatio + fltp_to_dec(0.00001 as abap.dec(19,6))
      end as PayoffWeightedRatio,

      _CompanyCode
}
where
  _LoanContrBP.LoanArchivingCategory = ' '