I_InsurApplCoveragePackage

@EndUserText.label: 'Coverage Package in Insurance Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurApplCoverage',
                              '_InsurApplCvrgPckgClause',
                              '_InsurApplCvrgPckgSurchrgDisc',
                              '_InsurApplCvrgPckgInsrdObject']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoveragePackageID',
   semanticKey: [ 'InsurPlcyCoveragePackageID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IACvrgPckg'
}

define view entity I_InsurApplCoveragePackage
  as select from P_InsurPolicyJournalKeys    as PlcyJrnl
    inner join   I_InsurPlcyCvrgPackageBasic as CoveragePackage on  PlcyJrnl.InsurPlcyUUID                  =  CoveragePackage.InsurPlcyUUID
                                                                and PlcyJrnl.InsurPlcyInsurContr            =  CoveragePackage.InsurPlcyInsurContr
                                                                and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= CoveragePackage.InsurPlcyJrnlNmbr
                                                                and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  CoveragePackage.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurApplContract     as _InsurApplContract      on  $projection.InsurPlcyUUID                  = _InsurApplContract.InsurPlcyUUID
                                                                                  and $projection.InsurPlcyInsurContr            = _InsurApplContract.InsurPlcyInsurContr
                                                                                  and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplContract.InsurPlcyContrDataDetnJrnlNmbr

  composition [1..*] of I_InsurApplCoverage            as _InsurApplCoverage
  composition [0..*] of I_InsurApplCvrgPckgClause      as _InsurApplCvrgPckgClause
  composition [0..*] of I_InsurApplCvrgPckgInsrdObject as _InsurApplCvrgPckgInsrdObject
  composition [0..*] of I_InsurApplCvrgPckgSurchrgDisc as _InsurApplCvrgPckgSurchrgDisc

  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT     on  $projection.InsurPlcyCvrgPackageTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurContrCanclnReason       as _InsurContrCanclnReason on  $projection.InsurPlcyCvrgPckgCanclnReason = _InsurContrCanclnReason.InsurContrCanclnRsn

{

  key CoveragePackage.InsurPlcyUUID,
  key CoveragePackage.InsurPlcyInsurContr,
  key CoveragePackage.InsurPlcyCoveragePackageID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      CoveragePackage.InsurPlcyJrnlNmbr,
      CoveragePackage.InsurPlcyJrnlEndNmbr,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      CoveragePackage.InsurPlcyCvrgPackageTemplate,
      CoveragePackage.InsurPlcyProductPackageID,
      @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      CoveragePackage.InsurPlcyCvrgPckgCanclnReason,
      @Semantics.dateTime:true
      CoveragePackage.InsurPlcyCvrgPckgCanclnDteTime,
      @Semantics.systemDateTime.lastChangedAt: true
      CoveragePackage.LastChangeDateTime,

      /* Associations */
      _InsurApplContract,
      _InsurApplCoverage,
      _InsurApplCvrgPckgClause,
      _InsurApplCvrgPckgInsrdObject,
      _InsurApplCvrgPckgSurchrgDisc,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurContrCanclnReason

}