I_InsurOpenApplCoveragePackage

@EndUserText.label: 'Coverage Package in InsurOpenAppl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurOpenApplCoverage',
                              '_InsurOpenApplCvrgPckgClause',
                              '_InsOpApCvrgPckgSurchrgDisc',
                              '_InsurOpenApplCvrgPckgInsrdObj']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoveragePackageID',
   semanticKey: [ 'InsurPlcyCoveragePackageID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IOACvrgPckg'
}
define view entity I_InsurOpenApplCoveragePackage
  as select from           I_InsurPlcyCvrgPackageBasic   as CoveragePackage

    left outer to one join P_InsurOpenApplCvrgPckgLatest as OpenApplJrnl on  (
        OpenApplJrnl.InsurPlcyUUID                                                                                       = CoveragePackage.InsurPlcyUUID
        or OpenApplJrnl.InsurPlcyApplUUID                                                                                = CoveragePackage.InsurPlcyUUID
      )
                                                                         and OpenApplJrnl.InsurPlcyInsurContr            = CoveragePackage.InsurPlcyInsurContr
                                                                         and OpenApplJrnl.InsurPlcyCoveragePackageID     = CoveragePackage.InsurPlcyCoveragePackageID
                                                                         and OpenApplJrnl.InsurPlcyJrnlNmbr              = CoveragePackage.InsurPlcyJrnlNmbr
                                                                         and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr < CoveragePackage.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurOpenApplContract as _InsurOpenApplContract  on  $projection.InsurPlcyApplUUID              = _InsurOpenApplContract.InsurPlcyApplUUID
                                                                                  and $projection.InsuranceApplication           = _InsurOpenApplContract.InsuranceApplication
                                                                                  and $projection.InsurPlcyInsurContr            = _InsurOpenApplContract.InsurPlcyInsurContr
                                                                                  and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurOpenApplContract.InsurPlcyContrDataDetnJrnlNmbr



  composition [1..*] of I_InsurOpenApplCoverage        as _InsurOpenApplCoverage
  composition [0..*] of I_InsurOpenApplCvrgPckgClause  as _InsurOpenApplCvrgPckgClause
  composition [0..*] of I_InsOpApCvrgPckgInsrdObject   as _InsurOpenApplCvrgPckgInsrdObj
  composition [0..*] of I_InsOpApCvrgPckgSurchrgDisc   as _InsOpApCvrgPckgSurchrgDisc

  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT     on  $projection.InsurPlcyCvrgPackageTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurContrCanclnReason       as _InsurContrCanclnReason on  $projection.InsurPlcyCvrgPckgCanclnReason = _InsurContrCanclnReason.InsurContrCanclnRsn

{

  key OpenApplJrnl.InsurPlcyApplUUID,
  key cast( OpenApplJrnl.InsuranceApplication as /pm0/vdm_applicationnr_tt preserving type )              as InsuranceApplication,
  key CoveragePackage.InsurPlcyInsurContr,
  key CoveragePackage.InsurPlcyCoveragePackageID,
  key cast( OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      CoveragePackage.InsurPlcyJrnlNmbr,
      CoveragePackage.InsurPlcyJrnlEndNmbr,
      OpenApplJrnl.InsurPlcyUUID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      CoveragePackage.InsurPlcyCvrgPackageTemplate,
      CoveragePackage.InsurPlcyProductPackageID,
      @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      CoveragePackage.InsurPlcyCvrgPckgCanclnReason,
      @Semantics.dateTime:true
      CoveragePackage.InsurPlcyCvrgPckgCanclnDteTime,
      @Semantics.systemDateTime.lastChangedAt: true
      CoveragePackage.LastChangeDateTime,

      /* Associations */
      _InsurOpenApplContract,
      _InsurOpenApplCoverage,
      _InsurOpenApplCvrgPckgClause,
      _InsurOpenApplCvrgPckgInsrdObj,
      _InsOpApCvrgPckgSurchrgDisc,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurContrCanclnReason

}
where
      OpenApplJrnl.InsurPlcyApplUUID    is not initial //Perf. Tuning: Make inner Join out of left outer Join

  and OpenApplJrnl.InsuranceApplication is not initial