I_FiscalPeriodForVariant

DDL: I_FISCALPERIODFORVARIANT SQL: IFIFFSCLPERDFYV Type: view BASIC

Fiscal Period For Fiscal Year Variant

I_FiscalPeriodForVariant is a Basic CDS View (Dimension) that provides data about "Fiscal Period For Fiscal Year Variant" in SAP S/4HANA. It reads from 1 data source (P_FiscalYearPeriod) and exposes 15 fields with key fields FiscalYearVariant, FiscalYear, FiscalPeriod. It has 4 associations to related views.

1 data source(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
P_FiscalYearPeriod P_FiscalYearPeriod from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_FiscalYearVariant _FiscalYearVariant $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
[0..1] I_CalendarDate _FiscalPeriodStartDate $projection.FiscalPeriodStartDate = _FiscalPeriodStartDate.CalendarDate
[0..1] I_FiscalYear _FiscalYear $projection.FiscalYearVariant = _FiscalYear.FiscalYearVariant and $projection.FiscalYear = _FiscalYear.FiscalYear
[0..*] I_FiscalYearPeriodText _Text $projection.FiscalYearVariant = _Text.FiscalYearVariant and $projection.FiscalYear = _Text.FiscalYear and $projection.FiscalPeriod = _Text.FiscalPeriod

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName IFIFFSCLPERDFYV view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
EndUserText.label Fiscal Period For Fiscal Year Variant view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #BASIC view
ObjectModel.representativeKey FiscalPeriod view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #CUSTOMIZING view
Analytics.dataExtraction.enabled true view
AccessControl.authorizationCheck #NOT_REQUIRED view
Analytics.dataCategory #DIMENSION view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY FiscalYearVariant fiscal_year_variant
KEY FiscalYear fiscal_year
KEY FiscalPeriod fiscal_period
FiscalPeriodStartDate fiscal_period_start_date
FiscalPeriodEndDate fiscal_period_end_date
IsSpecialPeriod is_special_period
FiscalYearStartDate fiscal_year_start_date
FiscalYearEndDate fiscal_year_end_date
FiscalYearPeriod fiscal_year_period
NextFiscalPeriod next_fiscal_period
NextFiscalPeriodFiscalYear next_fiscal_period_fiscal_year
_FiscalYearVariant _FiscalYearVariant
_FiscalPeriodStartDate _FiscalPeriodStartDate
_FiscalYear _FiscalYear
_Text _Text 
@AbapCatalog.sqlViewName: 'IFIFFSCLPERDFYV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Fiscal Period For Fiscal Year Variant'

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'FiscalPeriod'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@Analytics.dataExtraction.enabled:true

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics: { dataCategory: #DIMENSION }

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]

define view I_FiscalPeriodForVariant as select from P_FiscalYearPeriod 

association [0..1] to I_FiscalYearVariant    as _FiscalYearVariant     on  $projection.FiscalYearVariant     = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_CalendarDate         as _FiscalPeriodStartDate on  $projection.FiscalPeriodStartDate = _FiscalPeriodStartDate.CalendarDate
association [0..1] to I_FiscalYear           as _FiscalYear            on  $projection.FiscalYearVariant     = _FiscalYear.FiscalYearVariant
                                                                       and $projection.FiscalYear            = _FiscalYear.FiscalYear
association [0..*] to I_FiscalYearPeriodText as _Text                  on  $projection.FiscalYearVariant     = _Text.FiscalYearVariant
                                                                       and $projection.FiscalYear            = _Text.FiscalYear
                                                                       and $projection.FiscalPeriod          = _Text.FiscalPeriod
{
 
@ObjectModel.foreignKey.association: '_FiscalYearVariant'  
//@Semantics.fiscal.yearVariant: true    

key fiscal_year_variant            as FiscalYearVariant,
@ObjectModel.foreignKey.association: '_FiscalYear'      
key fiscal_year                    as FiscalYear,
@ObjectModel.text.association: '_Text'
key fiscal_period                  as FiscalPeriod,

//@ObjectModel.foreignKey.association: '_FiscalPeriodStartDate'      

    fiscal_period_start_date       as FiscalPeriodStartDate,
    fiscal_period_end_date         as FiscalPeriodEndDate,
    
    is_special_period              as IsSpecialPeriod,
    
    fiscal_year_start_date         as FiscalYearStartDate,
    fiscal_year_end_date           as FiscalYearEndDate,
       
    fiscal_year_period             as FiscalYearPeriod,

    next_fiscal_period             as NextFiscalPeriod,
    next_fiscal_period_fiscal_year as NextFiscalPeriodFiscalYear,
    
    _FiscalYearVariant, 
    _FiscalPeriodStartDate,
    _FiscalYear,
    _Text 
           
}

Learn More