I_InspPlanOperationVersion

@AbapCatalog.sqlViewName: 'IIPLNOPVRS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Plan Operation Version'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BOOOpInternalVersionCounter'
define view I_InspPlanOperationVersion
  as select from I_BillOfOperationsOpBasic as _BillOfOperationsOpBasic
    inner join   I_InspPlanOpAssgmt        as _InspPlanOpAssgmt on  _BillOfOperationsOpBasic.BillOfOperationsGroup  = _InspPlanOpAssgmt.InspectionPlanGroup
                                                                and _BillOfOperationsOpBasic.BOOOperationInternalID = _InspPlanOpAssgmt.BOOOperationInternalID
                                                                and _BillOfOperationsOpBasic.BillOfOperationsType   = _InspPlanOpAssgmt.BillOfOperationsType

  association [1..1] to I_InspPlanOperation     as _InspPlanOperation     on  $projection.InspectionPlanGroup    = _InspPlanOperation.InspectionPlanGroup
                                                                          and $projection.BOOOperationInternalID = _InspPlanOperation.BOOOperationInternalID
  /*+[hideWarning] { "IDS" :  [ "CARDINALITY_CHECK" ] } */
  association [1..*] to I_InspectionPlanVersion as _InspectionPlanVersion on  $projection.InspectionPlanGroup =  _InspectionPlanVersion.InspectionPlanGroup
                                                                          and $projection.InspectionPlan      =  _InspectionPlanVersion.InspectionPlan

  association [1..1] to I_BillOfOperationsType  as _BillOfOperationsType  on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType

{
           @ObjectModel.foreignKey.association: '_InspPlanOperation'
  key      BillOfOperationsGroup as InspectionPlanGroup,
           @ObjectModel.foreignKey.association: '_InspPlanOperation'
  key      _BillOfOperationsOpBasic.BOOOperationInternalID,
  key      BOOOpInternalVersionCounter,
           @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key      _BillOfOperationsOpBasic.BillOfOperationsType,
           _InspPlanOpAssgmt.InspectionPlan,

           WorkCenterInternalID,
           WorkCenterTypeCode,
           _BillOfOperationsOpBasic.IsDeleted,
           _BillOfOperationsOpBasic.IsImplicitlyDeleted,
           OperationExternalID,
           Operation,

           // ************************** Operation General **************************


           -- Operation
           OperationText,
           Plant,
           OperationControlProfile,
           OperationStandardTextCode,

           -- Origin
           BillOfOperationsRefType,
           BillOfOperationsRefGroup,
           BillOfOperationsRefVariant,
           BOORefOperationIncrementValue,

           -- Quality management: general
           InspResultRecordingView,

           -- Quality management: inspection points
           InspSbstCompletionConfirmation,
           InspSbstHasNoTimeOrQuantity,

           --Standard Values
           OperationReferenceQuantity,
           OperationUnit,
           OpQtyToBaseQtyDnmntr,
           OpQtyToBaseQtyNmrtr,

           // *************************** Administration ****************************

           _BillOfOperationsOpBasic.CreationDate,
           _BillOfOperationsOpBasic.CreatedByUser,
           _BillOfOperationsOpBasic.LastChangeDate,
           _BillOfOperationsOpBasic.LastChangedByUser,
           _BillOfOperationsOpBasic.ChangeNumber,
           _BillOfOperationsOpBasic.ValidityStartDate,
           _BillOfOperationsOpBasic.ValidityEndDate,


           // **************************** Associations *****************************

           _Plant,
           _WorkCenter,
           _WorkCenterType,
           _InspPlanOperation,
           _InspectionPlanVersion,
           _OperationUnit,
           _BillOfOperationsType
}

//where

//     BillOfOperationsType = 'Q'

//  or BillOfOperationsType = 'S'