I_IncomingPaymentFile

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.sqlViewName: 'IINCPMNTFILE'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Incoming Payment File'
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view I_IncomingPaymentFile as select from far_ipf_header
association [1..1] to I_UserContactCard           as _UserContactCard       on  $projection.UploadedByUser = _UserContactCard.ContactCardID 
association [1..1] to I_IncomingPaymentFileStatus as _IncomingPaymentFileStatus
                      on $projection.IncomingPaymentFileStatus = _IncomingPaymentFileStatus.IncomingPaymentFileStatus
                      
association [1..1] to I_ElectronicBankStmntFormat as _ElectronicBankStmntFormat
                      on $projection.ElectronicBankStatementFormat = _ElectronicBankStmntFormat.ElectronicBankStatementFormat
                      
association [1..1] to I_IncomingPaytFileUploadType as _IncomingPaytFileUploadType
                      on $projection.IncomingPaymentFileUploadType = _IncomingPaytFileUploadType.IncomingPaymentFileUploadType
                      
association [1..1] to I_IncomingPaytFileType as _IncomingPaytFileType
                      on $projection.IncomingPaymentFileType = _IncomingPaytFileType.IncomingPaymentFileType
                      
association [1..1] to I_IncomingPaymentFileFormat as _IncomingPaymentFileFormat
                      on  $projection.ElectronicBankStatementFormat = _IncomingPaymentFileFormat.ElectronicBankStatementFormat
                      and $projection.ElectronicBankStmntLongFormat = _IncomingPaymentFileFormat.ElectronicBankStmntLongFormat
                      and $projection.PaymentTransactionTypeGroup = _IncomingPaymentFileFormat.PaymentTransactionTypeGroup
                      
association [1..1] to I_PaymentRejectionFormat as _PaymentRejectionFormat
                      on  $projection.ElectronicBankStatementFormat = _PaymentRejectionFormat.ElectronicBankStatementFormat
                      and $projection.ElectronicBankStmntLongFormat = _PaymentRejectionFormat.ElectronicBankStmntLongFormat
                      and $projection.PaymentTransactionTypeGroup = _PaymentRejectionFormat.PaymentTransactionTypeGroup
                      
association [0..*] to I_IncomingPaymentFileLine   as _IncomingPaymentFileLine   
                      on $projection.IncomingPaymentFile = _IncomingPaymentFileLine.IncomingPaymentFile  {
                      
  key incomingpaymentfileid as IncomingPaymentFile,

  incomingpaymentfiletype as IncomingPaymentFileType,
  
  @ObjectModel.foreignKey.association: '_ElectronicBankStmntFormat'
  bankstatementformat as ElectronicBankStatementFormat,
  
  bankstatementformatlong as ElectronicBankStmntLongFormat,
  
  paymenttransactiontypegroup as PaymentTransactionTypeGroup,
  
  @ObjectModel.foreignKey.association: '_IncomingPaymentFileStatus'
  incomingpaymentfilestatus as IncomingPaymentFileStatus,
    
  incomingpaymentfiletotalitems as IncgPaytFileTotalNumberOfItems,
  
  incomingpaymentfilename as IncomingPaymentFileName,
  uploadedbyuser as UploadedByUser,
  
  @ObjectModel.foreignKey.association: '_IncomingPaytFileUploadType'
  uploadtype as IncomingPaymentFileUploadType,
  
  uploaddatetime as IncomingPaytFileUploadDateTime,
  
  documentid as SAPOfficeDocument,
  
  parametersetid as BankStmntImprtParamSet,
  
  converterid as IncomingPaymentFileConverter,
  
  _UserContactCard,
  _IncomingPaymentFileLine,
  _IncomingPaymentFileStatus,
  _ElectronicBankStmntFormat,
  _IncomingPaytFileUploadType,
  _IncomingPaymentFileFormat,
  _IncomingPaytFileType,
  _PaymentRejectionFormat  
  
}