I_FundedProgramHierarchy

@ObjectModel.representativeKey: 'FundedProgramHierarchy'
@EndUserText.label: 'Funded Program Hierarchy'
@Analytics: { dataCategory: #DIMENSION, internalName:#LOCAL }
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFUNDEDPH'
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.compiler.compareFilter:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL
}

@Metadata.allowExtensions: true

@Analytics.dataExtraction.enabled: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE ]

@AccessControl.privilegedAssociations: ['_FinancialManagementAreaText']
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.sapObjectNodeType.name: 'FundedProgramHierarchy'
define view I_FundedProgramHierarchy
  as select from hrrp_dir_n

  association [1..*] to I_FinancialManagementAreaText as _FinancialManagementAreaText on  $projection.FinancialManagementArea = _FinancialManagementAreaText.FinancialManagementArea

  association [1..*] to I_FundedProgramHierarchyText  as _Text                        on  $projection.FundedProgramHierarchy  = _Text.FundedProgramHierarchy
                                                                                      and $projection.FinancialManagementArea = _Text.FinancialManagementArea

  association [1..1] to I_FinancialManagementArea     as _FinMgmtArea                 on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea

{

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_FinMgmtAreaStdVH',
                     element: 'FinancialManagementArea' }
        }]
      @ObjectModel.foreignKey.association: '_FinMgmtArea'
  key cast(hrrp_dir_n.hrycls as fikrs )                                         as FinancialManagementArea,
      @ObjectModel.text.association: '_Text'
  key cast(hrrp_dir_n.hryid as fmis_hryid_fundedprogram )                       as FundedProgramHierarchy,
      @Semantics.businessDate.to: true
  key cast(hrrp_dir_n.hryvalto as fmis_fp_validityenddate preserving type )     as ValidityEndDate,
      @Semantics.businessDate.from: true
      cast(hrrp_dir_n.hryvalfrom as fmis_fp_validitystartdate preserving type ) as ValidityStartDate,
      @Semantics.user.lastChangedBy: true
      hrrp_dir_n.upduser                                                        as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      hrrp_dir_n.updtime                                                        as LastChangeDateTime,
      hrrp_dir_n.hrysid                                                         as HierarchyShortID,
      @Hierarchy.notAssignedNode.suppressIndicator: true
      cast( 'X' as rshiernorest )                                               as NotAssgdNdeHasBeenSuppressed,

      _FinMgmtArea,
      @Consumption.hidden: true
      _FinancialManagementAreaText,
      _Text

}
where
  hrrp_dir_n.hrytyp = '0315';