I_GenericPriority

@AbapCatalog: { compiler.compareFilter: true, sqlViewName: 'IGENERICPRIORITY' }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Generic Priority'

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API }

@ObjectModel: {
  representativeKey: 'PriorityCode',
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #S } }

@Metadata.ignorePropagatedAnnotations
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]

define view I_GenericPriority
  as select from t356
  association [0..1] to I_GenericPriorityType as _GenericPriorityType           on  _GenericPriorityType.GenericPriorityType = $projection.GenericPriorityType

  association [0..*] to I_GenericPriorityText as _GenericPriorityText           on  _GenericPriorityText.PriorityCode        = $projection.PriorityCode
                                                                                and _GenericPriorityText.GenericPriorityType = $projection.GenericPriorityType

  association [0..1] to I_UnitOfMeasure       as _GenericStrtDateShiftFctrUnit  on  _GenericStrtDateShiftFctrUnit.UnitOfMeasure = $projection.GenericStrtDateShiftFactorUnit

  association [0..1] to I_UnitOfMeasure       as _GenericEndDateShiftFactorUnit on  _GenericEndDateShiftFactorUnit.UnitOfMeasure = $projection.GenericEndDateShiftFactorUnit
  
  association [0..1] to I_UnitOfMeasure       as _LtstAcceptableCompltnDteUoM   on  _LtstAcceptableCompltnDteUoM.UnitOfMeasure = $projection.LtstAcceptableCompltnDteUoM
{
      @ObjectModel.foreignKey.association: '_GenericPriorityType'
  key t356.artpr  as GenericPriorityType,

      @ObjectModel.text.association: '_GenericPriorityText'
  key t356.priok  as PriorityCode,

      t356.tagbn  as GenericStartDateShiftFactor,

      @ObjectModel.foreignKey.association: '_GenericStrtDateShiftFctrUnit'
      t356.ehtbg  as GenericStrtDateShiftFactorUnit,

      t356.tagen  as GenericEndDateShiftFactor,

      @ObjectModel.foreignKey.association: '_GenericEndDateShiftFactorUnit'
      t356.ehten  as GenericEndDateShiftFactorUnit,

      t356.priocc as GenericPriorityColorCode,
      
      t356.lacd_unit as LtstAcceptableCompltnDteFactor,
      
      @ObjectModel.foreignKey.association: '_LtstAcceptableCompltnDteUoM'
      t356.lacd_uom as LtstAcceptableCompltnDteUoM, 

      // Associations

      _GenericPriorityType,
      _GenericPriorityText,
      _GenericStrtDateShiftFctrUnit,
      _GenericEndDateShiftFactorUnit,
      _LtstAcceptableCompltnDteUoM
}