I_HouseBankAccountVH

@AbapCatalog.sqlViewName: 'IHBAVH'
@EndUserText.label: 'House Bank Account Value Help'

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.semanticKey:  [ 'CompanyCode','HouseBank','HouseBankAccount' ]
@VDM.viewType: #COMPOSITE
@Search.searchable: true
@ObjectModel.dataCategory: #VALUE_HELP
@Consumption.ranked: true

define view I_HouseBankAccountVH
  as select distinct from I_HouseBankAccountLinkage
  association [0..1] to I_BankAccount          as _BankAccount on  $projection.BankAccountInternalID = _BankAccount.BankAccountInternalID
{
      @UI.lineItem: [
      { position: 2, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
  key I_HouseBankAccountLinkage.CompanyCode,
      @UI.lineItem: [
      { position: 3, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
  key I_HouseBankAccountLinkage.HouseBank,
      @UI.lineItem: [
      { position: 1, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
      @ObjectModel.text.element: ['HouseBankAccountDescription']
  key I_HouseBankAccountLinkage.HouseBankAccount,

      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      BankAccountInternalID,
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      BankAccount, //bank account number: length of 18 characters

      @UI.lineItem: [
      { position: 5, importance: #HIGH }
      ]
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      _BankAccount.BankAccountNumber as BankAccountNumber, //bank account number: length of 40 characters (SAP Note 1585003)


      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      BankAccountCurrency,

      @UI.lineItem: [
      { position: 4, importance: #HIGH }
      ]
      @Semantics.text: true
      @Search: {
      defaultSearchElement: true,
      ranking: #HIGH,
      fuzzinessThreshold: 0.8
      }
      I_HouseBankAccountLinkage.BankAccountDescription as HouseBankAccountDescription

}