I_GrantorProgram

DDL: I_GRANTORPROGRAM Type: view_entity BASIC

Grantor Program

I_GrantorProgram is a Basic CDS View (Dimension) that provides data about "Grantor Program" in SAP S/4HANA. It reads from 1 data source (cgpl_project) and exposes 10 fields with key field GrantorProgram.

1 data source(s) 10 fields

Data Sources (1)

SourceAliasJoin Type
cgpl_project cgpl_project from

Annotations (13)

NameValueLevelField
EndUserText.label Grantor Program view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.representativeKey GrantorProgram view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #M view
Analytics.dataCategory #DIMENSION view
Analytics.internalName #LOCAL view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY GrantorProgram
GrantorProgramUUID
GrantorProgramStartDateTime
GrantorProgramEndDateTime
CreatedByUser created_by
CreationDate created_on
LastChangedByUser changed_by
LastChangedDate changed_on
_GrantorProgramDescription _GrantorProgramDescription
_GrantorProgramAttributes _GrantorProgramAttributes 
@EndUserText.label: 'Grantor Program'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'GrantorProgram',
   supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE],
   modelingPattern: #ANALYTICAL_DIMENSION,
   usageType: {
     dataClass:      #MASTER,
     serviceQuality: #A,
     sizeCategory:   #M
   }
}
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL
}
@Metadata: {
  allowExtensions:true,
  ignorePropagatedAnnotations: true
}
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view entity I_GrantorProgram
  as select from cgpl_project

  association of exact one to many I_GrantorProgramDescription as _GrantorProgramDescription on $projection.GrantorProgram = _GrantorProgramDescription.GrantorProgram
  association of exact one to one I_GrantorProgramAttributes   as _GrantorProgramAttributes  on $projection.GrantorProgramUUID = _GrantorProgramAttributes.GrantorProgramUUID
{
          @ObjectModel.text.association: '_GrantorProgramDescription'
  key     cast(external_id as crmt_gpm_extid preserving type)        as GrantorProgram,
          cast(guid as crmt_gpm_program_guid preserving type)        as GrantorProgramUUID,
          cast(planstart as crms4_grm_program_start preserving type) as GrantorProgramStartDateTime,
          cast(planfinish as crms4_grm_program_end preserving type)  as GrantorProgramEndDateTime,
          created_by                                                 as CreatedByUser,
          created_on                                                 as CreationDate,
          changed_by                                                 as LastChangedByUser,
          changed_on                                                 as LastChangedDate,
          _GrantorProgramDescription,
          _GrantorProgramAttributes
}
where
      object_type = 'GMP'
  and application = 'GPM'

Learn More