I_GLAccountYearToDateBalanceC

@AbapCatalog:   {
                    sqlViewName: 'IFIGLACCTYTDBALC',
                    compiler.compareFilter: true,
                    buffering.status: #NOT_ALLOWED,
                    preserveKey: true
                }
@AccessControl: {
                    authorizationCheck: #CHECK,
                    personalData.blocking:#REQUIRED
                }
@ObjectModel:   {
                    representativeKey: 'LedgerGLLineItem',
                    usageType:  {
                                    sizeCategory: #XXL,
                                    serviceQuality: #D,
                                    dataClass: #MIXED
                                },
                   supportedCapabilities: [ #ANALYTICAL_PROVIDER,#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
                   modelingPattern: #ANALYTICAL_CUBE
                }

@Analytics:     {
                    dataCategory: #CUBE,
                    internalName: #LOCAL

                }
@VDM:           {
                    viewType: #COMPOSITE
                }
@Metadata:  {
                ignorePropagatedAnnotations: true,
                allowExtensions: true
            }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'G/L Account Balances - Cube'
define view I_GLAccountYearToDateBalanceC
  as select from I_GLAccountLineItem as I_GLAccountLineItem

  association [0..1] to I_ProjectByExternalID    as _ProjectExternalID           on  $projection.ProjectExternalID = _ProjectExternalID.ProjectExternalID
  association [0..1] to I_ProjectByExternalID    as _PartnerProjectExternalID    on  $projection.PartnerProjectExternalID = _PartnerProjectExternalID.ProjectExternalID
  association [0..1] to I_WBSElementByExternalID as _WBSElementExternalID        on  $projection.WBSElementExternalID = _WBSElementExternalID.WBSElementExternalID
  association [0..1] to I_WBSElementByExternalID as _PartnerWBSElementExternalID on  $projection.PartnerWBSElementExternalID = _PartnerWBSElementExternalID.WBSElementExternalID
  association [0..1] to I_JournalEntry           as _ClearingAccountingDocument  on  $projection.CompanyCode                = _ClearingAccountingDocument.CompanyCode
                                                                                 and $projection.FiscalYear                 = _ClearingAccountingDocument.FiscalYear
                                                                                 and $projection.ClearingAccountingDocument = _ClearingAccountingDocument.AccountingDocument

  association [0..1] to I_Order                  as _PartnerOrder_2              on  $projection.PartnerOrder = _PartnerOrder_2.OrderID
  /* needed for compatibility reasons */
  association [0..1] to I_InternalOrder          as _PartnerOrder                on  $projection.PartnerOrder = _PartnerOrder.InternalOrder
  
association [0..1] to I_FinServicesProductGroup   as _FinServicesProductGroup  on $projection.FinancialServicesProductGroup = _FinServicesProductGroup.FinancialServicesProductGroup
association [0..1] to I_FinancialServicesBranch   as _FinancialServicesBranch  on $projection.FinancialServicesBranch       = _FinancialServicesBranch.FinancialServicesBranch
association [0..1] to I_FinancialDataSource       as _FinancialDataSource      on $projection.FinancialDataSource           = _FinancialDataSource.FinancialDataSource
association [0..1] to I_CustomerSupplierIndustry  as _CustomerSupplierIndustry on $projection.CustomerSupplierIndustry      = _CustomerSupplierIndustry.Industry 

  association [1..1] to E_JournalEntryItem       as _Extension                   on  $projection.SourceLedger       = _Extension.SourceLedger
                                                                                 and $projection.CompanyCode        = _Extension.CompanyCode
                                                                                 and $projection.FiscalYear         = _Extension.FiscalYear
                                                                                 and $projection.AccountingDocument = _Extension.AccountingDocument
                                                                                 and $projection.LedgerGLLineItem   = _Extension.LedgerGLLineItem

{
      @ObjectModel.foreignKey.association: '_SourceLedger'
  key I_GLAccountLineItem.SourceLedger,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key I_GLAccountLineItem.CompanyCode,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key I_GLAccountLineItem.FiscalYear,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key I_GLAccountLineItem.AccountingDocument,
  key I_GLAccountLineItem.LedgerGLLineItem,
      @ObjectModel.foreignKey.association: '_Ledger'
  key I_GLAccountLineItem.Ledger,
      @Consumption: {
                        filter: {
                                      mandatory: true,
                                    multipleSelections: false,
                                    selectionType: #SINGLE
                                }
                     }
      //      @Semantics.fiscal.year: true

      //       @ObjectModel.foreignKey.association: '_LedgerFiscalYearForVariant'

      I_GLAccountLineItem.LedgerFiscalYear,
      I_GLAccountLineItem.GLRecordType,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      I_GLAccountLineItem.ChartOfAccounts,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      I_GLAccountLineItem.ControllingArea,
      @ObjectModel.foreignKey.association: '_FinancialTransactionType'
      I_GLAccountLineItem.FinancialTransactionType,
      I_GLAccountLineItem.GLBusinessTransactionType,
      @ObjectModel.foreignKey.association: '_BusinessTransactionCategory'
      I_GLAccountLineItem.BusinessTransactionCategory,
      @ObjectModel.foreignKey.association: '_BusinessTransactionType'
      I_GLAccountLineItem.BusinessTransactionType,
      I_GLAccountLineItem.ControllingBusTransacType,
      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      I_GLAccountLineItem.ReferenceDocumentType,
      I_GLAccountLineItem.LogicalSystem,
      I_GLAccountLineItem.ReferenceDocumentContext,
      I_GLAccountLineItem.ReferenceDocument,
      I_GLAccountLineItem.ReferenceDocumentItem,
      I_GLAccountLineItem.ReferenceDocumentItemGroup,
      I_GLAccountLineItem.TransactionSubitem,
      I_GLAccountLineItem.IsReversal,
      I_GLAccountLineItem.IsReversed,
      I_GLAccountLineItem.ReversalReferenceDocumentCntxt,
      I_GLAccountLineItem.ReversalReferenceDocument,
      I_GLAccountLineItem.ReversalTransactionSubitem,
      I_GLAccountLineItem.IsSettlement,
      I_GLAccountLineItem.IsSettled,
      @ObjectModel.foreignKey.association: '_PredecessorReferenceDocType'
      I_GLAccountLineItem.PredecessorReferenceDocType,
      I_GLAccountLineItem.PredecessorReferenceDocCntxt,
      I_GLAccountLineItem.PredecessorReferenceDocument,
      I_GLAccountLineItem.PredecessorReferenceDocItem,
      I_GLAccountLineItem.PrdcssrJournalEntryCompanyCode,
      I_GLAccountLineItem.PrdcssrJournalEntryFiscalYear,
      I_GLAccountLineItem.PredecessorJournalEntry,
      I_GLAccountLineItem.PredecessorJournalEntryItem,
      I_GLAccountLineItem.SourceReferenceDocumentType,
      I_GLAccountLineItem.SourceLogicalSystem,
      I_GLAccountLineItem.SourceReferenceDocumentCntxt,
      I_GLAccountLineItem.SourceReferenceDocument,
      I_GLAccountLineItem.SourceReferenceDocumentItem,
      I_GLAccountLineItem.SourceReferenceDocSubitem,
      I_GLAccountLineItem.IsCommitment,
      I_GLAccountLineItem.JrnlEntryItemObsoleteReason,
      I_GLAccountLineItem.JrnlPeriodEndClosingRunLogUUID,
      I_GLAccountLineItem.OrganizationalChange,
      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      I_GLAccountLineItem.GLAccount,
      @ObjectModel.foreignKey.association: '_CostCenter'
      I_GLAccountLineItem.CostCenter,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      I_GLAccountLineItem.ProfitCenter,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      I_GLAccountLineItem.FunctionalArea,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      I_GLAccountLineItem.BusinessArea,
      @ObjectModel.foreignKey.association: '_Segment'
      I_GLAccountLineItem.Segment,
      @ObjectModel.foreignKey.association: '_PartnerCostCenter'
      I_GLAccountLineItem.PartnerCostCenter,
      @ObjectModel.foreignKey.association: '_PartnerProfitCenter'
      I_GLAccountLineItem.PartnerProfitCenter,
      @ObjectModel.foreignKey.association: '_PartnerFunctionalArea'
      I_GLAccountLineItem.PartnerFunctionalArea,
      @ObjectModel.foreignKey.association: '_PartnerBusinessArea'
      I_GLAccountLineItem.PartnerBusinessArea,
      @ObjectModel.foreignKey.association: '_PartnerCompany'
      I_GLAccountLineItem.PartnerCompany,
      I_GLAccountLineItem.PartnerSegment,
      @ObjectModel.foreignKey.association: '_BalanceTransactionCurrency'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.BalanceTransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      I_GLAccountLineItem.AmountInBalanceTransacCrcy,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.TransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      I_GLAccountLineItem.AmountInTransactionCurrency,
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      I_GLAccountLineItem.AmountInCompanyCodeCurrency,
      @ObjectModel.foreignKey.association: '_GlobalCurrency'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.AmountInGlobalCurrency,
      @ObjectModel.foreignKey.association: '_FunctionalCurrency'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FunctionalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      I_GLAccountLineItem.AmountInFunctionalCurrency,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency1'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency1,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency2'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency2,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency3'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency3,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency4'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency4,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency4,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency5'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency5,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency5,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency6'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency6,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency6,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency7'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency7,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency7,
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency8'
      @Semantics.currencyCode:true
      I_GLAccountLineItem.FreeDefinedCurrency8,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      I_GLAccountLineItem.AmountInFreeDefinedCurrency8,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.FixedAmountInGlobalCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.GrpValnFixedAmtInGlobCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.PrftCtrValnFxdAmtInGlobCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.TotalPriceVarcInGlobalCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.GrpValnTotPrcVarcInGlobCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.PrftCtrValnTotPrcVarcInGlbCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.FixedPriceVarcInGlobalCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.GrpValnFixedPrcVarcInGlobCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.PrftCtrValnFxdPrcVarcInGlbCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      I_GLAccountLineItem.FixedAmountInCoCodeCrcy,
      @Semantics.currencyCode:true
      I_GLAccountLineItem.ControllingObjectCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
      I_GLAccountLineItem.AmountInObjectCurrency,
      @Semantics.currencyCode:true
      I_GLAccountLineItem.GrantCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GrantCurrency'} }
      I_GLAccountLineItem.AmountInGrantCurrency,
      @ObjectModel.foreignKey.association: '_BaseUnit'
      @Semantics.unitOfMeasure:true
      I_GLAccountLineItem.BaseUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      I_GLAccountLineItem.Quantity,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      I_GLAccountLineItem.FixedQuantity,
      @ObjectModel.foreignKey.association: '_CostSourceUnit'
      @Semantics.unitOfMeasure:true
      I_GLAccountLineItem.CostSourceUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }
      I_GLAccountLineItem.ValuationQuantity,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'CostSourceUnit'} }
      I_GLAccountLineItem.ValuationFixedQuantity,
      @ObjectModel.foreignKey.association: '_ReferenceQuantityUnit'
      @Semantics.unitOfMeasure:true
      I_GLAccountLineItem.ReferenceQuantityUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'ReferenceQuantityUnit'} }
      I_GLAccountLineItem.ReferenceQuantity,
      @ObjectModel.foreignKey.association: '_AdditionalQuantity1Unit'
      @Semantics.unitOfMeasure:true
      I_GLAccountLineItem.AdditionalQuantity1Unit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity1Unit'} }
      I_GLAccountLineItem.AdditionalQuantity1,
      @ObjectModel.foreignKey.association: '_AdditionalQuantity2Unit'
      @Semantics.unitOfMeasure:true
      I_GLAccountLineItem.AdditionalQuantity2Unit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity2Unit'} }
      I_GLAccountLineItem.AdditionalQuantity2,
      @ObjectModel.foreignKey.association: '_AdditionalQuantity3Unit'
      @Semantics.unitOfMeasure:true
      I_GLAccountLineItem.AdditionalQuantity3Unit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'AdditionalQuantity3Unit'} }
      I_GLAccountLineItem.AdditionalQuantity3,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      I_GLAccountLineItem.DebitCreditCode,
      //      @ObjectModel.foreignKey.association: '_FiscalPeriodForVariant'

      @Semantics.fiscal.period: true
      I_GLAccountLineItem.FiscalPeriod,
      //      @ObjectModel.foreignKey.association: '_FiscalYearVariant'

      @Semantics.fiscal.yearVariant: true
      I_GLAccountLineItem.FiscalYearVariant,
      //      @ObjectModel.foreignKey.association: '_FiscalYearPeriodForVariant'

      @Semantics.fiscal.yearPeriod: true
      I_GLAccountLineItem.FiscalYearPeriod,
      I_GLAccountLineItem.PostingDate,
      @Semantics.fiscal.quarter: true
      // association

      _FiscalCalendarDate.FiscalQuarter                                                      as FiscalQuarter,
      I_GLAccountLineItem.DocumentDate,
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      I_GLAccountLineItem.AccountingDocumentType,
      I_GLAccountLineItem.AccountingDocumentItem,
      I_GLAccountLineItem.AssignmentReference,
      @ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
      I_GLAccountLineItem.AccountingDocumentCategory,
      @ObjectModel.foreignKey.association: '_PostingKey'
      I_GLAccountLineItem.PostingKey,
      I_GLAccountLineItem.TransactionTypeDetermination,
      @ObjectModel.foreignKey.association: '_SubLedgerAccLineItemType'
      I_GLAccountLineItem.SubLedgerAcctLineItemType,
      I_GLAccountLineItem.AccountingDocCreatedByUser,
      I_GLAccountLineItem.LastChangeDateTime,
      I_GLAccountLineItem.CreationDateTime,
      I_GLAccountLineItem.CreationDate,
      @ObjectModel.foreignKey.association: '_EliminationProfitCenter'
      I_GLAccountLineItem.EliminationProfitCenter,
      I_GLAccountLineItem.OriginObjectType,
      @ObjectModel.foreignKey.association: '_GLAccountType'
      I_GLAccountLineItem.GLAccountType,
      @ObjectModel.foreignKey.association: '_AlternativeGLAccount'
      I_GLAccountLineItem.AlternativeGLAccount,
      @ObjectModel.foreignKey.association: '_CountryChartOfAccounts'
      I_GLAccountLineItem.CountryChartOfAccounts,
      I_GLAccountLineItem.ItemIsSplit,
      @ObjectModel.foreignKey.association: '_ConsolidationUnit'
      I_GLAccountLineItem.ConsolidationUnit,
      @ObjectModel.foreignKey.association: '_PartnerConsolidationUnit'
      I_GLAccountLineItem.PartnerConsolidationUnit,
      @ObjectModel.foreignKey.association: '_Company'
      I_GLAccountLineItem.Company,
      @ObjectModel.foreignKey.association: '_ConsolidationChartOfAccounts'
      I_GLAccountLineItem.ConsolidationChartOfAccounts,
      @ObjectModel.foreignKey.association: '_CnsldtnFinancialStatementItem'
      I_GLAccountLineItem.CnsldtnFinancialStatementItem,
      @ObjectModel.foreignKey.association: '_CnsldtnSubitemCategory'
      I_GLAccountLineItem.CnsldtnSubitemCategory,
      @ObjectModel.foreignKey.association: '_CnsldtnSubitem'
      I_GLAccountLineItem.CnsldtnSubitem,
      I_GLAccountLineItem.InvoiceReference,
      I_GLAccountLineItem.InvoiceReferenceFiscalYear,
      I_GLAccountLineItem.FollowOnDocumentType,
      I_GLAccountLineItem.InvoiceItemReference,
      I_GLAccountLineItem.ReferencePurchaseOrderCategory,
      I_GLAccountLineItem.PurchasingDocument,
      I_GLAccountLineItem.PurchasingDocumentItem,
      I_GLAccountLineItem.AccountAssignmentNumber,
      I_GLAccountLineItem.DocumentItemText,
      @ObjectModel.foreignKey.association: '_SalesDocument'
      I_GLAccountLineItem.SalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocumentItem'
      I_GLAccountLineItem.SalesDocumentItem,
      @ObjectModel.foreignKey.association: '_Product'
      I_GLAccountLineItem.Product,
      @ObjectModel.foreignKey.association: '_Plant'
      I_GLAccountLineItem.Plant,
      @ObjectModel.foreignKey.association: '_Supplier'
      I_GLAccountLineItem.Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      I_GLAccountLineItem.Customer,
      I_GLAccountLineItem.ServicesRenderedDate,
      @ObjectModel.foreignKey.association: '_ConditionContract'
      I_GLAccountLineItem.ConditionContract,
      @ObjectModel.foreignKey.association: '_FinancialAccountType'
      I_GLAccountLineItem.FinancialAccountType,
      @ObjectModel.foreignKey.association: '_SpecialGLCode'
      I_GLAccountLineItem.SpecialGLCode,
      I_GLAccountLineItem.TaxCode,
      @ObjectModel.foreignKey.association: '_TaxCountry'
      I_GLAccountLineItem.TaxCountry,
      @ObjectModel.foreignKey.association: '_HouseBank'
      I_GLAccountLineItem.HouseBank,
      I_GLAccountLineItem.HouseBankAccount,
      I_GLAccountLineItem.ClearingDate,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'ClearingJournalEntry'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'ClearingJournalEntry'
      @ObjectModel.foreignKey.association: '_ClearingAccountingDocument'
      I_GLAccountLineItem.ClearingAccountingDocument,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'ClearingJournalEntryFiscalYear'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'ClearingJournalEntryFiscalYear'
      I_GLAccountLineItem.ClearingDocFiscalYear,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_ClearingJournalEntry'
      ClearingJournalEntry,
      @Semantics.fiscal.year: true
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_ClearingJrnlEntryFiscalYear'
      ClearingJournalEntryFiscalYear,
      I_GLAccountLineItem.ValueDate,
      I_GLAccountLineItem.AssetDepreciationArea,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
      I_GLAccountLineItem.MasterFixedAsset,
      @ObjectModel.foreignKey.association: '_FixedAsset'
      I_GLAccountLineItem.FixedAsset,
      I_GLAccountLineItem.AssetValueDate,
      @ObjectModel.foreignKey.association: '_AssetTransactionType'
      I_GLAccountLineItem.AssetTransactionType,
      @ObjectModel.foreignKey.association: '_MovementCategory'
      I_GLAccountLineItem.AssetAcctTransClassfctn,
      I_GLAccountLineItem.DepreciationFiscalPeriod,
      @ObjectModel.foreignKey.association: '_GroupMasterFixedAsset'
      I_GLAccountLineItem.GroupMasterFixedAsset,
      @ObjectModel.foreignKey.association: '_GroupFixedAsset'
      I_GLAccountLineItem.GroupFixedAsset,
      I_GLAccountLineItem.AssetClass,
      @ObjectModel.foreignKey.association: '_PartnerMasterFixedAsset'
      I_GLAccountLineItem.PartnerMasterFixedAsset,
      @ObjectModel.foreignKey.association: '_PartnerFixedAsset'
      I_GLAccountLineItem.PartnerFixedAsset,
      I_GLAccountLineItem.CostEstimate,
      I_GLAccountLineItem.InventorySpecialStockValnType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
      I_GLAccountLineItem.InventorySpecialStockType,
      @ObjectModel.foreignKey.association: '_InventorySpclStkSalesDocument'
      I_GLAccountLineItem.InventorySpclStkSalesDocument,
      @ObjectModel.foreignKey.association: '_InventorySpclStkSalesDocItm'
      I_GLAccountLineItem.InventorySpclStkSalesDocItm,
      @ObjectModel.foreignKey.association: '_InvtrySpclStkWBSElmntBscData'
      I_GLAccountLineItem.InvtrySpclStockWBSElmntIntID,
      I_GLAccountLineItem.InventorySpecialStockSupplier,
      @ObjectModel.foreignKey.association: '_InventoryValuationType'
      I_GLAccountLineItem.InventoryValuationType,
      I_GLAccountLineItem.ValuationArea,
      I_GLAccountLineItem.SenderGLAccount,
      I_GLAccountLineItem.SenderAccountAssignment,
      I_GLAccountLineItem.SenderAccountAssignmentType,
      I_GLAccountLineItem.CostOriginGroup,
      @ObjectModel.foreignKey.association: '_OriginSenderObject'
      I_GLAccountLineItem.OriginSenderObject,
      @ObjectModel.foreignKey.association: '_ControllingDebitCreditCode'
      I_GLAccountLineItem.ControllingDebitCreditCode,
      I_GLAccountLineItem.ControllingObjectDebitType,
      I_GLAccountLineItem.QuantityIsIncomplete,
      @ObjectModel.foreignKey.association: '_OffsettingAccountWithBP'
      I_GLAccountLineItem.OffsettingAccount,
      @ObjectModel.foreignKey.association: '_OffsettingAccountType'
      I_GLAccountLineItem.OffsettingAccountType,
      @ObjectModel.foreignKey.association: '_OffsettingChartOfAccounts'
      I_GLAccountLineItem.OffsettingChartOfAccounts,
      I_GLAccountLineItem.LineItemIsCompleted,
      I_GLAccountLineItem.PersonnelNumber,
      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      I_GLAccountLineItem.ControllingObjectClass,
      @ObjectModel.foreignKey.association: '_PartnerCompanyCode'
      I_GLAccountLineItem.PartnerCompanyCode,
      @ObjectModel.foreignKey.association: '_PartnerControllingObjectClass'
      I_GLAccountLineItem.PartnerControllingObjectClass,
      @ObjectModel.foreignKey.association: '_OriginCostCenter'
      I_GLAccountLineItem.OriginCostCenter,
      @ObjectModel.foreignKey.association: '_OriginProfitCenter'
      I_GLAccountLineItem.OriginProfitCenter,
      @ObjectModel.foreignKey.association: '_OriginCostCtrActivityType'
      I_GLAccountLineItem.OriginCostCtrActivityType,
      I_GLAccountLineItem.OriginProduct,
      I_GLAccountLineItem.VarianceOriginGLAccount,
      I_GLAccountLineItem.AccountAssignment,
      I_GLAccountLineItem.AccountAssignmentType,
      @ObjectModel.foreignKey.association: '_CostCtrActivityType'
      I_GLAccountLineItem.CostCtrActivityType,
      @ObjectModel.foreignKey.association: '_Order'
      I_GLAccountLineItem.OrderID,
      @ObjectModel.foreignKey.association: '_OrderCategory'
      I_GLAccountLineItem.OrderCategory,
      @ObjectModel.foreignKey.association: '_WBSElementBasicData'
      I_GLAccountLineItem.WBSElementInternalID,
      @ObjectModel.foreignKey.association: '_WBSElementExternalID'
      cast( _WBSElementBasicData.WBSElementExternalID as fis_wbsext_no_conv )                as WBSElementExternalID,
      @ObjectModel.foreignKey.association: '_PartnerWBSElementBasicData'
      I_GLAccountLineItem.PartnerWBSElementInternalID,
      @ObjectModel.foreignKey.association: '_PartnerWBSElementExternalID'
      cast( _PartnerWBSElementBasicData.WBSElementExternalID as fis_partner_wbsext_no_conv ) as PartnerWBSElementExternalID,
      @ObjectModel.foreignKey.association: '_ProjectBasicData'
      I_GLAccountLineItem.ProjectInternalID,
      @ObjectModel.foreignKey.association: '_ProjectExternalID'
      cast( _ProjectBasicData.ProjectExternalID as fis_projectext_no_conv )                  as ProjectExternalID,
      @ObjectModel.foreignKey.association: '_PartnerProjectBasicData'
      I_GLAccountLineItem.PartnerProjectInternalID,
      @ObjectModel.foreignKey.association: '_PartnerProjectExternalID'
      cast( _PartnerProjectBasicData.ProjectExternalID as fis_part_projectext_no_conv )      as PartnerProjectExternalID,
      I_GLAccountLineItem.OperatingConcern,
      I_GLAccountLineItem.ProjectNetwork,
      //      I_GLAccountLineItem.RelatedNetworkActivity, conversion exit atc check

      @ObjectModel.foreignKey.association: '_BusinessProcess'
      I_GLAccountLineItem.BusinessProcess,
      I_GLAccountLineItem.CostObject,
      @ObjectModel.foreignKey.association: '_BillableControl'
      I_GLAccountLineItem.BillableControl,
      @ObjectModel.foreignKey.association: '_CostAnalysisResource'
      I_GLAccountLineItem.CostAnalysisResource,
      I_GLAccountLineItem.CustomerServiceNotification,
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      I_GLAccountLineItem.ServiceDocumentType,
      @ObjectModel.foreignKey.association: '_ServiceDocument'
      I_GLAccountLineItem.ServiceDocument,
      @ObjectModel.foreignKey.association: '_ServiceDocumentItem'
      I_GLAccountLineItem.ServiceDocumentItem,
      @ObjectModel.foreignKey.association: '_PartnerServiceDocumentType'
      I_GLAccountLineItem.PartnerServiceDocumentType,
      @ObjectModel.foreignKey.association: '_PartnerServiceDocument'
      I_GLAccountLineItem.PartnerServiceDocument,
      @ObjectModel.foreignKey.association: '_PartnerServiceDocumentItem'
      I_GLAccountLineItem.PartnerServiceDocumentItem,
      @ObjectModel.foreignKey.association: '_ServiceContractType'
      I_GLAccountLineItem.ServiceContractType,
      @ObjectModel.foreignKey.association: '_ServiceContract'
      I_GLAccountLineItem.ServiceContract,
      @ObjectModel.foreignKey.association: '_ServiceContractItem'
      I_GLAccountLineItem.ServiceContractItem,
      I_GLAccountLineItem.BusinessSolutionOrder,
      I_GLAccountLineItem.BusinessSolutionOrderItem,
      @ObjectModel.foreignKey.association: '_ProviderContract'
      I_GLAccountLineItem.ProviderContract,
      @ObjectModel.foreignKey.association: '_ProviderContractItem'
      I_GLAccountLineItem.ProviderContractItem,
      @ObjectModel.foreignKey.association: '_TimeSheetOvertimeCat'
      I_GLAccountLineItem.TimeSheetOvertimeCategory,
      I_GLAccountLineItem.PartnerAccountAssignment,
      I_GLAccountLineItem.PartnerAccountAssignmentType,
      @ObjectModel.foreignKey.association: '_PartnerCostCtrActivityType'
      I_GLAccountLineItem.PartnerCostCtrActivityType,
      @ObjectModel.foreignKey.association: '_PartnerOrder_2'
      I_GLAccountLineItem.PartnerOrder_2                                                     as PartnerOrder,
      @ObjectModel.foreignKey.association: '_PartnerOrderCategory'
      I_GLAccountLineItem.PartnerOrderCategory,
      @ObjectModel.foreignKey.association: '_PartnerSalesDocument'
      I_GLAccountLineItem.PartnerSalesDocument,
      @ObjectModel.foreignKey.association: '_PartnerSalesDocumentItem'
      I_GLAccountLineItem.PartnerSalesDocumentItem,
      I_GLAccountLineItem.PartnerProjectNetwork,
      //      I_GLAccountLineItem.PartnerProjectNetworkActivity,

      @ObjectModel.foreignKey.association: '_PartnerBusinessProcess'
      I_GLAccountLineItem.PartnerBusinessProcess,
      I_GLAccountLineItem.PartnerCostObject,
      I_GLAccountLineItem.ControllingDocumentItem,
      @ObjectModel.foreignKey.association: '_BillingDocumentType'
      I_GLAccountLineItem.BillingDocumentType,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      I_GLAccountLineItem.SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      I_GLAccountLineItem.DistributionChannel,
      I_GLAccountLineItem.OrganizationDivision,
      @ObjectModel.foreignKey.association: '_SoldProduct'
      I_GLAccountLineItem.SoldProduct,
      @ObjectModel.foreignKey.association: '_SoldProductGroup_2'
      I_GLAccountLineItem.SoldProductGroup,
      @ObjectModel.foreignKey.association: '_CustomerGroup'
      I_GLAccountLineItem.CustomerGroup,
      @Analytics.internalName: #LOCAL 
      @ObjectModel.foreignKey.association: '_CustomerSupplierCountry'      
      I_GLAccountLineItem.CustomerSupplierCountry,
      @Analytics.internalName: #LOCAL 
      @ObjectModel.foreignKey.association: '_CustomerSupplierIndustry'     
      I_GLAccountLineItem.CustomerSupplierIndustry,
      I_GLAccountLineItem.SalesDistrict,
      I_GLAccountLineItem.BillToParty,
      I_GLAccountLineItem.ShipToParty,
      I_GLAccountLineItem.CustomerSupplierCorporateGroup,
      @ObjectModel.foreignKey.association: '_CashLedgerCompanyCode'
      I_GLAccountLineItem.CashLedgerCompanyCode,
      @ObjectModel.foreignKey.association: '_CashLedgerAccount'
      I_GLAccountLineItem.CashLedgerAccount,
      @ObjectModel.foreignKey.association: '_FinancialManagementArea'
      I_GLAccountLineItem.FinancialManagementArea,
      I_GLAccountLineItem.FundsCenter,
      @ObjectModel.foreignKey.association: '_FundedProgram'
      I_GLAccountLineItem.FundedProgram,
      @ObjectModel.foreignKey.association: '_Fund'
      I_GLAccountLineItem.Fund,
      @ObjectModel.foreignKey.association: '_Grant'
      I_GLAccountLineItem.GrantID,
      @ObjectModel.foreignKey.association: '_BudgetPeriod'
      I_GLAccountLineItem.BudgetPeriod,
      @ObjectModel.foreignKey.association: '_PartnerFund'
      I_GLAccountLineItem.PartnerFund,
      @ObjectModel.foreignKey.association: '_PartnerGrant'
      I_GLAccountLineItem.PartnerGrant,
      @ObjectModel.foreignKey.association: '_PartnerBudgetPeriod'
      I_GLAccountLineItem.PartnerBudgetPeriod,
      @ObjectModel.foreignKey.association: '_PubSecBudgetAccount'
      I_GLAccountLineItem.PubSecBudgetAccount,
      @ObjectModel.foreignKey.association: '_PubSecBudgetAccountCoCode'
      I_GLAccountLineItem.PubSecBudgetAccountCoCode,
      @ObjectModel.foreignKey.association: '_PubSecBudgetCnsmpnDate'
      I_GLAccountLineItem.PubSecBudgetCnsmpnDate,
      @ObjectModel.foreignKey.association: '_PubSecBudgetCnsmpnFsclPeriod'
      I_GLAccountLineItem.PubSecBudgetCnsmpnFsclPeriod,
      @ObjectModel.foreignKey.association: '_PubSecBudgetCnsmpnFsclYear'
      I_GLAccountLineItem.PubSecBudgetCnsmpnFsclYear,
      I_GLAccountLineItem.PubSecBudgetIsRelevant,
      @ObjectModel.foreignKey.association: '_PubSecBudgetCnsmpnType'
      I_GLAccountLineItem.PubSecBudgetCnsmpnType,
      @ObjectModel.foreignKey.association: '_PubSecBudgetCnsmpnAmtType'
      I_GLAccountLineItem.PubSecBudgetCnsmpnAmtType,
      I_GLAccountLineItem.SponsoredProgram,
      I_GLAccountLineItem.SponsoredClass,
      I_GLAccountLineItem.GteeMBudgetValidityNumber,
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_FinServicesProductGroup'      
      I_GLAccountLineItem.FinancialServicesProductGroup,
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_FinancialServicesBranch'      
      I_GLAccountLineItem.FinancialServicesBranch,
@Analytics.internalName: #LOCAL
@ObjectModel.foreignKey.association: '_FinancialDataSource'      
      I_GLAccountLineItem.FinancialDataSource,
      I_GLAccountLineItem.JointVenture,
      I_GLAccountLineItem.JointVentureEquityGroup,
      I_GLAccountLineItem.JointVentureCostRecoveryCode,
      I_GLAccountLineItem.JointVenturePartner,
      I_GLAccountLineItem.JointVentureBillingType,
      I_GLAccountLineItem.JointVentureEquityType,
      I_GLAccountLineItem.JointVentureProductionDate,
      I_GLAccountLineItem.JointVentureBillingDate,
      I_GLAccountLineItem.JointVentureOperationalDate,
      I_GLAccountLineItem.JointVentureAccountingActivity,
      I_GLAccountLineItem.PartnerVenture,
      I_GLAccountLineItem.PartnerEquityGroup,
      I_GLAccountLineItem.SenderCostRecoveryCode,
      I_GLAccountLineItem.REBusinessEntity,
      I_GLAccountLineItem.RealEstateBuilding,
      I_GLAccountLineItem.RealEstateProperty,
      I_GLAccountLineItem.RERentalObject,
      I_GLAccountLineItem.RealEstateContract,
      I_GLAccountLineItem.REServiceChargeKey,
      I_GLAccountLineItem.RESettlementUnitID,
      I_GLAccountLineItem.SettlementReferenceDate,
      I_GLAccountLineItem.REPartnerBusinessEntity,
      I_GLAccountLineItem.RealEstatePartnerBuilding,
      I_GLAccountLineItem.RealEstatePartnerProperty,
      I_GLAccountLineItem.REPartnerRentalObject,
      I_GLAccountLineItem.RealEstatePartnerContract,
      I_GLAccountLineItem.REPartnerServiceChargeKey,
      I_GLAccountLineItem.REPartnerSettlementUnitID,
      I_GLAccountLineItem.PartnerSettlementReferenceDate,
      I_GLAccountLineItem.AccrualObjectType,
      I_GLAccountLineItem.AccrualObject,
      I_GLAccountLineItem.AccrualSubobject,
      I_GLAccountLineItem.AccrualItemType,
      I_GLAccountLineItem.AccrualValueDate,
      I_GLAccountLineItem.FinancialValuationObjectType,
      I_GLAccountLineItem.FinancialValuationObject,
      I_GLAccountLineItem.FinancialValuationSubobject,
      I_GLAccountLineItem.NetDueDate,
      I_GLAccountLineItem.CreditRiskClass,
      I_GLAccountLineItem.WorkCenterInternalID,
      //      I_GLAccountLineItem.OrderOperation,

      I_GLAccountLineItem.OrderItem,
      I_GLAccountLineItem.PartnerOrderItem,
      //      I_GLAccountLineItem.OrderSuboperation,

      @ObjectModel.foreignKey.association: '_Equipment'
      I_GLAccountLineItem.Equipment,
      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      I_GLAccountLineItem.FunctionalLocation,
      @ObjectModel.foreignKey.association: '_Assembly'
      I_GLAccountLineItem.Assembly,
      @ObjectModel.foreignKey.association: '_MaintenanceActivityType'
      I_GLAccountLineItem.MaintenanceActivityType,
      @ObjectModel.foreignKey.association: '_MaintOrdPlngDegreeCode'
      I_GLAccountLineItem.MaintenanceOrderPlanningCode,
      I_GLAccountLineItem.MaintPriorityType,
      I_GLAccountLineItem.MaintPriority,
      I_GLAccountLineItem.SuperiorOrder,
      @ObjectModel.foreignKey.association: '_ProductGroup_2'
      I_GLAccountLineItem.ProductGroup,
      I_GLAccountLineItem.MaintenanceOrderIsPlanned,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      I_GLAccountLineItem.DebitAmountInCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      I_GLAccountLineItem.CreditAmountInCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      I_GLAccountLineItem.DebitAmountInTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      I_GLAccountLineItem.CreditAmountInTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      I_GLAccountLineItem.DebitAmountInBalanceTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      I_GLAccountLineItem.CreditAmountInBalanceTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.DebitAmountInGlobalCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      I_GLAccountLineItem.CreditAmountInGlobalCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      I_GLAccountLineItem.DebitAmountInFunctionalCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      I_GLAccountLineItem.CreditAmountInFunctionalCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy1                                      as DebitAmountInFreeDfndCrcy1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy1                                     as CreditAmountInFreeDfndCrcy1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy2                                      as DebitAmountInFreeDfndCrcy2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy2                                     as CreditAmountInFreeDfndCrcy2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy3                                      as DebitAmountInFreeDfndCrcy3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy3                                     as CreditAmountInFreeDfndCrcy3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy4                                      as DebitAmountInFreeDfndCrcy4,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy4                                     as CreditAmountInFreeDfndCrcy4,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy5                                      as DebitAmountInFreeDfndCrcy5,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy5                                     as CreditAmountInFreeDfndCrcy5,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy6                                      as DebitAmountInFreeDfndCrcy6,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy6                                     as CreditAmountInFreeDfndCrcy6,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy7                                      as DebitAmountInFreeDfndCrcy7,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy7                                     as CreditAmountInFreeDfndCrcy7,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      I_GLAccountLineItem.DebitAmountInFreeDefinedCrcy8                                      as DebitAmountInFreeDfndCrcy8,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      I_GLAccountLineItem.CreditAmountInFreeDefinedCrcy8                                     as CreditAmountInFreeDfndCrcy8,
      I_GLAccountLineItem.IsStatisticalOrder,
      I_GLAccountLineItem.IsStatisticalCostCenter,
      I_GLAccountLineItem.IsStatisticalSalesDocument,
      I_GLAccountLineItem.WBSIsStatisticalWBSElement,
      I_GLAccountLineItem.CalendarYear,
      I_GLAccountLineItem.CalendarQuarter,
      I_GLAccountLineItem.CalendarYearQuarter,
      I_GLAccountLineItem.CalendarMonth,
      I_GLAccountLineItem.CalendarYearMonth,
      I_GLAccountLineItem.CalendarWeek,
      I_GLAccountLineItem.CalendarYearWeek,
      /* Associations */
      _Assembly,
      _AlternativeGLAccount,
      _AdditionalQuantity3Unit,
      _AssetTransactionType,
      _BalanceTransactionCurrency,
      _BaseUnit,
      _AdditionalQuantity2Unit,
      _AdditionalQuantity1Unit,
      _AccountingDocumentType,
      _AccountingDocumentCategory,
      _BillableControl,
      _BillingDocumentType,
      _BudgetPeriod,
      _BusinessArea,
      _BusinessProcess,
      _BusinessTransactionCategory,
      _BusinessTransactionType,
      _CashLedgerAccount,
      _CashLedgerCompanyCode,
      _ChartOfAccounts,
      _ClearingJrnlEntryFiscalYear,
      _ClearingJournalEntry,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    '_ClearingJournalEntry'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: '_ClearingJournalEntry'
      _ClearingAccountingDocument,
      _CnsldtnFinancialStatementItem,
      _CnsldtnSubitem,
      _CnsldtnSubitemCategory,
      _Company,
      _CompanyCode,
      _CompanyCodeCurrency,
      _ConditionContract,
      _ConsolidationChartOfAccounts,
      _ConsolidationUnit,
      _ControllingArea,
      _ControllingDebitCreditCode,
      _ControllingObjectClass,
      _CostAnalysisResource,
      _CostCenter,
      _CostCtrActivityType,
      _CostOriginGroup,
      _CostSourceUnit,
      _CountryChartOfAccounts,
      _CurrentProfitCenter, // necessary for authorizationgroup/ DCL

      _CurrentCostCenter, // necessary for authorizationgroup/ DCL

      _Customer,
      _CustomerCompany,
      _CustomerGroup,
      _DebitCreditCode,
      _DistributionChannel,
      _EliminationProfitCenter,
      _Equipment,
      _FinancialAccountType,
      _FinancialManagementArea,
      _FinancialTransactionType,
      _FiscalPeriodForVariant,
      _FiscalYear,
      _FiscalYearPeriodForVariant,
      _FiscalYearVariant,
      _FixedAsset,
      _FreeDefinedCurrency1,
      _FreeDefinedCurrency2,
      _FreeDefinedCurrency3,
      _FreeDefinedCurrency4,
      _FreeDefinedCurrency5,
      _FreeDefinedCurrency6,
      _FreeDefinedCurrency7,
      _FreeDefinedCurrency8,
      _FunctionalArea,
      _FunctionalCurrency,
      _FunctionalLocation,
      _Fund,
      _FundedProgram,
      _GLAccountInChartOfAccounts,
      _GLAccountInCompanyCode, // used for AuthorizationGroup

      _GLAccountType,
      _GlobalCurrency,
      _Grant,
      _GroupFixedAsset,
      _GroupMasterFixedAsset,
      _HouseBank,
      _InventorySpclStkSalesDocItm,
      _InventorySpclStkSalesDocument,
      _InventorySpecialStockType,
      _InventoryValuationType,
      _InvtrySpclStkWBSElmntBscData,
      _JournalEntry,
      _Ledger,
      _LedgerFiscalYearForVariant,
      _MaintenanceActivityType,
      _MaintOrdPlngDegreeCode,
      _MasterFixedAsset,
      _MovementCategory,
      _OffsettingAccountType,
      _OffsettingAccountWithBP,
      _OffsettingChartOfAccounts,
      _Order,
      _OrderCategory,
      _OriginCostCenter,
      _OriginCostCtrActivityType,
      _OriginProfitCenter,
      _OriginSenderObject,
      _PartnerBudgetPeriod,
      _PartnerBusinessArea,
      _PartnerBusinessProcess,
      _PartnerCompany,
      _PartnerCompanyCode,
      _PartnerConsolidationUnit,
      _PartnerControllingObjectClass,
      _PartnerCostCenter,
      _PartnerProjectBasicData,
      _PartnerProfitCenter,
      _PartnerSalesDocument,
      _PartnerOrderCategory,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:   '_PartnerOrder_2'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: '_PartnerOrder_2'
      _PartnerOrder,
      _PartnerOrder_2,
      _PartnerMasterFixedAsset,
      _PartnerGrant,
      _PartnerFund,
      _PartnerFunctionalArea,
      _PartnerFixedAsset,
      _PartnerCostCtrActivityType,
      _PartnerProjectExternalID,
      _PartnerSalesDocumentItem,
      _PartnerServiceDocument,
      _PartnerServiceDocumentItem,
      _PartnerServiceDocumentType,
      _PartnerWBSElementBasicData,
      _PartnerWBSElementExternalID,
      _Plant,
      _PostingKey,
      _PredecessorReferenceDocType,
      _Product,
      _ProductGroup_2,
      _ProfitCenter,
      _ProjectBasicData,
      _ProjectExternalID,
      _ProviderContract,
      _ProviderContractItem,
      _PubSecBudgetAccount,
      _PubSecBudgetAccountCoCode,
      _PubSecBudgetCnsmpnAmtType,
      _PubSecBudgetCnsmpnDate,
      _PubSecBudgetCnsmpnFsclPeriod,
      _PubSecBudgetCnsmpnFsclYear,
      _PubSecBudgetCnsmpnType,
      _ReferenceDocumentType,
      _ReferenceQuantityUnit,
      _SalesDocument,
      _SalesDocumentItem,
      _SalesOrganization,
      _Segment,
      _ServiceContract,
      _ServiceContractItem,
      _ServiceContractType,
      _ServiceDocument,
      _ServiceDocumentItem,
      _ServiceDocumentType,
      _SoldProduct,
      _SoldProductGroup_2,
      _SourceLedger,
      _SpecialGLCode,
      _SubLedgerAccLineItemType,
      _Supplier,
      _SupplierCompany,
      _TaxCountry,
      _TimeSheetOvertimeCat,
      _TransactionCurrency,
      _WBSElementBasicData,
      _WBSElementExternalID,
_FinServicesProductGroup,
_FinancialServicesBranch,
_FinancialDataSource,
_CustomerSupplierCountry,
_CustomerSupplierIndustry

}