I_InspectionSubsetTP

@AbapCatalog.sqlViewName: 'IINSPSUBSETTP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Point of Inspection Operation'
@VDM.viewType: #TRANSACTIONAL 
@AccessControl.privilegedAssociations:  [ '_CreatedByUser' ]
//@ObjectModel.representativeKey: 'InspectionSubsetInternalID'

@ObjectModel.usageType: { serviceQuality: #D, sizeCategory: #L, dataClass: #TRANSACTIONAL }

/* Draft 2.0 */
//@ObjectModel.modelCategory: #BUSINESS_OBJECT

@ObjectModel.semanticKey:  [ 'InspectionLot' , 'InspectionSubsetInternalID' , 'InspPlanOperationInternalID'  ]
@ObjectModel:{
    compositionRoot: true,
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    transactionalProcessingEnabled: true,
    draftEnabled: true,
    writeDraftPersistence: 'QINSPSUBSETRR_D',
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                    // Default 'PT15M'

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                       // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'    // Default 'PT10M'

    }
}

define view I_InspectionSubsetTP 
  as select from I_InspectionSubset        as InspectionSubset
    left outer to one join P_InspUsgeDcsnSelectedSetCode as SelectedCodeSet   on  InspectionSubset.InspectionLot                   = SelectedCodeSet.InspectionLot
  association [0..*] to I_InspSubsetCharcResultTP as _InspSubsetCharcResult on  $projection.InspectionLot               = _InspSubsetCharcResult.InspectionLot
                                                                            and $projection.InspPlanOperationInternalID = _InspSubsetCharcResult.InspPlanOperationInternalID
                                                                            and $projection.InspectionSubsetInternalID  = _InspSubsetCharcResult.InspectionSubsetInternalID                                                                           
  association [1..1] to I_UserContactCard         as _CreatedByUser           on  $projection.UserID = _CreatedByUser.ContactCardID
  association [1..1] to I_UserContactCard         as _LastChangedByUser       on  $projection.ContactCardID = _LastChangedByUser.ContactCardID                                                                            


{
      @ObjectModel.foreignKey.association: '_InspectionLot'
  key InspectionSubset.InspectionLot,
      @ObjectModel.foreignKey.association: '_InspectionOperation'
  key InspPlanOperationInternalID,
  key InspectionSubsetInternalID,
      cast(InspectionSubset.InspectionLot as qplos preserving type )                  as InspectionLotForEdit,
      cast(InspPlanOperationInternalID as qlfnkn preserving type )   as InspectionOperationForEdit,
      InspectionSubset._InspectionOperation.InspectionOperation,
      //@ObjectModel.readOnly: true

      cast('' as abap.char( 2 ))                                     as InspSubsetStatus,
      InspectionSubsetSortKey,

      //@ObjectModel.readOnly: true

      cast ('' as abap.char(1333))                                   as InspectionOperations,
      // Field for E-tag

      @ObjectModel.readOnly: true
      ChangedDateTime,

      cast(00000 as qrastzfak)                                       as InspSubsetTimeInterval,
      cast('' as qrastzeht)                                          as InspSubsetTimeIntervalUnit,

      SelectedCodeSet.SelectedCodeSetPlant,
    //  @ObjectModel.foreignKey.association: '_SelectedCodeSet'

      SelectedCodeSet.SelectedCodeSet,
      @ObjectModel.foreignKey.association: '_UsageDecisionCodeGroup'
      InspSubsetUsageDcsnCodeGroup,
      InspSubsetUsageDcsnCode,
      @ObjectModel.foreignKey.association: '_InspSubsetUsageDcsnValn'
      InspSubsetUsageDcsnValuation,
      InspectionSubsetTime,
      SelectedCodeSet.InspSbstTimeFldProperty,
      InspectionSubsetDate,
      SelectedCodeSet.InspSbstDateFldProperty,
      InspSubsetLongNumericKey,
      InspSbstLongNmbrFldProperty,
      InspSubsetShortNumericKey,
      InspSbstShrtNmbrFldProperty,
      InspectionSubsetLongCharKey,
      InspSbstLongTxtFldProperty,
      InspectionSubsetShortCharKey,
      InspSbstShrtTxtFldProperty,  
      SelectedCodeSet.InspSubsetTimeFieldName,
      SelectedCodeSet.InspSubsetDateFieldName,         

      //    @ObjectModel.foreignKey.association: '_InspectionPartialLot'

      //    teillos as InspectionPartialLot,

//      @DefaultAggregation:#NONE

      @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
      InspectionSubsetYieldQty,
//      @DefaultAggregation:#NONE

      @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
      InspectionSubsetScrapQty,
//      @DefaultAggregation:#NONE

      @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
      InspectionSubsetReworkQty,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_Unit'
      InspectionSubsetQtyUnit,

      //    vetext as InspectionSubset,       QALT.vetext

      Inspector,
      
      
//      cast( InspectionSubsetDate as abap.char(8) ) as InspSubsetDateTime,

      
      @ObjectModel.readOnly: true
      CreatedByUser                                                           as UserID,
      @ObjectModel.readOnly: true
      InspectionSubset.LastChangedByUser                                      as ContactCardID,

      @ObjectModel.readOnly: true
       _CreatedByUser.FullName                                                 as CreatedByUser,
 //     @Semantics.businessDate.createdAt: true

      @ObjectModel.readOnly: true
      CreationDate,
      @Semantics.time: true
      @ObjectModel.readOnly: true
      CreationTime,      
      @ObjectModel.readOnly: true
      _LastChangedByUser.FullName                                             as LastChangedByUser,
 //     @Semantics.businessDate.lastChangedAt: true

      @ObjectModel.readOnly: true
      LastChangeDate,
      @Semantics.time: true
      @ObjectModel.readOnly: true
      LastChangeTime,

      //  Draft Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _InspSubsetCharcResult,
 
      // Associations

      _InspectionLot,
      _InspectionOperation,
      _InspectionSubsetInternalID,
      _CreatedByUser,
      _LastChangedByUser,
      _UsageDecisionCodeGroup,
      _UsageDecisionCode,
     // _SelectedCodeSet,

      _InspSubsetUsageDcsnValn,
      _InspSubsetUsageDcsnValnTxt,
      //    _MaterialSample,

      //    _FunctionalLocation,

      //    _ShopFloorItem,

      //    _Equipment,

      
      _Unit
}