I_FixedAssetUsageObject

@AbapCatalog.sqlViewName: 'IFIXASSETUO'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.dataMaintenance: #RESTRICTED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Fixed Asset Usage Object'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'FixedAssetUsageObject'
@ObjectModel.compositionRoot: true
@ObjectModel.usageType: {
        serviceQuality: #A,
        sizeCategory: #XL,
        dataClass: #MASTER
}

@ObjectModel:{
    supportedCapabilities: [ #SQL_DATA_SOURCE,
                             #CDS_MODELING_DATA_SOURCE,
                             #CDS_MODELING_ASSOCIATION_TARGET ]
}

@Metadata.ignorePropagatedAnnotations: true

@VDM.lifecycle.contract.type:#PUBLIC_LOCAL_API

define view I_FixedAssetUsageObject
  as select from faat_uo as UsageObject

  association [0..*] to I_FixedAssetUsageObjectPeriod as _UsageObjectPeriod          on  $projection.CompanyCode           = _UsageObjectPeriod.CompanyCode
                                                                                     and $projection.FixedAssetUsageObject = _UsageObjectPeriod.FixedAssetUsageObject

  association [0..*] to I_FixedAssetUsageObjectTotal  as _UsageObjectTotal           on  $projection.CompanyCode           = _UsageObjectTotal.CompanyCode

                                                                                     and $projection.FixedAssetUsageObject = _UsageObjectTotal.FixedAssetUsageObject

  association [0..*] to I_FixedAssetUsageObjWhereUsd  as _UsageObjectWhereUsd        on  $projection.CompanyCode           = _UsageObjectWhereUsd.CompanyCode

                                                                                     and $projection.FixedAssetUsageObject = _UsageObjectWhereUsd.FixedAssetUsageObject

  association [0..1] to I_CompanyCode                 as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_UnitOfMeasure               as _UnitOfMeasure              on  $projection.BaseUnit = _UnitOfMeasure.UnitOfMeasure
  association [0..1] to I_FxdAstUsageObjectLfcycSts   as _UsageObjectLifecycleStatus on  $projection.FixedAssetUsageObjLfcycSts = _UsageObjectLifecycleStatus.FixedAssetUsageObjLfcycSts


{
         @ObjectModel.foreignKey.association: '_CompanyCode'
  key    comp_code           as CompanyCode,

         @ObjectModel.text.element: ['FixedAssetUsageObjectDesc']
  key    usage_object        as FixedAssetUsageObject,

         @Semantics.text: true
         description         as FixedAssetUsageObjectDesc,

         @Semantics.unitOfMeasure:true
         @ObjectModel: { foreignKey.association: '_UnitOfMeasure' }
         base_uom            as BaseUnit,

         @ObjectModel.foreignKey.association:'_UsageObjectLifecycleStatus'
         lifecycle_status    as FixedAssetUsageObjLfcycSts,

         @Semantics.systemDateTime.createdAt: true
         creation_datetime   as CreationDateTime,

         @Semantics.user.createdBy: true
         creation_user       as CreatedByUser,

         //         @Semantics.systemDateTime.lastChangedAt: true

         @Semantics.systemDateTime.localInstanceLastChangedAt: true
         lastchange_datetime as LastChangeDateTime,

         //         @Semantics.systemDateTime.lastChangedAt: true

         //         draft_lastchange_datetime as DraftLastChangedDateTime,


         @Semantics.user.lastChangedBy: true
         lastchange_user     as LastChangedByUser,

         _CompanyCode,

         _UnitOfMeasure,

         _UsageObjectLifecycleStatus,

         @ObjectModel.association.type:#TO_COMPOSITION_CHILD
         _UsageObjectPeriod,
         @ObjectModel.association.type:#TO_COMPOSITION_CHILD
         _UsageObjectTotal,
         @ObjectModel.association.type:#TO_COMPOSITION_CHILD
         _UsageObjectWhereUsd
}