I_GLAccountForPublicSectorTP

@AbapCatalog.sqlViewName: 'IGLACPSMTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true  
@EndUserText.label: 'FM Settings for GL Accounts'
@ObjectModel: {
  semanticKey: 'GLAccount',
  writeDraftPersistence: 'GLACTX_DRAFT_20',
  createEnabled,
  deleteEnabled,
  updateEnabled,
   usageType: {
       dataClass: #MASTER,
       serviceQuality: #C,
       sizeCategory: #L
   }
}    
@Search.searchable: true 
@VDM.viewType: #TRANSACTIONAL
define view I_GLAccountForPublicSectorTP
  as select from I_GLAccountForPublicSector as _PublicSector
  association [0..*] to I_PubSecBdgtCnsmpnTypeText   as _BudgetCnsmpnTypeText   on  $projection.PubSecBudgetCnsmpnType = _BudgetCnsmpnTypeText.PubSecBudgetCnsmpnType
  association [0..*] to I_PubSecBdgtAcctRevnExpnText as _BdgtAcctRevnExpnText   on  $projection.PubSecBdgtAcctRevnExpnCode = _BdgtAcctRevnExpnText.PubSecBdgtAcctRevnExpnCode
  association [0..*] to I_GLAccountText              as _CashLedgerAccountText  on  $projection.ChartOfAccounts   = _CashLedgerAccountText.ChartOfAccounts
                                                                                and $projection.CashLedgerAccount = _CashLedgerAccountText.GLAccount
  association [0..*] to I_GLAccountText              as _BdgtAcctCarryFwdToText on  $projection.ChartOfAccounts          = _BdgtAcctCarryFwdToText.ChartOfAccounts
                                                                                and $projection.PubSecBdgtAcctCarryFwdTo = _BdgtAcctCarryFwdToText.GLAccount
  /* BO nodes associations */
  association [1..1] to I_GLAcctInChtAcctsTP         as _GLAcctInChtAcctsTP     on  $projection.ChartOfAccounts = _GLAcctInChtAcctsTP.ChartOfAccounts
                                                                                and $projection.GLAccount       = _GLAcctInChtAcctsTP.GLAccount
{
      @ObjectModel.readOnly: true
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
  key _PublicSector.ChartOfAccounts,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.association: '_Text'
      @ObjectModel.hierarchy.association: '_GLAccountHierarchyNode'
      @ObjectModel.readOnly: true
  key _PublicSector.GLAccount,
      @ObjectModel.foreignKey.association: '_PubSecBdgtCnsmpnType'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_BudgetCnsmpnTypeText'
      _PublicSector.PubSecBudgetCnsmpnType,
      @ObjectModel.foreignKey.association: '_PubSecBdgtAcctRevnExpnCode'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_BdgtAcctRevnExpnText'
      _PublicSector.PubSecBdgtAcctRevnExpnCode,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _PublicSector.PubSecBudgetIsRelevant,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _PublicSector.PubSecBdgtAcctIsPostgAllowed,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _PublicSector.PubSecBdgtAcctIsBdgtAllowed,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _PublicSector.PubSecBdgtAcctIsCarryFwd,
      
//      @ObjectModel.foreignKey.association: '_PubSecBdgtAcctCarryFwdTo'

      @ObjectModel.foreignKey.association: '_CarryForwardBudgetAccount'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_BdgtAcctCarryFwdToText'
      _PublicSector.PubSecBdgtAcctCarryFwdTo,
      @ObjectModel.foreignKey.association: '_CashLedgerAccount'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.text.association: '_CashLedgerAccountText'
      //_PublicSector.PubSecBdgtAcctCashOrigin,

      _PublicSector.CashLedgerAccount,
      
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _PublicSector.SponsoredClass,
      _PublicSector._ChartOfAccounts,
      _PublicSector._GLAccountHierarchyNode,
      _PublicSector._PubSecBdgtCnsmpnType,
      _PublicSector._PubSecBdgtAcctRevnExpnCode,
      _PublicSector._PubSecBdgtAcctCarryFwdTo,
      _PublicSector._CarryForwardBudgetAccount,
      _PublicSector._CashLedgerAccount,
      _PublicSector._Text,
      _BudgetCnsmpnTypeText,
      _BdgtAcctRevnExpnText,
      _CashLedgerAccountText,
      _BdgtAcctCarryFwdToText,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _GLAcctInChtAcctsTP

}