I_InsurOpenApplSubCoverage

@EndUserText.label: 'Cvrg SubCoverage of CvPcg in InsOpenAppl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurOpenApplLimit',
                              '_InsurOpenApplSubCvrgClause',
                              '_InsurOpenApplSubCvrgDcbl']
}
@ObjectModel: {
   representativeKey: 'InsurPlcySubCvrgID',
   semanticKey: [ 'InsurPlcyInsuranceSubCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IOASubCvrg'
}
define view entity I_InsurOpenApplSubCoverage
  as select from           I_InsurPlcySubCoverageBasic  as SubCoverage
    left outer to one join P_InsurOpenApplSubCvrgLatest as OpenApplJrnl on  (
        OpenApplJrnl.InsurPlcyUUID                                                                                      = SubCoverage.InsurPlcyUUID
        or OpenApplJrnl.InsurPlcyApplUUID                                                                               = SubCoverage.InsurPlcyUUID
      )
                                                                        and OpenApplJrnl.InsurPlcyInsurContr            = SubCoverage.InsurPlcyInsurContr
                                                                        and OpenApplJrnl.InsurPlcyCoveragePackageID     = SubCoverage.InsurPlcyCoveragePackageID
                                                                        and OpenApplJrnl.InsurPlcyCoverageID            = SubCoverage.InsurPlcyCoverageID
                                                                        and OpenApplJrnl.InsurPlcySubCvrgID             = SubCoverage.InsurPlcySubCvrgID
                                                                        and OpenApplJrnl.InsurPlcyJrnlNmbr              = SubCoverage.InsurPlcyJrnlNmbr
                                                                        and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr < SubCoverage.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurOpenApplCoverage as _InsurOpenApplCoverage     on  $projection.InsurPlcyApplUUID              = _InsurOpenApplCoverage.InsurPlcyApplUUID
                                                                                     and $projection.InsuranceApplication           = _InsurOpenApplCoverage.InsuranceApplication
                                                                                     and $projection.InsurPlcyInsurContr            = _InsurOpenApplCoverage.InsurPlcyInsurContr
                                                                                     and $projection.InsurPlcyCoveragePackageID     = _InsurOpenApplCoverage.InsurPlcyCoveragePackageID
                                                                                     and $projection.InsurPlcyCoverageID            = _InsurOpenApplCoverage.InsurPlcyCoverageID
                                                                                     and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurOpenApplCoverage.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsurOpenApplLimit           as _InsurOpenApplLimit
  composition [0..*] of I_InsurOpenApplSubCvrgClause   as _InsurOpenApplSubCvrgClause
  composition [0..*] of I_InsOpApSubCoverageDeductible as _InsurOpenApplSubCvrgDcbl

  association [1..1] to I_InsurPlcyCvrgInsrdSumCalc    as _InsurPlcyCvrgInsrdSumCalc on  $projection.InsurPlcySubCvrgInsrdSumCalc = _InsurPlcyCvrgInsrdSumCalc.InsurPlcyCvrgInsrdSumCalcMeth
  association [1..1] to I_Currency                     as _Currency                  on  $projection.InsurPlcySubCoverageCurrency = _Currency.Currency
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT        on  $projection.InsurPlcySubCoverageTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key OpenApplJrnl.InsurPlcyApplUUID,
  key cast( OpenApplJrnl.InsuranceApplication as /pm0/vdm_applicationnr_tt preserving type )              as InsuranceApplication,
  key SubCoverage.InsurPlcyInsurContr,
  key SubCoverage.InsurPlcyCoveragePackageID,
  key SubCoverage.InsurPlcyCoverageID,
  key SubCoverage.InsurPlcySubCvrgID,
  key cast( OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      SubCoverage.InsurPlcyJrnlNmbr,
      SubCoverage.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      SubCoverage.InsurPlcyProductPackageID,
      SubCoverage.InsurPlcyInsuranceSubCoverage,
      OpenApplJrnl.InsurPlcyUUID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      SubCoverage.InsurPlcySubCoverageTemplate,
      SubCoverage.InsurPlcySubCoverageStartDate,
      SubCoverage.InsurPlcySubCoverageEndDate,
      @Semantics.amount.currencyCode: 'InsurPlcySubCoverageCurrency'
      SubCoverage.InsurPlcySubCvrgInsrdSumAmount,
      @ObjectModel.foreignKey.association: '_Currency'
      SubCoverage.InsurPlcySubCoverageCurrency,
      SubCoverage.InsurPlcySubCvrgInsuredSumPct,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      SubCoverage.InsurPlcySubCvrgInsrdSumCalc,
      @Semantics.systemDateTime.lastChangedAt: true
      SubCoverage.LastChangeDateTime,

      /* Associations */
      _InsurOpenApplCoverage,
      _InsurOpenApplLimit,
      _InsurOpenApplSubCvrgClause,
      _InsurOpenApplSubCvrgDcbl,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _Currency,
      @Consumption.hidden: true
      _InsurPlcyCvrgInsrdSumCalc

}
where
      SubCoverage.InsurPlcyCoveragePackageID <> 0
  and OpenApplJrnl.InsurPlcyApplUUID         is not initial //Perf. Tuning: Make inner Join out of left outer Join

  and OpenApplJrnl.InsuranceApplication      is not initial