I_GoodsMovementReasonCodeText

@Analytics: { technicalName: 'IGdsMvtRsnCdTxt',
              dataExtraction.enabled:true }

@EndUserText.label: 'Goods Movement Reason Code - Text'

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { dataCategory: #TEXT,
                modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
                representativeKey: 'GoodsMovementReasonCode',
                usageType: { serviceQuality: #A,
                             dataClass: #CUSTOMIZING,
                             sizeCategory: #S },
                supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #EXTRACTION_DATA_SOURCE,
                                        #LANGUAGE_DEPENDENT_TEXT,
                                        #SEARCHABLE_ENTITY,
                                        #SQL_DATA_SOURCE] }

@Search.searchable: true

@VDM: { lifecycle.contract.type: #PUBLIC_LOCAL_API,
        viewType: #BASIC }
@AbapCatalog.entityBuffer.definitionAllowed: true
define view entity I_GoodsMovementReasonCodeText
  as select from t157e

  association [0..1] to I_Language                as _Language                on  $projection.Language = _Language.Language
  association [0..1] to I_GoodsMovementType       as _GoodsMovementType       on  $projection.GoodsMovementType = _GoodsMovementType.GoodsMovementType

  association [0..1] to I_GoodsMovementReasonCode as _GoodsMovementReasonCode on  $projection.GoodsMovementType       = _GoodsMovementReasonCode.GoodsMovementType
                                                                              and $projection.GoodsMovementReasonCode = _GoodsMovementReasonCode.GoodsMovementReasonCode
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key t157e.spras as Language,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      @ObjectModel.text.element: ['GoodsMovementType']
  key t157e.bwart as GoodsMovementType,
      @ObjectModel.foreignKey.association: '_GoodsMovementReasonCode'
      @ObjectModel.text.element: ['GoodsMovementReasonName']
      @UI.textArrangement: #TEXT_FIRST
  key t157e.grund as GoodsMovementReasonCode,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      @EndUserText.label: 'Goods Movement Reason Text'
      t157e.grtxt as GoodsMovementReasonName,

      //Associations

      _Language,
      _GoodsMovementType,
      _GoodsMovementReasonCode
}