I_LoanContrBPFinSrvcWthDflt

@AbapCatalog:
{
    sqlViewName: 'ILCBPFINSERWTDF',
    compiler.compareFilter: true,
    preserveKey: true
}
@AccessControl:
{
    authorizationCheck: #CHECK,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@ObjectModel.usageType:
{
    serviceQuality: 'C',
    sizeCategory: 'XL',
    dataClass:'MASTER'
}
@VDM:
{
    viewType: #COMPOSITE,
    private: false
}
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'Loan Contract Business Partner Financials with defaulting'
define view I_LoanContrBPFinSrvcWthDflt
  as select distinct from I_LoanContrData             as _LoanContrBP
    left outer join       I_BPFinancialServicesExtn as _LoanContrBPFinAttributes on _LoanContrBPFinAttributes.BusinessPartner = _LoanContrBP.BusinessPartner
    left outer join       I_CompanyCode             as _CompanyCode              on _CompanyCode.CompanyCode                  = _LoanContrBP.CompanyCode
    association [0..1] to I_Currency                as _Currency                 on  $projection.BusinessPartnerIncomeCurrency = _Currency.Currency
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key _LoanContrBP.CompanyCode,
  key _LoanContrBP.LoanContractID,

      _LoanContrBP.BusinessPartner,

      case
      when _LoanContrBPFinAttributes.BusinessPartnerIsVIP is initial or _LoanContrBPFinAttributes.BusinessPartnerIsVIP is null
      then 'N'
      else 'Y'
      end as BusinessPartnerIsVIP,

      case
      when _LoanContrBPFinAttributes.CustomerIsUnwanted is initial or _LoanContrBPFinAttributes.CustomerIsUnwanted is null
      then 'N'
      else 'Y'
      end as CustomerIsUnwanted,

      case
      when _LoanContrBPFinAttributes.UndesirabilityReason is initial or _LoanContrBPFinAttributes.UndesirabilityReason is null
      then '999'
      else _LoanContrBPFinAttributes.UndesirabilityReason
      end as UndesirabilityReason,

      @Semantics.currencyCode
      @ObjectModel.foreignKey.association: '_Currency'
      case
      when _LoanContrBPFinAttributes.BusinessPartnerIncomeCurrency is initial or _LoanContrBPFinAttributes.BusinessPartnerIncomeCurrency is null
      then cast('EUR' as abap.cuky( 5 ))
      else _LoanContrBPFinAttributes.BusinessPartnerIncomeCurrency
      end as BusinessPartnerIncomeCurrency,

      @Semantics.amount.currencyCode: 'BusinessPartnerIncomeCurrency'
      case
      when _LoanContrBPFinAttributes.BPAnnualNetIncAmtInIncomeCrcy is initial or _LoanContrBPFinAttributes.BPAnnualNetIncAmtInIncomeCrcy is null
      then fltp_to_dec(0.01 as abap.dec(17,2))
      else
      _LoanContrBPFinAttributes.BPAnnualNetIncAmtInIncomeCrcy + fltp_to_dec(0.01 as abap.dec(17,2))
      end as BPAnnualIncAmtInIncCrcy,

      @Semantics.amount.currencyCode: 'BusinessPartnerIncomeCurrency'
      case
      when _LoanContrBPFinAttributes.BPMonthlyNetIncAmtInIncomeCrcy is initial or _LoanContrBPFinAttributes.BPMonthlyNetIncAmtInIncomeCrcy is null
      then fltp_to_dec(0.01 as abap.dec(17,2))
      else
      _LoanContrBPFinAttributes.BPMonthlyNetIncAmtInIncomeCrcy + fltp_to_dec(0.01 as abap.dec(17,2))
      end as BPMonthlyIncAmtInIncCrcy,

      case
      when _LoanContrBPFinAttributes.BusinessPartnerTargetGroup is initial or _LoanContrBPFinAttributes.BusinessPartnerTargetGroup is null
      then '99999'
      else _LoanContrBPFinAttributes.BusinessPartnerTargetGroup
      end as BusPartEmploymentTargetGroup,
      
      _CompanyCode,
      _Currency
}
where
      _LoanContrBP._BusinessPartner.IsBusinessPurposeCompleted = ' '
  and _LoanContrBP._BusinessPartner.BusinessPartnerIsBlocked   = ' '
  and _LoanContrBP.LoanArchivingCategory                       = ' '